bolt/CMakeLists.txt

   1 include(ExternalProject)
   2
   3 set(BOLT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   4 set(BOLT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
   5 set(CMAKE_CXX_STANDARD 14)
   6
   7 set(BOLT_ENABLE_RUNTIME OFF)
   8 if (CMAKE_SYSTEM_PROCESSOR MATCHES "x86_64")
   9   set(BOLT_ENABLE_RUNTIME ON)
  10 endif()
  11
  12 set(BOLT_CLANG_EXE "" CACHE FILEPATH "Path to clang executable for the target \
  13 architecture for use in BOLT tests")
  14 set(BOLT_LLD_EXE "" CACHE FILEPATH "Path to lld executable for the target \
  15 architecture for use in BOLT tests")
  16
  17 set(BOLT_INCLUDE_TESTS OFF)
  18 if (LLVM_INCLUDE_TESTS)
  19   set(BOLT_CLANG_PRESENT OFF)
  20   set(BOLT_LLD_PRESENT OFF)
  21
  22   if ("clang" IN_LIST LLVM_ENABLE_PROJECTS AND BOLT_CLANG_EXE)
  23     message(WARNING "BOLT_CLANG_EXE is set and clang project is enabled. \
  24           BOLT_CLANG_EXE will be used for BOLT tests.")
  25   endif()
  26   if ("clang" IN_LIST LLVM_ENABLE_PROJECTS OR BOLT_CLANG_EXE)
  27     set(BOLT_CLANG_PRESENT ON)
  28   endif()
  29
  30   if ("lld" IN_LIST LLVM_ENABLE_PROJECTS AND BOLT_LLD_EXE)
  31     message(WARNING "BOLT_LLD_EXE is set and lld project is enabled. \
  32           BOLT_LLD_EXE will be used for BOLT tests.")
  33   endif()
  34   if ("lld" IN_LIST LLVM_ENABLE_PROJECTS OR BOLT_LLD_EXE)
  35     set(BOLT_LLD_PRESENT ON)
  36   endif()
  37
  38   if (BOLT_CLANG_PRESENT AND BOLT_LLD_PRESENT)
  39     set(BOLT_INCLUDE_TESTS ON)
  40   else()
  41     message(WARNING "Not including BOLT tests since clang or lld is disabled. \
  42           Add clang and lld to LLVM_ENABLE_PROJECTS or provide paths to clang \
  43           and lld binaries in BOLT_CLANG_EXE and BOLT_LLD_EXE.")
  44   endif()
  45 endif()
  46
  47 if (BOLT_ENABLE_RUNTIME)
  48   message(STATUS "Building BOLT runtime libraries for X86")
  49   ExternalProject_Add(bolt_rt
  50     SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/runtime"
  51     STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/bolt_rt-stamps
  52     BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/bolt_rt-bins
  53     CMAKE_ARGS -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
  54                -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
  55                -DCMAKE_BUILD_TYPE=Release
  56                -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
  57                -DCMAKE_INSTALL_PREFIX=${LLVM_BINARY_DIR}
  58     BUILD_ALWAYS True
  59     )
  60   install(CODE "execute_process\(COMMAND \${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=\${CMAKE_INSTALL_PREFIX} -P ${CMAKE_CURRENT_BINARY_DIR}/bolt_rt-bins/cmake_install.cmake \)"
  61     COMPONENT bolt)
  62   add_llvm_install_targets(install-bolt_rt
  63     DEPENDS bolt_rt bolt
  64     COMPONENT bolt)
  65 endif()
  66
  67 find_program(GNU_LD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.bfd ld.bfd DOC "GNU ld")
  68
  69 include_directories(
  70   ${CMAKE_CURRENT_SOURCE_DIR}/include
  71   ${CMAKE_CURRENT_BINARY_DIR}/include
  72   )
  73
  74 add_subdirectory(lib)
  75 add_subdirectory(tools)
  76
  77 if (BOLT_INCLUDE_TESTS)
  78   if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
  79     add_subdirectory(unittests)
  80     list(APPEND BOLT_TEST_DEPS BoltUnitTests)
  81   endif()
  82   add_subdirectory(test)
  83 endif()
  84
  85 option(BOLT_INCLUDE_DOCS "Generate build targets for the BOLT docs."
  86        ${LLVM_INCLUDE_DOCS})
  87 if (BOLT_INCLUDE_DOCS)
  88   add_subdirectory(docs)
  89 endif()