compiler-rt/CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # An important constraint of the build is that it only produces libraries
   4 # based on the ability of the host toolchain to target various platforms.
   5
   6 cmake_minimum_required(VERSION 3.20.0)
   7
   8 # Check if compiler-rt is built as a standalone project.
   9 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR OR COMPILER_RT_STANDALONE_BUILD)
  10   project(CompilerRT C CXX ASM)
  11   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  12   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  13 endif()
  14
  15 set(LLVM_COMMON_CMAKE_UTILS "${CMAKE_CURRENT_SOURCE_DIR}/../cmake")
  16
  17 # Add path for custom compiler-rt modules.
  18 list(INSERT CMAKE_MODULE_PATH 0
  19   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  20   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
  21   "${LLVM_COMMON_CMAKE_UTILS}"
  22   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  23   )
  24
  25 if(CMAKE_CONFIGURATION_TYPES)
  26   set(CMAKE_CFG_RESOLVED_INTDIR "${CMAKE_CFG_INTDIR}/")
  27 else()
  28   set(CMAKE_CFG_RESOLVED_INTDIR "")
  29 endif()
  30
  31 include(SetPlatformToolchainTools)
  32 include(base-config-ix)
  33 include(CompilerRTUtils)
  34 include(CMakeDependentOption)
  35
  36 option(COMPILER_RT_BUILD_BUILTINS "Build builtins" ON)
  37 mark_as_advanced(COMPILER_RT_BUILD_BUILTINS)
  38 option(COMPILER_RT_DISABLE_AARCH64_FMV "Disable AArch64 Function Multi Versioning support" OFF)
  39 mark_as_advanced(COMPILER_RT_DISABLE_AARCH64_FMV)
  40 option(COMPILER_RT_BUILD_CRT "Build crtbegin.o/crtend.o" ON)
  41 mark_as_advanced(COMPILER_RT_BUILD_CRT)
  42 option(COMPILER_RT_CRT_USE_EH_FRAME_REGISTRY "Use eh_frame in crtbegin.o/crtend.o" ON)
  43 mark_as_advanced(COMPILER_RT_CRT_USE_EH_FRAME_REGISTRY)
  44 option(COMPILER_RT_BUILD_SANITIZERS "Build sanitizers" ON)
  45 mark_as_advanced(COMPILER_RT_BUILD_SANITIZERS)
  46 option(COMPILER_RT_BUILD_XRAY "Build xray" ON)
  47 mark_as_advanced(COMPILER_RT_BUILD_XRAY)
  48 option(COMPILER_RT_BUILD_LIBFUZZER "Build libFuzzer" ON)
  49 mark_as_advanced(COMPILER_RT_BUILD_LIBFUZZER)
  50 option(COMPILER_RT_BUILD_PROFILE "Build profile runtime" ON)
  51 mark_as_advanced(COMPILER_RT_BUILD_PROFILE)
  52 option(COMPILER_RT_BUILD_MEMPROF "Build memory profiling runtime" ON)
  53 mark_as_advanced(COMPILER_RT_BUILD_MEMPROF)
  54 option(COMPILER_RT_BUILD_XRAY_NO_PREINIT "Build xray with no preinit patching" OFF)
  55 mark_as_advanced(COMPILER_RT_BUILD_XRAY_NO_PREINIT)
  56 option(COMPILER_RT_BUILD_ORC "Build ORC runtime" ON)
  57 mark_as_advanced(COMPILER_RT_BUILD_ORC)
  58 option(COMPILER_RT_BUILD_GWP_ASAN "Build GWP-ASan, and link it into SCUDO" ON)
  59 mark_as_advanced(COMPILER_RT_BUILD_GWP_ASAN)
  60 option(COMPILER_RT_ENABLE_CET "Build Compiler RT with CET enabled" OFF)
  61
  62 option(COMPILER_RT_SCUDO_STANDALONE_SYSROOT_PATH "Set custom sysroot for building SCUDO standalone" OFF)
  63 mark_as_advanced(COMPILER_RT_SCUDO_STANDALONE_SYSROOT_PATH)
  64 option(COMPILER_RT_SCUDO_STANDALONE_BUILD_SHARED "Build SCUDO standalone for shared libraries" ON)
  65 mark_as_advanced(COMPILER_RT_SCUDO_STANDALONE_BUILD_SHARED)
  66 option(COMPILER_RT_BUILD_SCUDO_STANDALONE_WITH_LLVM_LIBC "Build SCUDO standalone with LLVM's libc headers" OFF)
  67 mark_as_advanced(COMPILER_RT_BUILD_SCUDO_STANDALONE_WITH_LLVM_LIBC)
  68
  69 if(FUCHSIA)
  70   set(COMPILER_RT_HWASAN_WITH_INTERCEPTORS_DEFAULT OFF)
  71 else()
  72   set(COMPILER_RT_HWASAN_WITH_INTERCEPTORS_DEFAULT ON)
  73 endif()
  74 set(COMPILER_RT_HWASAN_WITH_INTERCEPTORS ${COMPILER_RT_HWASAN_WITH_INTERCEPTORS_DEFAULT} CACHE BOOL "Enable libc interceptors in HWASan (testing mode)")
  75
  76 set(COMPILER_RT_BAREMETAL_BUILD OFF CACHE BOOL
  77   "Build for a bare-metal target.")
  78
  79 if (COMPILER_RT_STANDALONE_BUILD)
  80   set(CMAKE_CXX_STANDARD 17 CACHE STRING "C++ standard to conform to")
  81   set(CMAKE_CXX_STANDARD_REQUIRED YES)
  82   set(CMAKE_CXX_EXTENSIONS NO)
  83
  84   if (NOT LLVM_RUNTIMES_BUILD)
  85     load_llvm_config()
  86   endif()
  87   if (TARGET intrinsics_gen)
  88     # Loading the llvm config causes this target to be imported so place it
  89     # under the appropriate folder in an IDE.
  90     set_target_properties(intrinsics_gen PROPERTIES FOLDER "Compiler-RT Misc")
  91   endif()
  92
  93   find_package(Python3 COMPONENTS Interpreter)
  94   if(NOT Python3_Interpreter_FOUND)
  95     message(WARNING "Python3 not found, using python2 as a fallback")
  96     find_package(Python2 COMPONENTS Interpreter REQUIRED)
  97     if(Python2_VERSION VERSION_LESS 2.7)
  98       message(SEND_ERROR "Python 2.7 or newer is required")
  99     endif()
 100
 101     # Treat python2 as python3
 102     add_executable(Python3::Interpreter IMPORTED)
 103     set_target_properties(Python3::Interpreter PROPERTIES
 104       IMPORTED_LOCATION ${Python2_EXECUTABLE})
 105     set(Python3_EXECUTABLE ${Python2_EXECUTABLE})
 106   endif()
 107
 108   # Ensure that fat libraries are built correctly on Darwin
 109   if(APPLE)
 110     include(UseLibtool)
 111   endif()
 112
 113   # Define default arguments to lit.
 114   set(LIT_ARGS_DEFAULT "-sv")
 115   if (MSVC OR XCODE)
 116     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 117   endif()
 118   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 119   set(LLVM_LIT_OUTPUT_DIR "${COMPILER_RT_EXEC_OUTPUT_DIR}")
 120 endif()
 121
 122 construct_compiler_rt_default_triple()
 123 if ("${COMPILER_RT_DEFAULT_TARGET_TRIPLE}" MATCHES ".*hf$")
 124   if (${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "^arm")
 125     set(COMPILER_RT_DEFAULT_TARGET_ARCH "armhf")
 126     CHECK_SYMBOL_EXISTS (__thumb__ "" COMPILER_RT_ARM_THUMB)
 127   endif()
 128 endif()
 129 if (${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "^mips")
 130   CHECK_SYMBOL_EXISTS (_MIPS_ARCH_MIPS32R6 "" COMPILER_RT_MIPS32R6)
 131   CHECK_SYMBOL_EXISTS (_MIPS_ARCH_MIPS64R6 "" COMPILER_RT_MIPS64R6)
 132   CHECK_SYMBOL_EXISTS (__mips64 "" COMPILER_RT_MIPS_64)
 133   CHECK_SYMBOL_EXISTS (__MIPSEL__ "" COMPILER_RT_MIPS_EL)
 134   if ("${COMPILER_RT_MIPS_64}")
 135     set(COMPILER_RT_DEFAULT_TARGET_ARCH "mips64")
 136   else()
 137     set(COMPILER_RT_DEFAULT_TARGET_ARCH "mips")
 138   endif()
 139   if ("${COMPILER_RT_MIPS_EL}")
 140     set(COMPILER_RT_DEFAULT_TARGET_ARCH "${COMPILER_RT_DEFAULT_TARGET_ARCH}el")
 141   endif()
 142 endif()
 143 if ("${COMPILER_RT_DEFAULT_TARGET_TRIPLE}" MATCHES ".*android.*")
 144   set(ANDROID 1)
 145   string(REGEX MATCH "-target(=| +)[^ ]+android[a-z]*([0-9]+)" ANDROID_API_LEVEL "${CMAKE_C_FLAGS}")
 146   set(ANDROID_API_LEVEL ${CMAKE_MATCH_2})
 147 endif()
 148 pythonize_bool(ANDROID)
 149
 150 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 151 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 152
 153 pythonize_bool(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR)
 154
 155 # We support running instrumented tests when we're not cross-compiling
 156 # and target a UNIX-like system or Windows.
 157 # We can run tests on Android even when we are cross-compiling.
 158 if((NOT "${CMAKE_CROSSCOMPILING}" AND (UNIX OR WIN32))
 159    OR ANDROID OR COMPILER_RT_EMULATOR)
 160   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 161 else()
 162   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 163 endif()
 164
 165 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 166 option(COMPILER_RT_EXTERNALIZE_DEBUGINFO
 167   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 168 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 169 pythonize_bool(COMPILER_RT_DEBUG)
 170
 171 option(COMPILER_RT_INTERCEPT_LIBDISPATCH
 172   "Support interception of libdispatch (GCD). Requires '-fblocks'" OFF)
 173 option(COMPILER_RT_LIBDISPATCH_INSTALL_PATH
 174   "Specify if libdispatch is installed in a custom location" "")
 175 if (COMPILER_RT_INTERCEPT_LIBDISPATCH AND NOT APPLE)
 176   set(COMPILER_RT_LIBDISPATCH_CFLAGS -fblocks)
 177   set(COMPILER_RT_TEST_LIBDISPATCH_CFLAGS)
 178   if (COMPILER_RT_LIBDISPATCH_INSTALL_PATH)
 179     list(APPEND COMPILER_RT_TEST_LIBDISPATCH_CFLAGS
 180         -I${COMPILER_RT_LIBDISPATCH_INSTALL_PATH}/include
 181         -L${COMPILER_RT_LIBDISPATCH_INSTALL_PATH}/lib
 182         -Wl,-rpath=${COMPILER_RT_LIBDISPATCH_INSTALL_PATH}/lib)
 183   endif()
 184   list(APPEND COMPILER_RT_TEST_LIBDISPATCH_CFLAGS -lBlocksRuntime -ldispatch)
 185 endif()
 186 if (APPLE) # Always enable on Apple platforms.
 187   set(COMPILER_RT_INTERCEPT_LIBDISPATCH ON)
 188 endif()
 189 pythonize_bool(COMPILER_RT_INTERCEPT_LIBDISPATCH)
 190
 191 if(APPLE AND SANITIZER_MIN_OSX_VERSION AND SANITIZER_MIN_OSX_VERSION VERSION_LESS "10.9")
 192   # Mac OS X prior to 10.9 had problems with exporting symbols from
 193   # libc++/libc++abi.
 194   set(cxxabi_supported OFF)
 195 else()
 196   set(cxxabi_supported ON)
 197 endif()
 198
 199 option(SANITIZER_ALLOW_CXXABI "Allow use of C++ ABI details in ubsan" ON)
 200
 201 set(SANITIZER_CAN_USE_CXXABI OFF)
 202 if (cxxabi_supported AND SANITIZER_ALLOW_CXXABI)
 203   set(SANITIZER_CAN_USE_CXXABI ON)
 204 endif()
 205 pythonize_bool(SANITIZER_CAN_USE_CXXABI)
 206
 207 macro(handle_default_cxx_lib var)
 208   # Specifying -stdlib= in CMAKE_CXX_FLAGS overrides the defaults.
 209   if (CMAKE_CXX_FLAGS MATCHES "-stdlib=([a-zA-Z+]*)")
 210     set(${var}_LIBNAME "${CMAKE_MATCH_1}")
 211     set(${var}_SYSTEM 1)
 212   elseif (${var} STREQUAL "default")
 213     if (APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 214       set(${var}_LIBNAME "libc++")
 215       set(${var}_SYSTEM 1)
 216     elseif (FUCHSIA)
 217       set(${var}_LIBNAME "libc++")
 218       set(${var}_INTREE 1)
 219     else()
 220       set(${var}_LIBNAME "libstdc++")
 221       set(${var}_SYSTEM 1)
 222     endif()
 223   else()
 224     set(${var}_LIBNAME "${${var}}")
 225     set(${var}_SYSTEM 1)
 226   endif()
 227 endmacro()
 228
 229 # This is either directly the C++ ABI library or the full C++ library
 230 # which pulls in the ABI transitively.
 231 # TODO: Mark this as internal flag, most users should use COMPILER_RT_CXX_LIBRARY.
 232 set(SANITIZER_CXX_ABI "default" CACHE STRING
 233     "Specify C++ ABI library to use.")
 234 set(CXXABIS none default libstdc++ libc++ libcxxabi)
 235 set_property(CACHE SANITIZER_CXX_ABI PROPERTY STRINGS ;${CXXABIS})
 236 handle_default_cxx_lib(SANITIZER_CXX_ABI)
 237
 238 # This needs to be a full C++ library for linking gtest and unit tests.
 239 # TODO: Mark this as internal flag, most users should use COMPILER_RT_CXX_LIBRARY.
 240 set(SANITIZER_TEST_CXX "default" CACHE STRING
 241     "Specify C++ library to use for tests.")
 242 set(CXXLIBS none default libstdc++ libc++)
 243 set_property(CACHE SANITIZER_TEST_CXX PROPERTY STRINGS ;${CXXLIBS})
 244 handle_default_cxx_lib(SANITIZER_TEST_CXX)
 245
 246 option(COMPILER_RT_USE_LLVM_UNWINDER "Use the LLVM unwinder." OFF)
 247 cmake_dependent_option(COMPILER_RT_ENABLE_STATIC_UNWINDER
 248   "Statically link the LLVM unwinder." OFF
 249   "COMPILER_RT_USE_LLVM_UNWINDER" OFF)
 250
 251 set(DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER OFF)
 252 if (FUCHSIA)
 253   set(DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER ON)
 254 elseif (DEFINED LIBUNWIND_ENABLE_SHARED AND NOT LIBUNWIND_ENABLE_SHARED)
 255   set(DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER ON)
 256 endif()
 257
 258 option(SANITIZER_USE_STATIC_LLVM_UNWINDER
 259   "Use static LLVM unwinder." ${DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER})
 260 pythonize_bool(SANITIZER_USE_STATIC_LLVM_UNWINDER)
 261
 262 set(DEFAULT_SANITIZER_USE_STATIC_CXX_ABI OFF)
 263 if (DEFINED LIBCXXABI_ENABLE_SHARED AND NOT LIBCXXABI_ENABLE_SHARED)
 264   set(DEFAULT_SANITIZER_USE_STATIC_CXX_ABI ON)
 265 endif()
 266
 267 option(SANITIZER_USE_STATIC_CXX_ABI
 268   "Use static libc++abi." ${DEFAULT_SANITIZER_USE_STATIC_CXX_ABI})
 269 pythonize_bool(SANITIZER_USE_STATIC_CXX_ABI)
 270
 271 set(DEFAULT_SANITIZER_USE_STATIC_TEST_CXX OFF)
 272 if (DEFINED LIBCXX_ENABLE_SHARED AND NOT LIBCXX_ENABLE_SHARED)
 273   set(DEFAULT_SANITIZER_USE_STATIC_TEST_CXX ON)
 274 endif()
 275
 276 option(SANITIZER_USE_STATIC_TEST_CXX
 277   "Use static libc++ for tests." ${DEFAULT_SANITIZER_USE_STATIC_TEST_CXX})
 278 pythonize_bool(SANITIZER_USE_STATIC_TEST_CXX)
 279
 280 set(COMPILER_RT_SUPPORTED_CXX_LIBRARIES none default libcxx)
 281 set(COMPILER_RT_CXX_LIBRARY "default" CACHE STRING "Specify C++ library to use. Supported values are ${COMPILER_RT_SUPPORTED_CXX_LIBRARIES}.")
 282 if (NOT "${COMPILER_RT_CXX_LIBRARY}" IN_LIST COMPILER_RT_SUPPORTED_CXX_LIBRARIES)
 283   message(FATAL_ERROR "Unsupported C++ library: '${COMPILER_RT_CXX_LIBRARY}'. Supported values are ${COMPILER_RT_SUPPORTED_CXX_LIBRARIES}.")
 284 endif()
 285 cmake_dependent_option(COMPILER_RT_STATIC_CXX_LIBRARY
 286   "Statically link the C++ library." OFF
 287   "COMPILER_RT_CXX_LIBRARY" OFF)
 288
 289 set(DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY OFF)
 290 if (FUCHSIA)
 291   set(DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY ON)
 292 endif()
 293
 294 option(COMPILER_RT_USE_BUILTINS_LIBRARY
 295   "Use compiler-rt builtins instead of libgcc" ${DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY})
 296
 297 include(config-ix)
 298
 299 #================================
 300 # Setup Compiler Flags
 301 #================================
 302
 303 # fcf-protection is a gcc/clang option for CET support on Linux platforms.
 304 # We need to handle MSVC CET option on Windows platforms.
 305 if (NOT MSVC)
 306   if (COMPILER_RT_ENABLE_CET AND NOT COMPILER_RT_HAS_FCF_PROTECTION_FLAG)
 307     message(FATAL_ERROR "Compiler used to build compiler-rt doesn't support CET!")
 308   endif()
 309 endif()
 310
 311 if(MSVC)
 312   # Override any existing /W flags with /W4. This is what LLVM does.  Failing to
 313   # remove other /W[0-4] flags will result in a warning about overriding a
 314   # previous flag.
 315   if (COMPILER_RT_HAS_W4_FLAG)
 316     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 317     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 318     append_string_if(COMPILER_RT_HAS_W4_FLAG /W4 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 319   endif()
 320 else()
 321   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 322 endif()
 323 if(COMPILER_RT_ENABLE_WERROR)
 324   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 325   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 326 endif()
 327
 328 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 329 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 330   add_definitions(-D__func__=__FUNCTION__)
 331 endif()
 332
 333 # Provide some common commandline flags for Sanitizer runtimes.
 334 if("${ANDROID_API_LEVEL}" GREATER_EQUAL 29)
 335   list(APPEND SANITIZER_COMMON_CFLAGS -fno-emulated-tls)
 336   string(APPEND COMPILER_RT_TEST_COMPILER_CFLAGS " -fno-emulated-tls")
 337 endif()
 338 if(NOT WIN32)
 339   append_list_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 340 endif()
 341 append_list_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 342 append_list_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 343 if(NOT COMPILER_RT_DEBUG AND NOT APPLE)
 344   append_list_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 345 endif()
 346 append_list_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 347 append_list_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 348 append_list_if(COMPILER_RT_HAS_FNO_SANITIZE_SAFE_STACK_FLAG -fno-sanitize=safe-stack SANITIZER_COMMON_CFLAGS)
 349 append_list_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 350 if(NOT COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG)
 351   append_list_if(COMPILER_RT_HAS_FVISIBILITY_INLINES_HIDDEN_FLAG -fvisibility-inlines-hidden SANITIZER_COMMON_CFLAGS)
 352 endif()
 353 append_list_if(COMPILER_RT_HAS_FNO_LTO_FLAG -fno-lto SANITIZER_COMMON_CFLAGS)
 354
 355 # By default do not instrument or use profdata for compiler-rt.
 356 if(NOT COMPILER_RT_ENABLE_PGO)
 357   if(LLVM_PROFDATA_FILE AND COMPILER_RT_HAS_FNO_PROFILE_INSTR_USE_FLAG)
 358     list(APPEND SANITIZER_COMMON_CFLAGS "-fno-profile-instr-use")
 359   endif()
 360   if(LLVM_BUILD_INSTRUMENTED MATCHES IR AND COMPILER_RT_HAS_FNO_PROFILE_GENERATE_FLAG)
 361     list(APPEND SANITIZER_COMMON_CFLAGS "-fno-profile-generate")
 362   elseif((LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE) AND COMPILER_RT_HAS_FNO_PROFILE_INSTR_GENERATE_FLAG)
 363     list(APPEND SANITIZER_COMMON_CFLAGS "-fno-profile-instr-generate")
 364     if(LLVM_BUILD_INSTRUMENTED_COVERAGE AND COMPILER_RT_HAS_FNO_COVERAGE_MAPPING_FLAG)
 365       list(APPEND SANITIZER_COMMON_CFLAGS "-fno-coverage-mapping")
 366     endif()
 367   endif()
 368 endif()
 369
 370 # The following is a workaround for powerpc64le. This is the only architecture
 371 # that requires -fno-function-sections to work properly. If lacking, the ASan
 372 # Linux test function-sections-are-bad.cpp fails with the following error:
 373 # 'undefined symbol: __sanitizer_unaligned_load32'.
 374 if(DEFINED TARGET_powerpc64le_CFLAGS)
 375   if(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 376     append("-qnofuncsect" TARGET_powerpc64le_CFLAGS)
 377   else()
 378     append_list_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections TARGET_powerpc64le_CFLAGS)
 379   endif()
 380 endif()
 381
 382 # The following is a workaround for s390x.  This avoids creation of "partial
 383 # inline" function fragments when building the asan libraries with certain
 384 # GCC versions.  The presence of those fragments, in particular for the
 385 # interceptors, changes backtraces seen in asan error cases, which causes
 386 # testsuite failures.
 387 if("${COMPILER_RT_DEFAULT_TARGET_ARCH}" MATCHES "s390x")
 388   append_list_if(COMPILER_RT_HAS_FNO_PARTIAL_INLINING_FLAG -fno-partial-inlining SANITIZER_COMMON_CFLAGS)
 389 endif()
 390
 391 if(MSVC)
 392   # Replace the /M[DT][d] flags with /MT, and strip any definitions of _DEBUG,
 393   # which cause definition mismatches at link time.
 394   # FIXME: In fact, sanitizers should support both /MT and /MD, see PR20214.
 395   if(COMPILER_RT_HAS_MT_FLAG)
 396     foreach(flag_var
 397       CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 398       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 399       CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 400       CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 401       string(REGEX REPLACE "/M[DT]d" "/MT" ${flag_var} "${${flag_var}}")
 402       string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 403       string(REGEX REPLACE "/D_DEBUG" "" ${flag_var} "${${flag_var}}")
 404     endforeach()
 405   endif()
 406   append_list_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 407   append_list_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 408
 409   # Disable thread safe initialization for static locals. ASan shouldn't need
 410   # it. Thread safe initialization assumes that the CRT has already been
 411   # initialized, but ASan initializes before the CRT.
 412   list(APPEND SANITIZER_COMMON_CFLAGS /Zc:threadSafeInit-)
 413 endif()
 414
 415 append_list_if(COMPILER_RT_DEBUG -DSANITIZER_DEBUG=1 SANITIZER_COMMON_CFLAGS)
 416
 417 append_list_if(COMPILER_RT_HAS_WTHREAD_SAFETY_FLAG -Wthread-safety THREAD_SAFETY_FLAGS)
 418 append_list_if(COMPILER_RT_HAS_WTHREAD_SAFETY_REFERENCE_FLAG -Wthread-safety-reference THREAD_SAFETY_FLAGS)
 419 append_list_if(COMPILER_RT_HAS_WTHREAD_SAFETY_BETA_FLAG -Wthread-safety-beta THREAD_SAFETY_FLAGS)
 420 list(APPEND SANITIZER_COMMON_CFLAGS ${THREAD_SAFETY_FLAGS})
 421 string(REPLACE ";" " " thread_safety_flags_space_sep "${THREAD_SAFETY_FLAGS}")
 422 string(APPEND COMPILER_RT_TEST_COMPILER_CFLAGS " ${thread_safety_flags_space_sep}")
 423
 424 # If we're using MSVC,
 425 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 426 if (NOT MSVC)
 427
 428   # Build with optimization, unless we're in debug mode.
 429   if(COMPILER_RT_DEBUG)
 430     list(APPEND SANITIZER_COMMON_CFLAGS -O1)
 431   else()
 432     list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 433   endif()
 434 endif()
 435
 436 # Determine if we should restrict stack frame sizes.
 437 # Stack frames on PowerPC, Mips, SystemZ and in debug build can be much larger than
 438 # anticipated.
 439 # FIXME: Fix all sanitizers and add -Wframe-larger-than to
 440 # SANITIZER_COMMON_FLAGS
 441 if(COMPILER_RT_HAS_WFRAME_LARGER_THAN_FLAG AND NOT COMPILER_RT_DEBUG
 442    AND NOT ${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "powerpc|mips|s390x")
 443   set(SANITIZER_LIMIT_FRAME_SIZE TRUE)
 444 else()
 445   set(SANITIZER_LIMIT_FRAME_SIZE FALSE)
 446 endif()
 447
 448 if(FUCHSIA OR UNIX)
 449   set(SANITIZER_USE_SYMBOLS TRUE)
 450 else()
 451   set(SANITIZER_USE_SYMBOLS FALSE)
 452 endif()
 453
 454 # Build sanitizer runtimes with debug info.
 455 if(MSVC)
 456   # Use /Z7 instead of /Zi for the asan runtime. This avoids the LNK4099
 457   # warning from the MS linker complaining that it can't find the 'vc140.pdb'
 458   # file used by our object library compilations.
 459   list(APPEND SANITIZER_COMMON_CFLAGS /Z7)
 460   foreach(var_to_update
 461     CMAKE_CXX_FLAGS
 462     CMAKE_CXX_FLAGS_DEBUG
 463     CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 464     string(REGEX REPLACE "(^| )/Z[i7I]($| )" " /Z7 "
 465            "${var_to_update}" "${${var_to_update}}")
 466   endforeach()
 467 elseif(APPLE)
 468   # On Apple platforms use full debug info (i.e. not `-gline-tables-only`)
 469   # for all build types so that the runtime can be debugged.
 470   if(NOT COMPILER_RT_HAS_G_FLAG)
 471     message(FATAL_ERROR "-g is not supported by host compiler")
 472   endif()
 473   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 474 elseif(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG AND NOT COMPILER_RT_DEBUG)
 475   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 476 elseif(COMPILER_RT_HAS_G_FLAG)
 477   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 478 endif()
 479
 480 if(LLVM_ENABLE_MODULES)
 481   # Sanitizers cannot be built with -fmodules. The interceptors intentionally
 482   # don't include system headers, which is incompatible with modules.
 483   list(APPEND SANITIZER_COMMON_CFLAGS -fno-modules)
 484 endif()
 485
 486 # Turn off several warnings.
 487 append_list_if(COMPILER_RT_HAS_WGNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 488 append_list_if(COMPILER_RT_HAS_WVARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 489 append_list_if(COMPILER_RT_HAS_WC99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 490 # format-pedantic warns about passing T* for %p, which is not useful.
 491 append_list_if(COMPILER_RT_HAS_WD4146_FLAG /wd4146 SANITIZER_COMMON_CFLAGS)
 492 append_list_if(COMPILER_RT_HAS_WD4291_FLAG /wd4291 SANITIZER_COMMON_CFLAGS)
 493 append_list_if(COMPILER_RT_HAS_WD4391_FLAG /wd4391 SANITIZER_COMMON_CFLAGS)
 494 append_list_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 495 append_list_if(COMPILER_RT_HAS_WD4800_FLAG /wd4800 SANITIZER_COMMON_CFLAGS)
 496
 497 append_list_if(MINGW -fms-extensions SANITIZER_COMMON_CFLAGS)
 498
 499 # When lsan scans the stack for detecting reachable pointers, it's possible for
 500 # a leaked pointer, which was pushed to the stack on an earlier function call,
 501 # to still exist on the stack when doing a leak check if that part of the stack
 502 # was not overwritten. In particular, if there's any uninitialized data in the
 503 # lsan runtime, and the SP we start from is sufficiently deep into the runtime,
 504 # then a leaked pointer could be marked as reachable. Such instances could be
 505 # mitigated by clobbering any uninitialized data. Note that this won't cover
 506 # all possible uninitialized stack contents, such as those used for register
 507 # spill slots, unused portions for alignment, or even local variables not
 508 # yet in scope at a certain point in the function.
 509 #
 510 # Note that this type of issue was discovered with lsan, but can apply to other
 511 # sanitizers.
 512 append_list_if(COMPILER_RT_HAS_TRIVIAL_AUTO_INIT -ftrivial-auto-var-init=pattern SANITIZER_COMMON_CFLAGS)
 513
 514 # Set common link flags.
 515 # TODO: We should consider using the same model as libc++, that is use either
 516 # -nostdlib++ and --unwindlib=none if supported, or -nodefaultlibs otherwise.
 517 append_list_if(C_SUPPORTS_NODEFAULTLIBS_FLAG -nodefaultlibs SANITIZER_COMMON_LINK_FLAGS)
 518 append_list_if(COMPILER_RT_HAS_Z_TEXT -Wl,-z,text SANITIZER_COMMON_LINK_FLAGS)
 519
 520 # Only necessary for 32-bit SPARC.  Solaris 11.2+ ld uses -z ignore/-z record
 521 # natively, but supports --as-needed/--no-as-needed for GNU ld compatibility.
 522 if("${COMPILER_RT_DEFAULT_TARGET_ARCH}" MATCHES "sparc")
 523   list(APPEND SANITIZER_COMMON_LINK_LIBS -Wl,--as-needed atomic -Wl,--no-as-needed)
 524 endif()
 525
 526 if (COMPILER_RT_USE_BUILTINS_LIBRARY)
 527   string(REPLACE "-Wl,-z,defs" "" CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS}")
 528 else()
 529   if (ANDROID)
 530     append_list_if(COMPILER_RT_HAS_GCC_LIB gcc SANITIZER_COMMON_LINK_LIBS)
 531   else()
 532     append_list_if(COMPILER_RT_HAS_GCC_S_LIB gcc_s SANITIZER_COMMON_LINK_LIBS)
 533   endif()
 534 endif()
 535
 536 append_list_if(COMPILER_RT_HAS_LIBC c SANITIZER_COMMON_LINK_LIBS)
 537 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Fuchsia")
 538   list(APPEND SANITIZER_COMMON_LINK_LIBS zircon)
 539 endif()
 540
 541 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Fuchsia")
 542   set(SANITIZER_NO_UNDEFINED_SYMBOLS_DEFAULT ON)
 543 else()
 544   set(SANITIZER_NO_UNDEFINED_SYMBOLS_DEFAULT OFF)
 545 endif()
 546 option(SANITIZER_NO_UNDEFINED_SYMBOLS "Report error on unresolved symbol references" ${SANITIZER_NO_UNDEFINED_SYMBOLS_DEFAULT})
 547 if (SANITIZER_NO_UNDEFINED_SYMBOLS)
 548   list(APPEND SANITIZER_COMMON_LINK_FLAGS -Wl,-z,defs)
 549 endif()
 550
 551 # TODO: COMPILER_RT_COMMON_CFLAGS and COMPILER_RT_COMMON_LINK_FLAGS are
 552 # intended for use in non-sanitizer runtimes such as libFuzzer, profile or XRay,
 553 # move these higher to include common flags, then derive SANITIZER_COMMON_CFLAGS
 554 # and SANITIZER_COMMON_LINK_FLAGS from those and append sanitizer-specific flags.
 555 set(COMPILER_RT_COMMON_CFLAGS ${SANITIZER_COMMON_CFLAGS})
 556 set(COMPILER_RT_COMMON_LINK_FLAGS ${SANITIZER_COMMON_LINK_FLAGS})
 557
 558 # We don't use the C++ standard library, so avoid including it by mistake.
 559 append_list_if(COMPILER_RT_HAS_NOSTDINCXX_FLAG -nostdinc++ SANITIZER_COMMON_CFLAGS)
 560 append_list_if(COMPILER_RT_HAS_NOSTDLIBXX_FLAG -nostdlib++ SANITIZER_COMMON_LINK_FLAGS)
 561
 562 # Remove -stdlib= which is unused when passing -nostdinc++...
 563 string(REGEX MATCHALL "-stdlib=[a-zA-Z+]*" stdlib_flag "${CMAKE_CXX_FLAGS}")
 564 string(REGEX REPLACE "-stdlib=[a-zA-Z+]*" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 565
 566 # ...we need it to build some runtimes and tests so readd it where appropriate.
 567 list(APPEND COMPILER_RT_COMMON_CFLAGS ${stdlib_flag})
 568 list(APPEND COMPILER_RT_COMMON_LINK_FLAGS ${stdlib_flag})
 569
 570 # TODO: There's a lot of duplication across lib/*/tests/CMakeLists.txt files,
 571 # move some of the common flags to COMPILER_RT_UNITTEST_CFLAGS.
 572
 573 # Unittests need access to C++ standard library.
 574 string(APPEND COMPILER_RT_TEST_COMPILER_CFLAGS " ${stdlib_flag}")
 575
 576 # When cross-compiling, COMPILER_RT_TEST_COMPILER_CFLAGS help in compilation
 577 # and linking of unittests.
 578 string(REPLACE " " ";" COMPILER_RT_UNITTEST_CFLAGS "${COMPILER_RT_TEST_COMPILER_CFLAGS}")
 579 set(COMPILER_RT_UNITTEST_LINK_FLAGS ${COMPILER_RT_UNITTEST_CFLAGS})
 580
 581 if(COMPILER_RT_USE_LLVM_UNWINDER)
 582   # We're linking directly against the libunwind that we're building so don't
 583   # try to link in the toolchain's default libunwind which may be missing.
 584   append_list_if(CXX_SUPPORTS_UNWINDLIB_NONE_FLAG --unwindlib=none COMPILER_RT_COMMON_LINK_FLAGS)
 585   append_list_if(CXX_SUPPORTS_UNWINDLIB_NONE_FLAG --unwindlib=none COMPILER_RT_UNITTEST_LINK_FLAGS)
 586   if (COMPILER_RT_ENABLE_STATIC_UNWINDER)
 587     list(APPEND COMPILER_RT_UNWINDER_LINK_LIBS "$<TARGET_LINKER_FILE:unwind_static>")
 588   else()
 589     list(APPEND COMPILER_RT_UNWINDER_LINK_LIBS "$<TARGET_LINKER_FILE:$<IF:$<TARGET_EXISTS:unwind_shared>,unwind_shared,unwind_static>>")
 590   endif()
 591 endif()
 592
 593 if (COMPILER_RT_CXX_LIBRARY STREQUAL "libcxx")
 594   # We are using the in-tree libc++ so avoid including the default one.
 595   append_list_if(COMPILER_RT_HAS_NOSTDINCXX_FLAG -nostdinc++ COMPILER_RT_COMMON_CFLAGS)
 596   append_list_if(COMPILER_RT_HAS_NOSTDLIBXX_FLAG -nostdlib++ COMPILER_RT_COMMON_LINK_FLAGS)
 597   # Use the in-tree libc++ through explicit include and library paths.
 598   set(COMPILER_RT_CXX_CFLAGS "$<$<TARGET_EXISTS:cxx-headers>:$<IF:$<BOOL:${MSVC}>,/imsvc,-isystem>$<JOIN:$<TARGET_PROPERTY:cxx-headers,INTERFACE_INCLUDE_DIRECTORIES>,$<SEMICOLON>$<IF:$<BOOL:${MSVC}>,/imsvc,-isystem>>>")
 599   if (COMPILER_RT_STATIC_CXX_LIBRARY)
 600     set(COMPILER_RT_CXX_LINK_LIBS "$<TARGET_LINKER_FILE:cxx_static>")
 601   else()
 602     set(COMPILER_RT_CXX_LINK_LIBS "$<TARGET_LINKER_FILE:$<IF:$<TARGET_EXISTS:cxx_shared>,cxx_shared,cxx_static>>")
 603   endif()
 604 elseif (COMPILER_RT_CXX_LIBRARY STREQUAL "none")
 605   # We aren't using any C++ standard library so avoid including the default one.
 606   append_list_if(COMPILER_RT_HAS_NOSTDINCXX_FLAG -nostdinc++ COMPILER_RT_COMMON_CFLAGS)
 607   append_list_if(COMPILER_RT_HAS_NOSTDLIBXX_FLAG -nostdlib++ COMPILER_RT_COMMON_LINK_FLAGS)
 608 else()
 609   # Nothing to be done for `default`.
 610 endif()
 611
 612 if (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libc++")
 613   if (SANITIZER_CXX_ABI_INTREE)
 614     # TODO: We don't need to add --unwindlib=none to SANITIZER_COMMON_LINK_FLAGS
 615     # because we added -nodefaultlibs there earlier, and adding would result in
 616     # a warning, but if we switch to -nostdlib++, we would need to add it here.
 617     # append_list_if(CXX_SUPPORTS_UNWINDLIB_NONE_FLAG --unwindlib=none SANITIZER_COMMON_LINK_FLAGS)
 618     if(SANITIZER_USE_STATIC_CXX_ABI)
 619       if(TARGET libcxx-abi-static)
 620         set(SANITIZER_CXX_ABI_LIBRARIES libcxx-abi-static)
 621       endif()
 622     else()
 623       if(TARGET libcxx-abi-shared)
 624         set(SANITIZER_CXX_ABI_LIBRARIES libcxx-abi-shared)
 625       elseif(TARGET libcxx-abi-static)
 626         set(SANITIZER_CXX_ABI_LIBRARIES libcxx-abi-static)
 627       endif()
 628     endif()
 629   else()
 630     append_list_if(COMPILER_RT_HAS_LIBCXX c++ SANITIZER_CXX_ABI_LIBRARIES)
 631   endif()
 632 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libcxxabi")
 633   list(APPEND SANITIZER_CXX_ABI_LIBRARIES "c++abi")
 634 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libstdc++")
 635   append_list_if(COMPILER_RT_HAS_LIBSTDCXX stdc++ SANITIZER_CXX_ABI_LIBRARIES)
 636 endif()
 637
 638 if (SANITIZER_TEST_CXX_LIBNAME STREQUAL "libc++")
 639   if (SANITIZER_TEST_CXX_INTREE)
 640     list(APPEND SANITIZER_TEST_CXX_CFLAGS "$<$<TARGET_EXISTS:cxx-headers>:$<IF:$<BOOL:${MSVC}>,/imsvc,-isystem>$<JOIN:$<TARGET_PROPERTY:cxx-headers,INTERFACE_INCLUDE_DIRECTORIES>,$<SEMICOLON>$<IF:$<BOOL:${MSVC}>,/imsvc,-isystem>>>")
 641     if (SANITIZER_USE_STATIC_TEST_CXX)
 642       list(APPEND SANITIZER_TEST_CXX_LIBRARIES "$<TARGET_LINKER_FILE:cxx_static>")
 643     else()
 644       list(APPEND SANITIZER_TEST_CXX_LIBRARIES "$<TARGET_LINKER_FILE:$<IF:$<TARGET_EXISTS:cxx_shared>,cxx_shared,cxx_static>>")
 645     endif()
 646     # We are using the in tree libc++ so avoid including the default one.
 647     append_list_if(COMPILER_RT_HAS_NOSTDINCXX_FLAG -nostdinc++ COMPILER_RT_UNITTEST_CFLAGS)
 648     append_list_if(COMPILER_RT_HAS_NOSTDLIBXX_FLAG -nostdlib++ COMPILER_RT_UNITTEST_LINK_FLAGS)
 649   else()
 650     append_list_if(COMPILER_RT_HAS_LIBCXX -lc++ SANITIZER_TEST_CXX_LIBRARIES)
 651   endif()
 652 elseif (SANITIZER_TEST_CXX_LIBNAME STREQUAL "libstdc++")
 653   append_list_if(COMPILER_RT_HAS_LIBSTDCXX -lstdc++ SANITIZER_TEST_CXX_LIBRARIES)
 654 endif()
 655
 656 # Unittests support.
 657 # FIXME: When compiler-rt is build using -DLLVM_BUILD_EXTERNAL_COMPILER_RT=ON, then
 658 # The LLVM_THIRD_PARTY_DIR variable is not set.
 659 if (NOT LLVM_THIRD_PARTY_DIR)
 660   set(LLVM_THIRD_PARTY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../third-party")
 661 endif()
 662
 663 set(COMPILER_RT_GTEST_PATH ${LLVM_THIRD_PARTY_DIR}/unittest/googletest)
 664 set(COMPILER_RT_GTEST_SOURCE ${COMPILER_RT_GTEST_PATH}/src/gtest-all.cc)
 665 set(COMPILER_RT_GTEST_CFLAGS
 666   -DGTEST_NO_LLVM_SUPPORT=1
 667   -DGTEST_HAS_RTTI=0
 668   -I${COMPILER_RT_GTEST_PATH}/include
 669   -I${COMPILER_RT_GTEST_PATH}
 670 )
 671
 672 # Mocking support.
 673 set(COMPILER_RT_GMOCK_PATH ${LLVM_THIRD_PARTY_DIR}/unittest/googlemock)
 674 set(COMPILER_RT_GMOCK_SOURCE ${COMPILER_RT_GMOCK_PATH}/src/gmock-all.cc)
 675 set(COMPILER_RT_GMOCK_CFLAGS
 676   -DGTEST_NO_LLVM_SUPPORT=1
 677   -DGTEST_HAS_RTTI=0
 678   -I${COMPILER_RT_GMOCK_PATH}/include
 679   -I${COMPILER_RT_GMOCK_PATH}
 680 )
 681
 682 if(COMPILER_RT_HAS_G_FLAG)
 683   list(APPEND COMPILER_RT_UNITTEST_CFLAGS -g)
 684 endif()
 685 append_list_if(COMPILER_RT_DEBUG -DSANITIZER_DEBUG=1 COMPILER_RT_UNITTEST_CFLAGS)
 686 append_list_if(COMPILER_RT_HAS_WCOVERED_SWITCH_DEFAULT_FLAG -Wno-covered-switch-default COMPILER_RT_UNITTEST_CFLAGS)
 687 append_list_if(COMPILER_RT_HAS_WSUGGEST_OVERRIDE_FLAG -Wno-suggest-override COMPILER_RT_UNITTEST_CFLAGS)
 688
 689 if(MSVC)
 690   # gtest use a lot of stuff marked as deprecated on Windows.
 691   list(APPEND COMPILER_RT_GTEST_CFLAGS -Wno-deprecated-declarations)
 692 endif()
 693
 694 # Warnings to turn off for all libraries, not just sanitizers.
 695 append_string_if(COMPILER_RT_HAS_WUNUSED_PARAMETER_FLAG -Wno-unused-parameter CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 696
 697 if (CMAKE_LINKER MATCHES "link.exe$")
 698   # Silence MSVC linker warnings caused by empty object files. The
 699   # sanitizer libraries intentionally use ifdefs that result in empty
 700   # files, rather than skipping these files in the build system.
 701   # Ideally, we would pass this flag only for the libraries that need
 702   # it, but CMake doesn't seem to have a way to set linker flags for
 703   # individual static libraries, so we enable the suppression flag for
 704   # the whole compiler-rt project.
 705   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
 706 endif()
 707
 708 add_subdirectory(include)
 709
 710 option(COMPILER_RT_USE_LIBCXX
 711   "Enable compiler-rt to use libc++ from the source tree" ON)
 712 if(COMPILER_RT_USE_LIBCXX)
 713   if(LLVM_ENABLE_PROJECTS_USED)
 714     # Don't use libcxx if LLVM_ENABLE_PROJECTS does not enable it.
 715     set(COMPILER_RT_LIBCXX_PATH ${LLVM_EXTERNAL_LIBCXX_SOURCE_DIR})
 716     set(COMPILER_RT_LIBCXXABI_PATH ${LLVM_EXTERNAL_LIBCXXABI_SOURCE_DIR})
 717   else()
 718     foreach(path IN ITEMS ${LLVM_MAIN_SRC_DIR}/projects/libcxx
 719                           ${LLVM_MAIN_SRC_DIR}/runtimes/libcxx
 720                           ${LLVM_MAIN_SRC_DIR}/../libcxx
 721                           ${LLVM_EXTERNAL_LIBCXX_SOURCE_DIR})
 722       if(IS_DIRECTORY ${path})
 723         set(COMPILER_RT_LIBCXX_PATH ${path})
 724         break()
 725       endif()
 726     endforeach()
 727     foreach(path IN ITEMS ${LLVM_MAIN_SRC_DIR}/projects/libcxxabi
 728                           ${LLVM_MAIN_SRC_DIR}/runtimes/libcxxabi
 729                           ${LLVM_MAIN_SRC_DIR}/../libcxxabi
 730                           ${LLVM_EXTERNAL_LIBCXXABI_SOURCE_DIR})
 731       if(IS_DIRECTORY ${path})
 732         set(COMPILER_RT_LIBCXXABI_PATH ${path})
 733         break()
 734       endif()
 735     endforeach()
 736   endif()
 737 endif()
 738
 739 set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/tools/lld)
 740 if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
 741   set(COMPILER_RT_HAS_LLD TRUE)
 742 else()
 743   set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/../lld)
 744   if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
 745     set(COMPILER_RT_HAS_LLD TRUE)
 746   endif()
 747 endif()
 748
 749 if(ANDROID)
 750   set(COMPILER_RT_HAS_LLD TRUE)
 751   set(COMPILER_RT_TEST_USE_LLD TRUE)
 752   append_list_if(COMPILER_RT_HAS_FUSE_LD_LLD_FLAG -fuse-ld=lld SANITIZER_COMMON_LINK_FLAGS)
 753   append_list_if(COMPILER_RT_HAS_LLD -fuse-ld=lld COMPILER_RT_UNITTEST_LINK_FLAGS)
 754 endif()
 755 pythonize_bool(COMPILER_RT_HAS_LLD)
 756 pythonize_bool(COMPILER_RT_TEST_USE_LLD)
 757
 758 add_subdirectory(lib)
 759
 760 if(COMPILER_RT_INCLUDE_TESTS)
 761   add_subdirectory(unittests)
 762   add_subdirectory(test)
 763   # Don't build llvm-lit for runtimes-build, it will clean up map_config.
 764   if (COMPILER_RT_STANDALONE_BUILD AND NOT LLVM_RUNTIMES_BUILD)
 765     # If we have a valid source tree, generate llvm-lit into the bin directory.
 766     # The user can still choose to have the check targets *use* a different lit
 767     # by specifying -DLLVM_EXTERNAL_LIT, but we generate it regardless.
 768     if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 769       # Needed for lit support in standalone builds.
 770       include(AddLLVM)
 771       add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit ${CMAKE_CURRENT_BINARY_DIR}/llvm-lit)
 772     elseif(NOT EXISTS ${LLVM_EXTERNAL_LIT})
 773       message(WARNING "Could not find LLVM source directory and LLVM_EXTERNAL_LIT does not"
 774                        "point to a valid file.  You will not be able to run tests.")
 775     endif()
 776   endif()
 777 endif()
 778
 779 add_subdirectory(tools)