flang/test/Analysis/AliasAnalysis/alias-analysis-9.fir

   1 // Use --mlir-disable-threading so that the AA queries are serialized
   2 // as well as its diagnostic output.
   3 // RUN: fir-opt %s -pass-pipeline='builtin.module(func.func(test-fir-alias-analysis))' -split-input-file --mlir-disable-threading 2>&1 | FileCheck %s
   4
   5 // Fortran source code:
   6 // program TestTmpArrayAssignment
   7 //   integer :: a, b, c
   8 //   integer :: arrayD(3)
   9 //
  10 //   arrayD = [ a, b, c ]
  11 // end program TestTmpArrayAssignment
  12
  13 // CHECK-LABEL: Testing : "_QPTestTmpArrayAssignment"
  14 // CHECK-DAG: ArrayD#0 <-> tmp_array#0: NoAlias
  15 func.func @_QPTestTmpArrayAssignment() attributes {fir.bindc_name = "testtmparrayassignment"} {
  16   %0 = fir.alloca i32 {bindc_name = "a", uniq_name = "_QFEa"}
  17   %1:2 = hlfir.declare %0 {uniq_name = "_QFEa"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
  18   %c3 = arith.constant 3 : index
  19   %2 = fir.alloca !fir.array<3xi32> {bindc_name = "arrayd", uniq_name = "_QFEarrayd", test.ptr = "ArrayD" }
  20   %3 = fir.shape %c3 : (index) -> !fir.shape<1>
  21   %4:2 = hlfir.declare %2(%3) {uniq_name = "_QFEarrayd"} : (!fir.ref<!fir.array<3xi32>>, !fir.shape<1>) -> (!fir.ref<!fir.array<3xi32>>, !fir.ref<!fir.array<3xi32>>)
  22   %5 = fir.alloca i32 {bindc_name = "b", uniq_name = "_QFEb"}
  23   %6:2 = hlfir.declare %5 {uniq_name = "_QFEb"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
  24   %7 = fir.alloca i32 {bindc_name = "c", uniq_name = "_QFEc"}
  25   %8:2 = hlfir.declare %7 {uniq_name = "_QFEc"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
  26   %c3_0 = arith.constant 3 : index
  27   %c1 = arith.constant 1 : index
  28   %c1_1 = arith.constant 1 : index
  29   %9 = fir.allocmem !fir.array<3xi32> {bindc_name = ".tmp.arrayctor", uniq_name = ""}
  30   %10 = fir.shape %c3_0 : (index) -> !fir.shape<1>
  31   %11:2 = hlfir.declare %9(%10) {uniq_name = ".tmp.arrayctor"} : (!fir.heap<!fir.array<3xi32>>, !fir.shape<1>) -> (!fir.heap<!fir.array<3xi32>>, !fir.heap<!fir.array<3xi32>>)
  32   %12 = fir.load %1#0 : !fir.ref<i32>
  33   %13 = arith.addi %c1, %c1_1 : index
  34   %14 = hlfir.designate %11#0 (%c1)  : (!fir.heap<!fir.array<3xi32>>, index) -> !fir.ref<i32>
  35   hlfir.assign %12 to %14 : i32, !fir.ref<i32>
  36   %15 = fir.load %6#0 : !fir.ref<i32>
  37   %16 = arith.addi %13, %c1_1 : index
  38   %17 = hlfir.designate %11#0 (%13)  : (!fir.heap<!fir.array<3xi32>>, index) -> !fir.ref<i32>
  39   hlfir.assign %15 to %17 : i32, !fir.ref<i32>
  40   %18 = fir.load %8#0 : !fir.ref<i32>
  41   %19 = hlfir.designate %11#0 (%16)  : (!fir.heap<!fir.array<3xi32>>, index) -> !fir.ref<i32>
  42   hlfir.assign %18 to %19 : i32, !fir.ref<i32>
  43   %true = arith.constant true
  44   %20 = hlfir.as_expr %11#0 move %true {test.ptr = "tmp_array"}: (!fir.heap<!fir.array<3xi32>>, i1) -> !hlfir.expr<3xi32>
  45   hlfir.assign %20 to %4#0 : !hlfir.expr<3xi32>, !fir.ref<!fir.array<3xi32>>
  46   hlfir.destroy %20 : !hlfir.expr<3xi32>
  47   return
  48 }