libclc/generic/lib/math/cbrt.cl

   1 /*
   2  * Copyright (c) 2014,2015 Advanced Micro Devices, Inc.
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to deal
   6  * in the Software without restriction, including without limitation the rights
   7  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   8  * copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  19  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
  20  * THE SOFTWARE.
  21  */
  22
  23 #include <clc/clc.h>
  24
  25 #include "math.h"
  26 #include "tables.h"
  27 #include "../clcmacro.h"
  28
  29 _CLC_OVERLOAD _CLC_DEF float cbrt(float x) {
  30
  31     uint xi = as_uint(x);
  32     uint axi = xi & EXSIGNBIT_SP32;
  33     uint xsign = axi ^ xi;
  34     xi = axi;
  35
  36     int m = (xi >> EXPSHIFTBITS_SP32) - EXPBIAS_SP32;
  37
  38     // Treat subnormals
  39     uint xisub = as_uint(as_float(xi | 0x3f800000) - 1.0f);
  40     int msub = (xisub >> EXPSHIFTBITS_SP32) - 253;
  41     int c = m == -127;
  42     xi = c ? xisub : xi;
  43     m = c ? msub : m;
  44
  45     int m3 = m / 3;
  46     int rem = m - m3*3;
  47     float mf = as_float((m3 + EXPBIAS_SP32) << EXPSHIFTBITS_SP32);
  48
  49     uint indx = (xi & 0x007f0000) + ((xi & 0x00008000) << 1);
  50     float f = as_float((xi & MANTBITS_SP32) | 0x3f000000) - as_float(indx | 0x3f000000);
  51
  52     indx >>= 16;
  53     float r = f * USE_TABLE(log_inv_tbl, indx);
  54     float poly = mad(mad(r, 0x1.f9add4p-5f, -0x1.c71c72p-4f), r*r, r * 0x1.555556p-2f);
  55
  56     // This could also be done with a 5-element table
  57     float remH = 0x1.428000p-1f;
  58     float remT = 0x1.45f31ap-14f;
  59
  60     remH = rem == -1 ? 0x1.964000p-1f : remH;
  61     remT = rem == -1 ? 0x1.fea53ep-13f : remT;
  62
  63     remH = rem ==  0 ? 0x1.000000p+0f : remH;
  64     remT = rem ==  0 ? 0x0.000000p+0f  : remT;
  65
  66     remH = rem ==  1 ? 0x1.428000p+0f : remH;
  67     remT = rem ==  1 ? 0x1.45f31ap-13f : remT;
  68
  69     remH = rem ==  2 ? 0x1.964000p+0f : remH;
  70     remT = rem ==  2 ? 0x1.fea53ep-12f : remT;
  71
  72     float2 tv = USE_TABLE(cbrt_tbl, indx);
  73     float cbrtH = tv.s0;
  74     float cbrtT = tv.s1;
  75
  76     float bH = cbrtH * remH;
  77     float bT = mad(cbrtH, remT, mad(cbrtT, remH, cbrtT*remT));
  78
  79     float z = mad(poly, bH, mad(poly, bT, bT)) + bH;
  80     z *= mf;
  81     z = as_float(as_uint(z) | xsign);
  82     c = axi >= EXPBITS_SP32 | axi == 0;
  83     z = c ? x : z;
  84     return z;
  85
  86 }
  87
  88 _CLC_UNARY_VECTORIZE(_CLC_OVERLOAD _CLC_DEF, float, cbrt, float);
  89
  90 #ifdef cl_khr_fp64
  91 #pragma OPENCL EXTENSION cl_khr_fp64 : enable
  92
  93 _CLC_OVERLOAD _CLC_DEF double cbrt(double x) {
  94
  95     int return_x = isinf(x) | isnan(x) | x == 0.0;
  96     ulong ux = as_ulong(fabs(x));
  97     int m = (as_int2(ux).hi >> 20) - 1023;
  98
  99     // Treat subnormals
 100     ulong uxs = as_ulong(as_double(0x3ff0000000000000UL | ux) - 1.0);
 101     int ms = m + (as_int2(uxs).hi >> 20) - 1022;
 102
 103     int c = m == -1023;
 104     ux = c ? uxs : ux;
 105     m = c ? ms : m;
 106
 107     int mby3 = m / 3;
 108     int rem = m - 3*mby3;
 109
 110     double mf = as_double((ulong)(mby3 + 1023) << 52);
 111
 112     ux &= 0x000fffffffffffffUL;
 113     double Y = as_double(0x3fe0000000000000UL | ux);
 114
 115     // nearest integer
 116     int index = as_int2(ux).hi >> 11;
 117     index = (0x100 | (index >> 1)) + (index & 1);
 118     double F = (double)index * 0x1.0p-9;
 119
 120     double f = Y - F;
 121     double r = f * USE_TABLE(cbrt_inv_tbl, index-256);
 122
 123     double z = r * fma(r,
 124                        fma(r,
 125                            fma(r,
 126                                fma(r,
 127                                    fma(r, -0x1.8090d6221a247p-6, 0x1.ee7113506ac13p-6),
 128                                    -0x1.511e8d2b3183bp-5),
 129                                0x1.f9add3c0ca458p-5),
 130                            -0x1.c71c71c71c71cp-4),
 131                        0x1.5555555555555p-2);
 132
 133     double2 tv = USE_TABLE(cbrt_rem_tbl, rem+2);
 134     double Rem_h = tv.s0;
 135     double Rem_t = tv.s1;
 136
 137     tv = USE_TABLE(cbrt_dbl_tbl, index-256);
 138     double F_h = tv.s0;
 139     double F_t = tv.s1;
 140
 141     double b_h = F_h * Rem_h;
 142     double b_t = fma(Rem_t, F_h, fma(F_t, Rem_h, F_t*Rem_t));
 143
 144     double ans = fma(z, b_h, fma(z, b_t, b_t)) + b_h;
 145     ans = copysign(ans*mf, x);
 146     return return_x ? x : ans;
 147 }
 148
 149 _CLC_UNARY_VECTORIZE(_CLC_OVERLOAD _CLC_DEF, double, cbrt, double)
 150
 151 #endif