llvm/CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 11)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX git)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  44   # Some CMake features like object libraries get confused if you don't
  45   # explicitly specify an architecture setting with the Xcode generator.
  46   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  47 endif()
  48
  49 project(LLVM
  50   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  51   LANGUAGES C CXX ASM)
  52
  53 set(CMAKE_CXX_STANDARD 14 CACHE STRING "C++ standard to conform to")
  54 set(CMAKE_CXX_STANDARD_REQUIRED YES)
  55 set(CMAKE_CXX_EXTENSIONS NO)
  56
  57 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  58   message(STATUS "No build type selected, default to Debug")
  59   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  60 endif()
  61
  62 # Side-by-side subprojects layout: automatically set the
  63 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
  64 # This allows an easy way of setting up a build directory for llvm and another
  65 # one for llvm+clang+... using the same sources.
  66 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libc;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;mlir;openmp;parallel-libs;polly;pstl")
  67 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
  68         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
  69 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
  70   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
  71 endif()
  72
  73 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
  74 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
  75 # several reasons:
  76 #
  77 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
  78 # source of truth for which projects to build. This means we will ignore user
  79 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
  80 # them.
  81 #
  82 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
  83 # non-empty list but now the user wishes to disable building all other projects
  84 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
  85 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
  86 # building all the projects that were previously enabled.
  87 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
  88 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
  89
  90 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
  91   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
  92   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
  93     string(TOUPPER "${proj}" upper_proj)
  94     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
  95     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
  96       message(STATUS "${proj} project is enabled")
  97       set(SHOULD_ENABLE_PROJECT TRUE)
  98       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
  99       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 100         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 101       endif()
 102       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
 103         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
 104       else()
 105         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
 106       endif()
 107     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 108       message(STATUS "${proj} project is enabled")
 109       set(SHOULD_ENABLE_PROJECT TRUE)
 110     else()
 111       message(STATUS "${proj} project is disabled")
 112       set(SHOULD_ENABLE_PROJECT FALSE)
 113     endif()
 114     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 115     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 116     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 117     # we should deprecate allowing users to set these variables by turning them
 118     # into normal CMake variables rather than cache variables.
 119     set(LLVM_TOOL_${upper_proj}_BUILD
 120       ${SHOULD_ENABLE_PROJECT}
 121       CACHE
 122       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 123     )
 124   endforeach()
 125 endif()
 126 unset(SHOULD_ENABLE_PROJECT)
 127
 128 # Build llvm with ccache if the package is present
 129 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 130 if(LLVM_CCACHE_BUILD)
 131   find_program(CCACHE_PROGRAM ccache)
 132   if(CCACHE_PROGRAM)
 133       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 134       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 135       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 136           CACHE STRING "Parameters to pass through to ccache")
 137
 138       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 139       if (LLVM_CCACHE_MAXSIZE)
 140         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 141       endif()
 142       if (LLVM_CCACHE_DIR)
 143         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 144       endif()
 145       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 146   else()
 147     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 148   endif()
 149 endif()
 150
 151 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 152
 153 # Some features of the LLVM build may be disallowed when dependency debugging is
 154 # enabled. In particular you cannot use ccache because we want to force compile
 155 # operations to always happen.
 156 if(LLVM_DEPENDENCY_DEBUGGING)
 157   if(NOT CMAKE_HOST_APPLE)
 158     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 159   endif()
 160   if(LLVM_CCACHE_BUILD)
 161     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 162   endif()
 163 endif()
 164
 165 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 166 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 167 if(LLVM_ENABLE_GISEL_COV)
 168   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 169 endif()
 170
 171 # Add path for custom modules
 172 set(CMAKE_MODULE_PATH
 173   ${CMAKE_MODULE_PATH}
 174   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 175   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 176   )
 177
 178 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 179 # for use by clang_complete, YouCompleteMe, etc.
 180 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 181
 182 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 183   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 184
 185 option(LLVM_INSTALL_CCTOOLS_SYMLINKS
 186   "Install symlinks from the cctools tool names to the corresponding LLVM tools." OFF)
 187
 188 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 189
 190 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 191
 192 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 193 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 194 # the installation by default. See llvm.org/PR31905.
 195 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 196
 197 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 198 if ( LLVM_USE_FOLDERS )
 199   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 200 endif()
 201
 202 include(VersionFromVCS)
 203
 204 option(LLVM_APPEND_VC_REV
 205   "Embed the version control system revision in LLVM" ON)
 206
 207 set(PACKAGE_NAME LLVM)
 208 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 209 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 210
 211 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 212   "Default URL where bug reports are to be submitted.")
 213
 214 # Configure CPack.
 215 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 216 set(CPACK_PACKAGE_VENDOR "LLVM")
 217 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 218 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 219 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 220 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 221 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 222 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 223 if(WIN32 AND NOT UNIX)
 224   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 225   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 226   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 227   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 228   set(CPACK_NSIS_MODIFY_PATH "ON")
 229   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 230   if( CMAKE_CL_64 )
 231     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 232   endif()
 233 endif()
 234 include(CPack)
 235
 236 # Sanity check our source directory to make sure that we are not trying to
 237 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 238 # sure that we don't have any stray generated files lying around in the tree
 239 # (which would end up getting picked up by header search, instead of the correct
 240 # versions).
 241 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 242   message(FATAL_ERROR "In-source builds are not allowed.
 243 Please create a directory and run cmake from there, passing the path
 244 to this source directory as the last argument.
 245 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 246 Please delete them.")
 247 endif()
 248
 249 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 250
 251 if (CMAKE_BUILD_TYPE AND
 252     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 253   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 254 endif()
 255
 256 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 257
 258 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 259 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 260
 261 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 262     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 263 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 264
 265 # They are used as destination of target generators.
 266 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 267 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 268 if(WIN32 OR CYGWIN)
 269   # DLL platform -- put DLLs into bin.
 270   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 271 else()
 272   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 273 endif()
 274
 275 # Each of them corresponds to llvm-config's.
 276 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 277 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 278 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 279 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 280 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 281
 282 # Note: LLVM_CMAKE_PATH does not include generated files
 283 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 284 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 285 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 286
 287 # List of all targets to be built by default:
 288 set(LLVM_ALL_TARGETS
 289   AArch64
 290   AMDGPU
 291   ARM
 292   BPF
 293   Hexagon
 294   Lanai
 295   Mips
 296   MSP430
 297   NVPTX
 298   PowerPC
 299   RISCV
 300   Sparc
 301   SystemZ
 302   WebAssembly
 303   X86
 304   XCore
 305   )
 306
 307 # List of targets with JIT support:
 308 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 309
 310 set(LLVM_TARGETS_TO_BUILD "all"
 311     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 312
 313 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 314   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 315
 316 option(BUILD_SHARED_LIBS
 317   "Build all libraries as shared libraries instead of static" OFF)
 318
 319 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 320 if(LLVM_ENABLE_BACKTRACES)
 321   set(ENABLE_BACKTRACES 1)
 322 endif()
 323
 324 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 325
 326 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 327 if(LLVM_ENABLE_CRASH_OVERRIDES)
 328   set(ENABLE_CRASH_OVERRIDES 1)
 329 endif()
 330
 331 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 332
 333 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 334 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 335 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 336
 337 set(LLVM_TARGET_ARCH "host"
 338   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 339
 340 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 341
 342 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 343
 344 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 345
 346 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 347
 348 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 349
 350 if(CMAKE_SYSTEM_NAME STREQUAL Windows)
 351   set(zlib_DEFAULT "OFF")
 352 else()
 353   set(zlib_DEFAULT "ON")
 354 endif()
 355
 356 set(LLVM_ENABLE_ZLIB "${zlib_DEFAULT}" CACHE STRING "Use zlib for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
 357
 358 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 359
 360 find_package(Z3 4.7.1)
 361
 362 if (LLVM_Z3_INSTALL_DIR)
 363   if (NOT Z3_FOUND)
 364     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 365   endif()
 366 endif()
 367
 368 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 369
 370 option(LLVM_ENABLE_Z3_SOLVER
 371   "Enable Support for the Z3 constraint solver in LLVM."
 372   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 373 )
 374
 375 if (LLVM_ENABLE_Z3_SOLVER)
 376   if (NOT Z3_FOUND)
 377     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 378   endif()
 379
 380   set(LLVM_WITH_Z3 1)
 381 endif()
 382
 383 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 384   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 385 endif()
 386
 387 set(LLVM_TARGETS_TO_BUILD
 388    ${LLVM_TARGETS_TO_BUILD}
 389    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 390 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 391
 392 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 393 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 394 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 395 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 396   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 397   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 398 else()
 399   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 400   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 401 endif()
 402 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 403 option(LLVM_STATIC_LINK_CXX_STDLIB "Statically link the standard library." OFF)
 404 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 405 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 406 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 407
 408 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 409
 410 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 411   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 412 else()
 413   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 414 endif()
 415
 416 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 417
 418 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 419   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 420
 421 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 422        "Set to ON to force using an old, unsupported host toolchain." OFF)
 423
 424 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 425        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 426
 427 option(LLVM_USE_INTEL_JITEVENTS
 428   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 429   OFF)
 430
 431 if( LLVM_USE_INTEL_JITEVENTS )
 432   # Verify we are on a supported platform
 433   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 434     message(FATAL_ERROR
 435       "Intel JIT API support is available on Linux and Windows only.")
 436   endif()
 437 endif( LLVM_USE_INTEL_JITEVENTS )
 438
 439 option(LLVM_USE_OPROFILE
 440   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 441
 442 option(LLVM_EXTERNALIZE_DEBUGINFO
 443   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 444
 445 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 446   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 447
 448 # If enabled, verify we are on a platform that supports oprofile.
 449 if( LLVM_USE_OPROFILE )
 450   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 451     message(FATAL_ERROR "OProfile support is available on Linux only.")
 452   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 453 endif( LLVM_USE_OPROFILE )
 454
 455 option(LLVM_USE_PERF
 456   "Use perf JIT interface to inform perf about JIT code" OFF)
 457
 458 # If enabled, verify we are on a platform that supports perf.
 459 if( LLVM_USE_PERF )
 460   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 461     message(FATAL_ERROR "perf support is available on Linux only.")
 462   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 463 endif( LLVM_USE_PERF )
 464
 465 set(LLVM_USE_SANITIZER "" CACHE STRING
 466   "Define the sanitizer used to build binaries and tests.")
 467 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 468 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 469   "Path to fuzzing library for linking with fuzz targets")
 470
 471 option(LLVM_USE_SPLIT_DWARF
 472   "Use -gsplit-dwarf when compiling llvm." OFF)
 473
 474 # Define an option controlling whether we should build for 32-bit on 64-bit
 475 # platforms, where supported.
 476 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 477   # TODO: support other platforms and toolchains.
 478   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 479 endif()
 480
 481 # Define the default arguments to use with 'lit', and an option for the user to
 482 # override.
 483 set(LIT_ARGS_DEFAULT "-sv")
 484 if (MSVC_IDE OR XCODE)
 485   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 486 endif()
 487 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 488
 489 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 490 if( WIN32 AND NOT CYGWIN )
 491   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 492 endif()
 493
 494 # Define options to control the inclusion and default build behavior for
 495 # components which may not strictly be necessary (tools, examples, and tests).
 496 #
 497 # This is primarily to support building smaller or faster project files.
 498 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 499 option(LLVM_BUILD_TOOLS
 500   "Build the LLVM tools. If OFF, just generate build targets." ON)
 501
 502 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 503 option(LLVM_BUILD_UTILS
 504   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 505
 506 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 507 option(LLVM_BUILD_RUNTIMES
 508   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 509
 510 option(LLVM_BUILD_RUNTIME
 511   "Build the LLVM runtime libraries." ON)
 512 option(LLVM_BUILD_EXAMPLES
 513   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 514 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 515
 516 if(LLVM_BUILD_EXAMPLES)
 517   add_definitions(-DBUILD_EXAMPLES)
 518 endif(LLVM_BUILD_EXAMPLES)
 519
 520 option(LLVM_BUILD_TESTS
 521   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 522 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 523 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 524
 525 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 526 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 527 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 528
 529 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 530 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 531 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 532 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 533 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 534 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 535
 536 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 537     CACHE STRING "Doxygen-generated HTML documentation install directory")
 538 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 539     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 540
 541 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 542   "Build compiler-rt as an external project." OFF)
 543
 544 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 545   "Show target and host info when tools are invoked with --version." ON)
 546
 547 # You can configure which libraries from LLVM you want to include in the
 548 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 549 # list of LLVM components. All component names handled by llvm-config are valid.
 550 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 551   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 552     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 553 endif()
 554
 555 if(MSVC)
 556   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 557   # Set this variable to OFF here so it can't be set with a command-line
 558   # argument.
 559   set (LLVM_LINK_LLVM_DYLIB OFF)
 560   if (BUILD_SHARED_LIBS)
 561     message(FATAL_ERROR "BUILD_SHARED_LIBS options is not supported on Windows.")
 562   endif()
 563 else()
 564   option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 565   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 566   set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 567   if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 568     set(LLVM_BUILD_LLVM_DYLIB_default ON)
 569   endif()
 570   option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 571 endif()
 572
 573 if (LLVM_LINK_LLVM_DYLIB AND BUILD_SHARED_LIBS)
 574   message(FATAL_ERROR "Cannot enable BUILD_SHARED_LIBS with LLVM_LINK_LLVM_DYLIB.  We recommend disabling BUILD_SHARED_LIBS.")
 575 endif()
 576
 577 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 578 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 579   set(LLVM_USE_HOST_TOOLS ON)
 580 endif()
 581
 582 if (MSVC_IDE)
 583   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 584 endif()
 585
 586 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 587     LLVM_ENABLE_IR_PGO)
 588   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 589     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 590     # for spining disks. Anything higher may only help on slower mediums.
 591     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 592   endif()
 593   if(NOT LLVM_PROFILE_FILE_PATTERN)
 594     if(NOT LLVM_PROFILE_DATA_DIR)
 595       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 596     endif()
 597     file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 598   endif()
 599   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 600     if(NOT LLVM_CSPROFILE_DATA_DIR)
 601       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 602     endif()
 603     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 604   endif()
 605 endif()
 606
 607 if (LLVM_BUILD_STATIC)
 608   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 609 endif()
 610
 611 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 612 if(CMAKE_HOST_APPLE AND APPLE)
 613   include(UseLibtool)
 614 endif()
 615
 616 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 617 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 618 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 619
 620 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 621   "Enable per-target runtimes directory")
 622
 623 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 624   "Profiling data file to use when compiling in order to improve runtime performance.")
 625
 626 # All options referred to from HandleLLVMOptions have to be specified
 627 # BEFORE this include, otherwise options will not be correctly set on
 628 # first cmake run
 629 include(config-ix)
 630
 631 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 632   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 633 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 634
 635 # By default, we target the host, but this can be overridden at CMake
 636 # invocation time.
 637 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 638   "Default target for which LLVM will generate code." )
 639 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 640 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 641 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 642
 643 if(WIN32 OR CYGWIN)
 644   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 645     set(LLVM_ENABLE_PLUGINS_default ON)
 646   else()
 647     set(LLVM_ENABLE_PLUGINS_default OFF)
 648   endif()
 649 else()
 650   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 651 endif()
 652 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 653
 654 include(HandleLLVMOptions)
 655
 656 include(FindPythonInterp)
 657 if( NOT PYTHONINTERP_FOUND )
 658   message(FATAL_ERROR
 659 "Unable to find Python interpreter, required for builds and testing.
 660
 661 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 662 endif()
 663
 664 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 665   message(FATAL_ERROR "Python 2.7 or newer is required")
 666 endif()
 667
 668 ######
 669 # LLVMBuild Integration
 670 #
 671 # We use llvm-build to generate all the data required by the CMake based
 672 # build system in one swoop:
 673 #
 674 #  - We generate a file (a CMake fragment) in the object root which contains
 675 #    all the definitions that are required by CMake.
 676 #
 677 #  - We generate the library table used by llvm-config.
 678 #
 679 #  - We generate the dependencies for the CMake fragment, so that we will
 680 #    automatically reconfigure ourselves.
 681
 682 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 683 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 684   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 685 set(LLVMBUILDCMAKEFRAG
 686   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 687
 688 # Create the list of optional components that are enabled
 689 if (LLVM_USE_INTEL_JITEVENTS)
 690   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 691 endif (LLVM_USE_INTEL_JITEVENTS)
 692 if (LLVM_USE_OPROFILE)
 693   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 694 endif (LLVM_USE_OPROFILE)
 695 if (LLVM_USE_PERF)
 696   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 697 endif (LLVM_USE_PERF)
 698
 699 message(STATUS "Constructing LLVMBuild project information")
 700 execute_process(
 701   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 702             --native-target "${LLVM_NATIVE_ARCH}"
 703             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 704             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 705             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 706             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 707             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 708             ERROR_VARIABLE LLVMBUILDERRORS
 709             OUTPUT_STRIP_TRAILING_WHITESPACE
 710             ERROR_STRIP_TRAILING_WHITESPACE
 711   RESULT_VARIABLE LLVMBUILDRESULT)
 712
 713 # On Win32, CMake doesn't properly handle piping the default output/error
 714 # streams into the GUI console. So, we explicitly catch and report them.
 715 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 716   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 717 endif()
 718 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 719   message(FATAL_ERROR
 720     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 721 endif()
 722
 723 # Include the generated CMake fragment. This will define properties from the
 724 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 725 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 726 # files change.
 727 include(${LLVMBUILDCMAKEFRAG})
 728
 729 ######
 730
 731 # Configure all of the various header file fragments LLVM uses which depend on
 732 # configuration variables.
 733 set(LLVM_ENUM_TARGETS "")
 734 set(LLVM_ENUM_ASM_PRINTERS "")
 735 set(LLVM_ENUM_ASM_PARSERS "")
 736 set(LLVM_ENUM_DISASSEMBLERS "")
 737 foreach(t ${LLVM_TARGETS_TO_BUILD})
 738   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 739
 740   list(FIND LLVM_ALL_TARGETS ${t} idx)
 741   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 742   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 743   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 744   # this test just makes sure that any experimental targets were passed via
 745   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 746   if( idx LESS 0 AND idy LESS 0 )
 747     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 748       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 749   else()
 750     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 751   endif()
 752
 753   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 754   if( asmp_file )
 755     set(LLVM_ENUM_ASM_PRINTERS
 756       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 757   endif()
 758   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 759     set(LLVM_ENUM_ASM_PARSERS
 760       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 761   endif()
 762   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 763     set(LLVM_ENUM_DISASSEMBLERS
 764       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 765   endif()
 766 endforeach(t)
 767
 768 # Produce the target definition files, which provide a way for clients to easily
 769 # include various classes of targets.
 770 configure_file(
 771   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 772   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 773   )
 774 configure_file(
 775   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 776   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 777   )
 778 configure_file(
 779   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 780   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 781   )
 782 configure_file(
 783   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 784   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 785   )
 786
 787 # Configure the three LLVM configuration header files.
 788 configure_file(
 789   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 790   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 791 configure_file(
 792   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 793   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 794 configure_file(
 795   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 796   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 797
 798 # Add target for generating source rpm package.
 799 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 800     CACHE FILEPATH ".spec file to use for srpm generation")
 801 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 802 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 803
 804 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 805 string(LENGTH "${revision}" revision_length)
 806 set(LLVM_RPM_SPEC_REVISION "${revision}")
 807
 808 configure_file(
 809   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 810   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 811
 812 add_custom_target(srpm
 813   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 814   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 815 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 816
 817
 818 # They are not referenced. See set_output_directory().
 819 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 820 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 821 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 822
 823 if(APPLE AND DARWIN_LTO_LIBRARY)
 824   set(CMAKE_EXE_LINKER_FLAGS
 825     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 826   set(CMAKE_SHARED_LINKER_FLAGS
 827     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 828   set(CMAKE_MODULE_LINKER_FLAGS
 829     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 830 endif()
 831
 832 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
 833 # break things. In this case we need to enable the large-file API as well.
 834 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 835           add_definitions("-D_XOPEN_SOURCE=700")
 836           add_definitions("-D_LARGE_FILE_API")
 837 endif()
 838
 839 # Build with _FILE_OFFSET_BITS=64 on Solaris to match g++ >= 9.
 840 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 841           add_definitions("-D_FILE_OFFSET_BITS=64")
 842 endif()
 843
 844 # Work around a broken bfd ld behavior. When linking a binary with a
 845 # foo.so library, it will try to find any library that foo.so uses and
 846 # check its symbols. This is wasteful (the check was done when foo.so
 847 # was created) and can fail since it is not the dynamic linker and
 848 # doesn't know how to handle search paths correctly.
 849 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 850   set(CMAKE_EXE_LINKER_FLAGS
 851       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 852 endif()
 853
 854 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 855
 856 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 857
 858 # when crosscompiling import the executable targets from a file
 859 if(LLVM_USE_HOST_TOOLS)
 860   include(CrossCompile)
 861   llvm_create_cross_target(LLVM NATIVE "" Release)
 862 endif(LLVM_USE_HOST_TOOLS)
 863 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 864 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 865 # (this is a variable that CrossCompile sets on recursive invocations)
 866 endif()
 867
 868 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 869   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 870   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 871   include_directories(SYSTEM "/usr/local/include")
 872   link_directories("/usr/local/lib")
 873 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 874
 875 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 876    # special hack for Solaris to handle crazy system sys/regset.h
 877    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 878 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 879
 880 # Make sure we don't get -rdynamic in every binary. For those that need it,
 881 # use export_executable_symbols(target).
 882 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 883
 884 include(AddLLVM)
 885 include(TableGen)
 886
 887 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 888   # People report that -O3 is unreliable on MinGW. The traditional
 889   # build also uses -O2 for that reason:
 890   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 891 endif()
 892
 893 # Put this before tblgen. Else we have a circular dependence.
 894 add_subdirectory(lib/Demangle)
 895 add_subdirectory(lib/Support)
 896 add_subdirectory(lib/TableGen)
 897
 898 add_subdirectory(utils/TableGen)
 899
 900 add_subdirectory(include/llvm)
 901
 902 add_subdirectory(lib)
 903
 904 if( LLVM_INCLUDE_UTILS )
 905   add_subdirectory(utils/FileCheck)
 906   add_subdirectory(utils/PerfectShuffle)
 907   add_subdirectory(utils/count)
 908   add_subdirectory(utils/not)
 909   add_subdirectory(utils/yaml-bench)
 910 else()
 911   if ( LLVM_INCLUDE_TESTS )
 912     message(FATAL_ERROR "Including tests when not building utils will not work.
 913     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 914   endif()
 915 endif()
 916
 917 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 918 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 919   add_subdirectory(utils/LLVMVisualizers)
 920 endif()
 921
 922 foreach( binding ${LLVM_BINDINGS_LIST} )
 923   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 924     add_subdirectory(bindings/${binding})
 925   endif()
 926 endforeach()
 927
 928 add_subdirectory(projects)
 929
 930 if( LLVM_INCLUDE_TOOLS )
 931   add_subdirectory(tools)
 932 endif()
 933
 934 if( LLVM_INCLUDE_RUNTIMES )
 935   add_subdirectory(runtimes)
 936 endif()
 937
 938 if( LLVM_INCLUDE_EXAMPLES )
 939   add_subdirectory(examples)
 940 endif()
 941
 942 if( LLVM_INCLUDE_TESTS )
 943   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 944     include(LLVMExternalProjectUtils)
 945     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 946       USE_TOOLCHAIN
 947       EXCLUDE_FROM_ALL
 948       NO_INSTALL
 949       ALWAYS_CLEAN)
 950   endif()
 951   add_subdirectory(utils/lit)
 952   add_subdirectory(test)
 953   add_subdirectory(unittests)
 954   if( LLVM_INCLUDE_UTILS )
 955     add_subdirectory(utils/unittest)
 956   endif()
 957
 958   if (WIN32)
 959     # This utility is used to prevent crashing tests from calling Dr. Watson on
 960     # Windows.
 961     add_subdirectory(utils/KillTheDoctor)
 962   endif()
 963
 964   # Add a global check rule now that all subdirectories have been traversed
 965   # and we know the total set of lit testsuites.
 966   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 967   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 968   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 969   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 970   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 971                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 972   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 973                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 974   add_lit_target(check-all
 975     "Running all regression tests"
 976     ${LLVM_LIT_TESTSUITES}
 977     PARAMS ${LLVM_LIT_PARAMS}
 978     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 979     ARGS ${LLVM_LIT_EXTRA_ARGS}
 980     )
 981   if(TARGET check-runtimes)
 982     add_dependencies(check-all check-runtimes)
 983   endif()
 984   add_custom_target(test-depends
 985                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 986   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 987 endif()
 988
 989 if (LLVM_INCLUDE_DOCS)
 990   add_subdirectory(docs)
 991 endif()
 992
 993 add_subdirectory(cmake/modules)
 994
 995 # Do this last so that all lit targets have already been created.
 996 if (LLVM_INCLUDE_UTILS)
 997   add_subdirectory(utils/llvm-lit)
 998 endif()
 999
1000 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1001   install(DIRECTORY include/llvm include/llvm-c
1002     DESTINATION include
1003     COMPONENT llvm-headers
1004     FILES_MATCHING
1005     PATTERN "*.def"
1006     PATTERN "*.h"
1007     PATTERN "*.td"
1008     PATTERN "*.inc"
1009     PATTERN "LICENSE.TXT"
1010     PATTERN ".svn" EXCLUDE
1011     )
1012
1013   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1014     DESTINATION include
1015     COMPONENT llvm-headers
1016     FILES_MATCHING
1017     PATTERN "*.def"
1018     PATTERN "*.h"
1019     PATTERN "*.gen"
1020     PATTERN "*.inc"
1021     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1022     PATTERN "CMakeFiles" EXCLUDE
1023     PATTERN "config.h" EXCLUDE
1024     PATTERN ".svn" EXCLUDE
1025     )
1026
1027   if (LLVM_INSTALL_MODULEMAPS)
1028     install(DIRECTORY include/llvm include/llvm-c
1029             DESTINATION include
1030             COMPONENT llvm-headers
1031             FILES_MATCHING
1032             PATTERN "module.modulemap"
1033             )
1034     install(FILES include/llvm/module.install.modulemap
1035             DESTINATION include/llvm
1036             COMPONENT llvm-headers
1037             RENAME "module.extern.modulemap"
1038             )
1039   endif(LLVM_INSTALL_MODULEMAPS)
1040
1041   # Installing the headers needs to depend on generating any public
1042   # tablegen'd headers.
1043   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1044   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1045
1046   if (NOT LLVM_ENABLE_IDE)
1047     add_llvm_install_targets(install-llvm-headers
1048                              DEPENDS llvm-headers
1049                              COMPONENT llvm-headers)
1050   endif()
1051
1052   # Custom target to install all libraries.
1053   add_custom_target(llvm-libraries)
1054   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1055
1056   if (NOT LLVM_ENABLE_IDE)
1057     add_llvm_install_targets(install-llvm-libraries
1058                              DEPENDS llvm-libraries
1059                              COMPONENT llvm-libraries)
1060   endif()
1061
1062   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1063   if(LLVM_LIBS)
1064     list(REMOVE_DUPLICATES LLVM_LIBS)
1065     foreach(lib ${LLVM_LIBS})
1066       add_dependencies(llvm-libraries ${lib})
1067       if (NOT LLVM_ENABLE_IDE)
1068         add_dependencies(install-llvm-libraries install-${lib})
1069       endif()
1070     endforeach()
1071   endif()
1072 endif()
1073
1074 # This must be at the end of the LLVM root CMakeLists file because it must run
1075 # after all targets are created.
1076 include(LLVMDistributionSupport)
1077 llvm_distribution_add_targets()
1078
1079 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1080 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1081   include(InstallRequiredSystemLibraries)
1082 endif()
1083
1084 if (LLVM_INCLUDE_BENCHMARKS)
1085   # Override benchmark defaults so that when the library itself is updated these
1086   # modifications are not lost.
1087   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1088   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1089   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1090   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1091   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1092   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1093   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1094
1095   add_subdirectory(utils/benchmark)
1096   add_subdirectory(benchmarks)
1097 endif()
1098
1099 if (LLVM_INCLUDE_UTILS AND LLVM_INCLUDE_TOOLS)
1100   add_subdirectory(utils/llvm-locstats)
1101 endif()
1102
1103 process_llvm_pass_plugins()