llvm/test/Analysis/LoopCacheAnalysis/PowerPC/matmul.ll

   1 ; RUN: opt < %s -passes='print<loop-cache-cost>' -disable-output 2>&1 | FileCheck %s
   2
   3 target datalayout = "e-m:e-i64:64-n32:64"
   4 target triple = "powerpc64le-unknown-linux-gnu"
   5
   6 ; void matmul(long n, long m, long o, int A[n][m], int B[n][m], int C[n]) {
   7 ;   for (long i = 0; i < n; i++)
   8 ;     for (long j = 0; j < m; j++)
   9 ;       for (long k = 0; k < o; k++)
  10 ;         C[i][j] = C[i][j] + A[i][k] * B[k][j];
  11 ; }
  12
  13 ; CHECK:Loop 'for.i' has cost = 2010000
  14 ; CHECK-NEXT:Loop 'for.k' has cost = 1040000
  15 ; CHECK-NEXT:Loop 'for.j' has cost = 70000
  16
  17 define void @matmul(i64 %n, i64 %m, i64 %o, i32* %A, i32* %B, i32* %C) {
  18 entry:
  19   br label %for.i
  20
  21 for.i:                                         ; preds = %entry, %for.inc.i
  22   %i = phi i64 [ 0, %entry ], [ %i.next, %for.inc.i ]
  23   %muli = mul i64 %i, %m
  24   br label %for.j
  25
  26 for.j:                                        ; preds = %for.i, %for.inc.j
  27   %j = phi i64 [ 0, %for.i ], [ %j.next, %for.inc.j ]
  28   %addj = add i64 %muli, %j
  29   %mulj = mul i64 %addj, %o
  30   br label %for.k
  31
  32 for.k:                                        ; preds = %for.j, %for.inc.k
  33   %k = phi i64 [ 0, %for.j ], [ %k.next, %for.inc.k ]
  34
  35   ; A[i][k]
  36   %arrayidx3 = add i64 %k, %muli
  37   %arrayidx4 = getelementptr inbounds i32, i32* %A, i64 %arrayidx3
  38   %elem_A = load i32, i32* %arrayidx4, align 4
  39
  40   ; B[k][j]
  41   %mulk = mul i64 %k, %o
  42   %arrayidx5 = add i64 %j, %mulk
  43   %arrayidx6 = getelementptr inbounds i32, i32* %B, i64 %arrayidx5
  44   %elem_B = load i32, i32* %arrayidx6, align 4
  45
  46   ; C[i][k]
  47   %arrayidx7 = add i64 %j, %muli
  48   %arrayidx8 = getelementptr inbounds i32, i32* %C, i64 %arrayidx7
  49   %elem_C = load i32, i32* %arrayidx8, align 4
  50
  51   ; C[i][j] = C[i][j] + A[i][k] * B[k][j];
  52   %mul = mul nsw i32 %elem_A, %elem_B
  53   %add = add nsw i32 %elem_C, %mul
  54   store i32 %add, i32* %arrayidx8, align 4
  55
  56   br label %for.inc.k
  57
  58 for.inc.k:                                          ; preds = %for.k
  59   %k.next = add nuw nsw i64 %k, 1
  60   %exitcond = icmp ne i64 %k.next, %o
  61   br i1 %exitcond, label %for.k, label %for.end
  62
  63 for.end:                                          ; preds = %for.inc
  64   br label %for.inc.j
  65
  66 for.inc.j:                                        ; preds = %for.end
  67   %j.next = add nuw nsw i64 %j, 1
  68   %exitcond5 = icmp ne i64 %j.next, %m
  69   br i1 %exitcond5, label %for.j, label %for.end23
  70
  71 for.end23:                                        ; preds = %for.inc.j
  72   br label %for.inc.i
  73
  74 for.inc.i:                                        ; preds = %for.end23
  75   %i.next = add nuw nsw i64 %i, 1
  76   %exitcond8 = icmp ne i64 %i.next, %n
  77   br i1 %exitcond8, label %for.i, label %for.end26
  78
  79 for.end26:                                        ; preds = %for.inc.i
  80   ret void
  81 }