libunwind/CMakeLists.txt

   1 #===============================================================================
   2 # Setup Project
   3 #===============================================================================
   4
   5 cmake_minimum_required(VERSION 3.20.0)
   6 set(LLVM_SUBPROJECT_TITLE "libunwind")
   7
   8 set(LLVM_COMMON_CMAKE_UTILS "${CMAKE_CURRENT_SOURCE_DIR}/../cmake")
   9
  10 # Add path for custom modules
  11 list(INSERT CMAKE_MODULE_PATH 0
  12   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  13   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
  14   "${CMAKE_CURRENT_SOURCE_DIR}/../runtimes/cmake/Modules"
  15   "${LLVM_COMMON_CMAKE_UTILS}"
  16   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  17   )
  18
  19 set(LIBUNWIND_SOURCE_DIR  ${CMAKE_CURRENT_SOURCE_DIR})
  20 set(LIBUNWIND_BINARY_DIR  ${CMAKE_CURRENT_BINARY_DIR})
  21 set(LIBUNWIND_LIBCXX_PATH "${CMAKE_CURRENT_LIST_DIR}/../libcxx" CACHE PATH
  22         "Specify path to libc++ source.")
  23
  24 include(GNUInstallDirs)
  25 include(CheckSymbolExists)
  26
  27 #===============================================================================
  28 # Setup CMake Options
  29 #===============================================================================
  30 include(CMakeDependentOption)
  31 include(HandleCompilerRT)
  32
  33 # Define options.
  34 option(LIBUNWIND_ENABLE_CET "Build libunwind with CET enabled." OFF)
  35 option(LIBUNWIND_ENABLE_GCS "Build libunwind with GCS enabled." OFF)
  36 option(LIBUNWIND_ENABLE_ASSERTIONS "Enable assertions independent of build mode." ON)
  37 option(LIBUNWIND_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
  38 option(LIBUNWIND_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
  39 option(LIBUNWIND_ENABLE_SHARED "Build libunwind as a shared library." ON)
  40 option(LIBUNWIND_ENABLE_STATIC "Build libunwind as a static library." ON)
  41 option(LIBUNWIND_ENABLE_CROSS_UNWINDING "Enable cross-platform unwinding support." OFF)
  42 option(LIBUNWIND_ENABLE_ARM_WMMX "Enable unwinding support for ARM WMMX registers." OFF)
  43 option(LIBUNWIND_ENABLE_THREADS "Build libunwind with threading support." ON)
  44 option(LIBUNWIND_WEAK_PTHREAD_LIB "Use weak references to refer to pthread functions." OFF)
  45 option(LIBUNWIND_USE_COMPILER_RT "Use compiler-rt instead of libgcc" OFF)
  46 option(LIBUNWIND_INCLUDE_DOCS "Build the libunwind documentation." ${LLVM_INCLUDE_DOCS})
  47 option(LIBUNWIND_INCLUDE_TESTS "Build the libunwind tests." ${LLVM_INCLUDE_TESTS})
  48 option(LIBUNWIND_IS_BAREMETAL "Build libunwind for baremetal targets." OFF)
  49 option(LIBUNWIND_USE_FRAME_HEADER_CACHE "Cache frame headers for unwinding. Requires locking dl_iterate_phdr." OFF)
  50 option(LIBUNWIND_REMEMBER_HEAP_ALLOC "Use heap instead of the stack for .cfi_remember_state." OFF)
  51 option(LIBUNWIND_INSTALL_HEADERS "Install the libunwind headers." ON)
  52 option(LIBUNWIND_ENABLE_FRAME_APIS "Include libgcc-compatible frame apis." OFF)
  53
  54 set(LIBUNWIND_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}" CACHE STRING
  55     "Define suffix of library directory name (32/64)")
  56 option(LIBUNWIND_INSTALL_LIBRARY "Install the libunwind library." ON)
  57 cmake_dependent_option(LIBUNWIND_INSTALL_STATIC_LIBRARY
  58   "Install the static libunwind library." ON
  59   "LIBUNWIND_ENABLE_STATIC;LIBUNWIND_INSTALL_LIBRARY" OFF)
  60 cmake_dependent_option(LIBUNWIND_INSTALL_SHARED_LIBRARY
  61   "Install the shared libunwind library." ON
  62   "LIBUNWIND_ENABLE_SHARED;LIBUNWIND_INSTALL_LIBRARY" OFF)
  63
  64 set(LIBUNWIND_LIBRARY_VERSION "1.0" CACHE STRING
  65   "Version of libunwind. This will be reflected in the name of the shared library produced.
  66    For example, -DLIBUNWIND_LIBRARY_VERSION=x.y will result in the library being named
  67    libunwind.x.y.dylib, along with the usual symlinks pointing to that. On Apple platforms,
  68    this also controls the linker's 'current_version' property.")
  69
  70 if(MINGW)
  71   if (LIBUNWIND_ENABLE_SHARED)
  72     set(LIBUNWIND_DEFAULT_TEST_CONFIG "llvm-libunwind-shared-mingw.cfg.in")
  73   else()
  74     set(LIBUNWIND_DEFAULT_TEST_CONFIG "llvm-libunwind-static-mingw.cfg.in")
  75   endif()
  76 elseif (LIBUNWIND_ENABLE_SHARED)
  77   set(LIBUNWIND_DEFAULT_TEST_CONFIG "llvm-libunwind-shared.cfg.in")
  78 else()
  79   set(LIBUNWIND_DEFAULT_TEST_CONFIG "llvm-libunwind-static.cfg.in")
  80 endif()
  81 set(LIBUNWIND_TEST_CONFIG "${LIBUNWIND_DEFAULT_TEST_CONFIG}" CACHE STRING
  82   "The path to the Lit testing configuration to use when running the tests.
  83    If a relative path is provided, it is assumed to be relative to '<monorepo>/libunwind/test/configs'.")
  84 if (NOT IS_ABSOLUTE "${LIBUNWIND_TEST_CONFIG}")
  85   set(LIBUNWIND_TEST_CONFIG "${CMAKE_CURRENT_SOURCE_DIR}/test/configs/${LIBUNWIND_TEST_CONFIG}")
  86 endif()
  87 message(STATUS "Using libunwind testing configuration: ${LIBUNWIND_TEST_CONFIG}")
  88 set(LIBUNWIND_TEST_PARAMS "" CACHE STRING
  89     "A list of parameters to run the Lit test suite with.")
  90
  91 if (NOT LIBUNWIND_ENABLE_SHARED AND NOT LIBUNWIND_ENABLE_STATIC)
  92   message(FATAL_ERROR "libunwind must be built as either a shared or static library.")
  93 endif()
  94
  95 if (LIBUNWIND_ENABLE_CET AND MSVC)
  96   message(FATAL_ERROR "libunwind CET support is not available for MSVC!")
  97 endif()
  98
  99 if (WIN32)
 100   set(LIBUNWIND_DEFAULT_HIDE_SYMBOLS TRUE)
 101 else()
 102   set(LIBUNWIND_DEFAULT_HIDE_SYMBOLS FALSE)
 103 endif()
 104 option(LIBUNWIND_HIDE_SYMBOLS
 105   "Do not export any symbols from the static library." ${LIBUNWIND_DEFAULT_HIDE_SYMBOLS})
 106
 107 # If toolchain is FPXX, we switch to FP64 to save the full FPRs. See:
 108 # https://web.archive.org/web/20180828210612/https://dmz-portal.mips.com/wiki/MIPS_O32_ABI_-_FR0_and_FR1_Interlinking
 109 check_symbol_exists(__mips_hard_float "" __MIPSHF)
 110 check_symbol_exists(_ABIO32 "" __MIPS_O32)
 111 if (__MIPSHF AND __MIPS_O32)
 112   file(WRITE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/mips_is_fpxx.c
 113     "#if __mips_fpr != 0\n"
 114     "# error\n"
 115     "#endif\n")
 116   try_compile(MIPS_FPABI_FPXX ${CMAKE_BINARY_DIR}
 117     ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/mips_is_fpxx.c
 118     CMAKE_FLAGS -DCMAKE_C_LINK_EXECUTABLE='echo')
 119 endif()
 120
 121 #===============================================================================
 122 # Configure System
 123 #===============================================================================
 124
 125 # Add path for custom modules
 126 set(CMAKE_MODULE_PATH
 127     "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 128     ${CMAKE_MODULE_PATH})
 129
 130 set(LIBUNWIND_INSTALL_INCLUDE_DIR "${CMAKE_INSTALL_INCLUDEDIR}" CACHE STRING
 131     "Path where built libunwind headers should be installed.")
 132 set(LIBUNWIND_INSTALL_RUNTIME_DIR "${CMAKE_INSTALL_BINDIR}" CACHE STRING
 133     "Path where built libunwind runtime libraries should be installed.")
 134
 135 set(LIBUNWIND_SHARED_OUTPUT_NAME "unwind" CACHE STRING "Output name for the shared libunwind runtime library.")
 136 set(LIBUNWIND_STATIC_OUTPUT_NAME "unwind" CACHE STRING "Output name for the static libunwind runtime library.")
 137
 138 if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
 139   set(LIBUNWIND_TARGET_SUBDIR ${LLVM_DEFAULT_TARGET_TRIPLE})
 140   if(LIBUNWIND_LIBDIR_SUBDIR)
 141     string(APPEND LIBUNWIND_TARGET_SUBDIR /${LIBUNWIND_LIBDIR_SUBDIR})
 142   endif()
 143   set(LIBUNWIND_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/${LIBUNWIND_TARGET_SUBDIR})
 144   set(LIBUNWIND_INSTALL_LIBRARY_DIR lib${LLVM_LIBDIR_SUFFIX}/${LIBUNWIND_TARGET_SUBDIR} CACHE STRING
 145       "Path where built libunwind libraries should be installed.")
 146   unset(LIBUNWIND_TARGET_SUBDIR)
 147 else()
 148   if(LLVM_LIBRARY_OUTPUT_INTDIR)
 149     set(LIBUNWIND_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 150   else()
 151     set(LIBUNWIND_LIBRARY_DIR ${CMAKE_BINARY_DIR}/lib${LIBUNWIND_LIBDIR_SUFFIX})
 152   endif()
 153   set(LIBUNWIND_INSTALL_LIBRARY_DIR lib${LIBUNWIND_LIBDIR_SUFFIX} CACHE STRING
 154       "Path where built libunwind libraries should be installed.")
 155 endif()
 156
 157 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
 158 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
 159 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
 160
 161 set(LIBUNWIND_C_FLAGS "")
 162 set(LIBUNWIND_CXX_FLAGS "")
 163 set(LIBUNWIND_COMPILE_FLAGS "")
 164 set(LIBUNWIND_LINK_FLAGS "")
 165 set(LIBUNWIND_ADDITIONAL_COMPILE_FLAGS "" CACHE STRING "See documentation for LIBCXX_ADDITIONAL_COMPILE_FLAGS")
 166 set(LIBUNWIND_ADDITIONAL_LIBRARIES "" CACHE STRING
 167     "Additional libraries libunwind is linked to which can be provided in cache")
 168
 169 # Include macros for adding and removing libunwind flags.
 170 include(HandleLibunwindFlags)
 171
 172 #===============================================================================
 173 # Setup Compiler Flags
 174 #===============================================================================
 175
 176 # Configure compiler.
 177 include(config-ix)
 178
 179 if (LIBUNWIND_USE_COMPILER_RT AND NOT LIBUNWIND_HAS_NODEFAULTLIBS_FLAG)
 180   list(APPEND LIBUNWIND_LINK_FLAGS "-rtlib=compiler-rt")
 181 endif()
 182
 183 add_compile_flags_if_supported(-Werror=return-type)
 184
 185 if (LIBUNWIND_ENABLE_CET)
 186   add_compile_flags_if_supported(-fcf-protection=full)
 187   add_compile_flags_if_supported(-mshstk)
 188   if (NOT CXX_SUPPORTS_FCF_PROTECTION_EQ_FULL_FLAG)
 189     message(SEND_ERROR "Compiler doesn't support CET -fcf-protection option!")
 190   endif()
 191   if (NOT CXX_SUPPORTS_MSHSTK_FLAG)
 192     message(SEND_ERROR "Compiler doesn't support CET -mshstk option!")
 193   endif()
 194 endif()
 195
 196 if (LIBUNWIND_ENABLE_GCS)
 197   add_compile_flags_if_supported(-mbranch-protection=standard)
 198   if (NOT CXX_SUPPORTS_MBRANCH_PROTECTION_EQ_STANDARD_FLAG)
 199     message(SEND_ERROR "Compiler doesn't support GCS -mbranch-protection option!")
 200   endif()
 201 endif()
 202
 203 if (WIN32)
 204   # The headers lack matching dllexport attributes (_LIBUNWIND_EXPORT);
 205   # silence the warning instead of cluttering the headers (which aren't
 206   # necessarily the ones that the callers will use anyway) with the
 207   # attributes.
 208   add_compile_flags_if_supported(-Wno-dll-attribute-on-redeclaration)
 209 endif()
 210
 211 if (MIPS_FPABI_FPXX)
 212   add_compile_flags(-mfp64)
 213 endif()
 214
 215 # Get feature flags.
 216 # Exceptions
 217 # Catches C++ exceptions only and tells the compiler to assume that extern C
 218 # functions never throw a C++ exception.
 219 add_cxx_compile_flags_if_supported(-fstrict-aliasing)
 220 add_cxx_compile_flags_if_supported(-EHsc)
 221
 222 # Don't run the linker in this CMake check.
 223 #
 224 # The reason why this was added is that when building libunwind for
 225 # ARM Linux, we need to pass the -funwind-tables flag in order for it to
 226 # work properly with ARM EHABI.
 227 #
 228 # However, when performing CMake checks, adding this flag causes the check
 229 # to produce a false negative, because the compiler generates calls
 230 # to __aeabi_unwind_cpp_pr0, which is defined in libunwind itself,
 231 # which isn't built yet, so the linker complains about undefined symbols.
 232 #
 233 # This leads to libunwind not being built with this flag, which makes
 234 # libunwind quite useless in this setup.
 235 set(_previous_CMAKE_TRY_COMPILE_TARGET_TYPE ${CMAKE_TRY_COMPILE_TARGET_TYPE})
 236 set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
 237 add_compile_flags_if_supported(-funwind-tables)
 238 set(CMAKE_TRY_COMPILE_TARGET_TYPE ${_previous_CMAKE_TRY_COMPILE_TARGET_TYPE})
 239
 240 if (LIBUNWIND_USES_ARM_EHABI AND NOT CXX_SUPPORTS_FUNWIND_TABLES_FLAG)
 241   message(SEND_ERROR "The -funwind-tables flag must be supported "
 242                      "because this target uses ARM Exception Handling ABI")
 243 endif()
 244
 245 add_cxx_compile_flags_if_supported(-fno-exceptions)
 246 add_cxx_compile_flags_if_supported(-fno-rtti)
 247
 248 # Ensure that we don't depend on C++ standard library.
 249 if (CXX_SUPPORTS_NOSTDINCXX_FLAG)
 250   list(APPEND LIBUNWIND_COMPILE_FLAGS -nostdinc++)
 251   # Remove -stdlib flags to prevent them from causing an unused flag warning.
 252   string(REPLACE "--stdlib=libc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 253   string(REPLACE "--stdlib=libstdc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 254   string(REPLACE "-stdlib=libc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 255   string(REPLACE "-stdlib=libstdc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 256 endif()
 257
 258 # Assert
 259 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 260 if (LIBUNWIND_ENABLE_ASSERTIONS)
 261   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
 262   if (NOT MSVC)
 263     add_compile_flags(-D_DEBUG)
 264   endif()
 265
 266   # On Release builds cmake automatically defines NDEBUG, so we
 267   # explicitly undefine it:
 268   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 269     add_compile_flags(-UNDEBUG)
 270   endif()
 271 else()
 272   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 273     add_compile_flags(-DNDEBUG)
 274   endif()
 275 endif()
 276
 277 # Cross-unwinding
 278 if (NOT LIBUNWIND_ENABLE_CROSS_UNWINDING)
 279   add_compile_flags(-D_LIBUNWIND_IS_NATIVE_ONLY)
 280 endif()
 281
 282 # Include stubs for __register_frame_info_bases and related
 283 if (LIBUNWIND_ENABLE_FRAME_APIS)
 284   add_compile_flags(-D_LIBUNWIND_SUPPORT_FRAME_APIS)
 285 endif()
 286
 287 # Threading-support
 288 if (NOT LIBUNWIND_ENABLE_THREADS)
 289   add_compile_flags(-D_LIBUNWIND_HAS_NO_THREADS)
 290 endif()
 291
 292 # ARM WMMX register support
 293 if (LIBUNWIND_ENABLE_ARM_WMMX)
 294   # __ARM_WMMX is a compiler pre-define (as per the ACLE 2.0). Clang does not
 295   # define this macro for any supported target at present. Therefore, here we
 296   # provide the option to explicitly enable support for WMMX registers in the
 297   # unwinder.
 298   add_compile_flags(-D__ARM_WMMX)
 299 endif()
 300
 301 if(LIBUNWIND_IS_BAREMETAL)
 302   add_compile_definitions(_LIBUNWIND_IS_BAREMETAL)
 303 endif()
 304
 305 if(LIBUNWIND_USE_FRAME_HEADER_CACHE)
 306   add_compile_definitions(_LIBUNWIND_USE_FRAME_HEADER_CACHE)
 307 endif()
 308
 309 if(LIBUNWIND_REMEMBER_HEAP_ALLOC)
 310   add_compile_definitions(_LIBUNWIND_REMEMBER_HEAP_ALLOC)
 311 endif()
 312
 313 # This is the _ONLY_ place where add_definitions is called.
 314 if (MSVC)
 315   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 316 endif()
 317
 318 if (C_SUPPORTS_COMMENT_LIB_PRAGMA)
 319   if (LIBUNWIND_HAS_DL_LIB)
 320     add_definitions(-D_LIBUNWIND_LINK_DL_LIB)
 321   endif()
 322   if (LIBUNWIND_HAS_PTHREAD_LIB)
 323     add_definitions(-D_LIBUNWIND_LINK_PTHREAD_LIB)
 324   endif()
 325 endif()
 326
 327 #===============================================================================
 328 # Setup Source Code
 329 #===============================================================================
 330
 331 add_subdirectory(include)
 332
 333 add_subdirectory(src)
 334
 335 if (LIBUNWIND_INCLUDE_DOCS)
 336   add_subdirectory(docs)
 337 endif()
 338
 339 if (LIBUNWIND_INCLUDE_TESTS AND EXISTS ${LLVM_CMAKE_DIR})
 340   add_subdirectory(test)
 341 endif()