flang/test/HLFIR/any-lowering.fir

   1 // Test hlfir.any operation lowering to fir runtime call
   2 // RUN: fir-opt %s -lower-hlfir-intrinsics | FileCheck %s
   3
   4 // one argument ANY
   5 func.func @_QPany1(%arg0: !fir.box<!fir.array<?x!fir.logical<4>>> {fir.bindc_name = "a"}, %arg1: !fir.ref<!fir.logical<4>> {fir.bindc_name = "s"}) {
   6   %0:2 = hlfir.declare %arg0 {uniq_name = "_QFany1Ea"} : (!fir.box<!fir.array<?x!fir.logical<4>>>) -> (!fir.box<!fir.array<?x!fir.logical<4>>>, !fir.box<!fir.array<?x!fir.logical<4>>>)
   7   %1:2 = hlfir.declare %arg1 {uniq_name = "_QFany1Es"} : (!fir.ref<!fir.logical<4>>) -> (!fir.ref<!fir.logical<4>>, !fir.ref<!fir.logical<4>>)
   8   %2 = hlfir.any %0#0 : (!fir.box<!fir.array<?x!fir.logical<4>>>) -> !fir.logical<4>
   9   hlfir.assign %2 to %1#0 : !fir.logical<4>, !fir.ref<!fir.logical<4>>
  10   return
  11 }
  12 // CHECK-LABEL: func.func @_QPany1(
  13 // CHECK:           %[[ARG0:.*]]: !fir.box<!fir.array<?x!fir.logical<4>>> {fir.bindc_name = "a"}
  14 // CHECK:           %[[ARG1:.*]]: !fir.ref<!fir.logical<4>>
  15 // CHECK-DAG:     %[[MASK:.*]]:2 = hlfir.declare %[[ARG0]]
  16 // CHECK-DAG:     %[[RES:.*]]:2 = hlfir.declare %[[ARG1]]
  17 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK]]#1 : (!fir.box<!fir.array<?x!fir.logical<4>>>) -> !fir.box<none>
  18 // CHECK:         %[[RET_ARG:.*]] = fir.call @_FortranAAny(%[[MASK_ARG]], %[[LOC_STR:.*]], %[[LOC_N:.*]], %[[C1:.*]]) : (!fir.box<none>, !fir.ref<i8>, i32, i32) -> i1
  19 // CHECK-NEXT:    %[[RET:.*]] = fir.convert %[[RET_ARG]] : (i1) -> !fir.logical<4>
  20 // CHECK-NEXT:    hlfir.assign %[[RET]] to %[[RES]]#0 : !fir.logical<4>, !fir.ref<!fir.logical<4>>
  21 // CHECK-NEXT:    return
  22 // CHECK-NEXT:  }
  23
  24 // ANY with dim argument by-ref
  25 func.func @_QPany2(%arg0: !fir.box<!fir.array<?x?x!fir.logical<4>>> {fir.bindc_name = "a"}, %arg1: !fir.box<!fir.array<?x!fir.logical<4>>> {fir.bindc_name = "s"}, %arg2: !fir.ref<i32> {fir.bindc_name = "d"}) {
  26   %0:2 = hlfir.declare %arg0 {uniq_name = "_QFany2Ea"} : (!fir.box<!fir.array<?x?x!fir.logical<4>>>) -> (!fir.box<!fir.array<?x?x!fir.logical<4>>>, !fir.box<!fir.array<?x?x!fir.logical<4>>>)
  27   %1:2 = hlfir.declare %arg2 {uniq_name = "_QFany2Ed"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
  28   %2:2 = hlfir.declare %arg1 {uniq_name = "_QFany2Es"} : (!fir.box<!fir.array<?x!fir.logical<4>>>) -> (!fir.box<!fir.array<?x!fir.logical<4>>>, !fir.box<!fir.array<?x!fir.logical<4>>>)
  29   %3 = fir.load %1#0 : !fir.ref<i32>
  30   %4 = hlfir.any %0#0 dim %3 : (!fir.box<!fir.array<?x?x!fir.logical<4>>>, i32) -> !hlfir.expr<?x!fir.logical<4>>
  31   hlfir.assign %4 to %2#0 : !hlfir.expr<?x!fir.logical<4>>, !fir.box<!fir.array<?x!fir.logical<4>>>
  32   hlfir.destroy %4 : !hlfir.expr<?x!fir.logical<4>>
  33   return
  34 }
  35 // CHECK-LABEL: func.func @_QPany2(
  36 // CHECK:           %[[ARG0:.*]]: !fir.box<!fir.array<?x?x!fir.logical<4>>>
  37 // CHECK:           %[[ARG1:.*]]: !fir.box<!fir.array<?x!fir.logical<4>>>
  38 // CHECK:           %[[ARG2:.*]]: !fir.ref<i32>
  39 // CHECK-DAG:     %[[TRUE:.*]] = arith.constant true
  40 // CHECK-DAG:     %[[MASK:.*]]:2 = hlfir.declare %[[ARG0]]
  41 // CHECK-DAG:     %[[DIM_VAR:.*]]:2 = hlfir.declare %[[ARG2]]
  42 // CHECK-DAG:     %[[RES:.*]]:2 = hlfir.declare %[[ARG1]]
  43
  44 // CHECK-DAG:     %[[RET_BOX:.*]] = fir.alloca !fir.box<!fir.heap<!fir.array<?x!fir.logical<4>>>>
  45 // CHECK-DAG:     %[[RET_ADDR:.*]] = fir.zero_bits !fir.heap<!fir.array<?x!fir.logical<4>>>
  46 // CHECK-DAG:     %[[C0:.*]] = arith.constant 0 : index
  47 // CHECK-DAG:     %[[RET_SHAPE:.*]] = fir.shape %[[C0]] : (index) -> !fir.shape<1>
  48 // CHECK-DAG:     %[[RET_EMBOX:.*]] = fir.embox %[[RET_ADDR]](%[[RET_SHAPE]])
  49 // CHECK-DAG:     fir.store %[[RET_EMBOX]] to %[[RET_BOX]]
  50
  51 // CHECK-DAG:     %[[DIM:.*]] = fir.load %[[DIM_VAR]]#0 : !fir.ref<i32>
  52 // CHECK-DAG:     %[[RET_ARG:.*]] = fir.convert %[[RET_BOX]]
  53 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK]]#1
  54
  55 // CHECK:         %[[NONE:.*]] = fir.call @_FortranAAnyDim(%[[RET_ARG]], %[[MASK_ARG]], %[[DIM]], %[[LOC_STR:.*]], %[[LOC_N:.*]]) : (!fir.ref<!fir.box<none>>, !fir.box<none>, i32, !fir.ref<i8>, i32) -> none
  56 // CHECK:         %[[RET:.*]] = fir.load %[[RET_BOX]]
  57 // CHECK:         %[[BOX_DIMS:.*]]:3 = fir.box_dims %[[RET]]
  58 // CHECK-NEXT:    %[[ADDR:.*]] = fir.box_addr %[[RET]]
  59 // CHECK-NEXT:    %[[SHIFT:.*]] = fir.shape_shift %[[BOX_DIMS]]#0, %[[BOX_DIMS]]#1
  60 // CHECK-NEXT:    %[[TMP:.*]]:2 = hlfir.declare %[[ADDR]](%[[SHIFT]]) {uniq_name = ".tmp.intrinsic_result"}
  61 // CHECK:         %[[EXPR:.*]] = hlfir.as_expr %[[TMP]]#0 move %[[TRUE]] : (!fir.box<!fir.array<?x!fir.logical<4>>>, i1) -> !hlfir.expr<?x!fir.logical<4>>
  62 // CHECK:         hlfir.assign %[[EXPR]] to %[[RES]]#0
  63 // CHECK:         hlfir.destroy %[[EXPR]]
  64 // CHECK-NEXT:    return
  65 // CHECK-NEXT:  }
  66
  67 // any with DIM argument by-val, mask isn't boxed
  68 func.func @_QPany3(%arg0: !fir.ref<!fir.array<2x!fir.logical<4>>> {fir.bindc_name = "s"}) {
  69   %0 = fir.address_of(@_QFany3Ea) : !fir.ref<!fir.array<2x2x!fir.logical<4>>>
  70   %c2 = arith.constant 2 : index
  71   %c2_0 = arith.constant 2 : index
  72   %1 = fir.shape %c2, %c2_0 : (index, index) -> !fir.shape<2>
  73   %2:2 = hlfir.declare %0(%1) {uniq_name = "_QFany3Ea"} : (!fir.ref<!fir.array<2x2x!fir.logical<4>>>, !fir.shape<2>) -> (!fir.ref<!fir.array<2x2x!fir.logical<4>>>, !fir.ref<!fir.array<2x2x!fir.logical<4>>>)
  74   %c2_1 = arith.constant 2 : index
  75   %3 = fir.shape %c2_1 : (index) -> !fir.shape<1>
  76   %4:2 = hlfir.declare %arg0(%3) {uniq_name = "_QFany3Es"} : (!fir.ref<!fir.array<2x!fir.logical<4>>>, !fir.shape<1>) -> (!fir.ref<!fir.array<2x!fir.logical<4>>>, !fir.ref<!fir.array<2x!fir.logical<4>>>)
  77   %c1_i32 = arith.constant 1 : i32
  78   %5 = hlfir.any %2#0 dim %c1_i32 : (!fir.ref<!fir.array<2x2x!fir.logical<4>>>, i32) -> !hlfir.expr<2x!fir.logical<4>>
  79   hlfir.assign %5 to %4#0 : !hlfir.expr<2x!fir.logical<4>>, !fir.ref<!fir.array<2x!fir.logical<4>>>
  80   hlfir.destroy %5 : !hlfir.expr<2x!fir.logical<4>>
  81   return
  82 }
  83 // CHECK-LABEL:  func.func @_QPany3(
  84 // CHECK:           %[[ARG0:.*]]: !fir.ref<!fir.array<2x!fir.logical<4>>>
  85 // CHECK-DAG:     %[[TRUE:.*]] = arith.constant true
  86 // CHECK-DAG:     %[[RET_BOX:.*]] = fir.alloca !fir.box<!fir.heap<!fir.array<?x!fir.logical<4>>>>
  87 // CHECK-DAG:     %[[RET_ADDR:.*]] = fir.zero_bits !fir.heap<!fir.array<?x!fir.logical<4>>>
  88 // CHECK-DAG:     %[[C0:.*]] = arith.constant 0 : index
  89 // CHECK-DAG:     %[[RET_SHAPE:.*]] = fir.shape %[[C0]] : (index) -> !fir.shape<1>
  90 // CHECK-DAG:     %[[RET_EMBOX:.*]] = fir.embox %[[RET_ADDR]](%[[RET_SHAPE]])
  91 // CHECK-DAG:     fir.store %[[RET_EMBOX]] to %[[RET_BOX]]
  92 // CHECK-DAG:     %[[RES:.*]]:2 = hlfir.declare %[[ARG0]](%[[RES_SHAPE:.*]])
  93
  94 // CHECK-DAG:     %[[MASK_ADDR:.*]] = fir.address_of
  95 // CHECK-DAG:     %[[MASK_VAR:.*]]:2 = hlfir.declare %[[MASK_ADDR]](%[[MASK_SHAPE:.*]])
  96 // CHECK-DAG:     %[[MASK_BOX:.*]] = fir.embox %[[MASK_VAR]]#1(%[[MASK_SHAPE:.*]])
  97
  98 // CHECK-DAG:     %[[DIM:.*]] = arith.constant 1 : i32
  99
 100 // CHECK-DAG:     %[[RET_ARG:.*]] = fir.convert %[[RET_BOX]]
 101 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK_BOX]] : (!fir.box<!fir.array<2x2x!fir.logical<4>>>) -> !fir.box<none>
 102 // CHECK:         %[[NONE:.*]] = fir.call @_FortranAAnyDim(%[[RET_ARG]], %[[MASK_ARG]], %[[DIM]], %[[LOC_STR:.*]], %[[LOC_N:.*]])
 103 // CHECK:         %[[RET:.*]] = fir.load %[[RET_BOX]]
 104 // CHECK:         %[[BOX_DIMS:.*]]:3 = fir.box_dims %[[RET]]
 105 // CHECK-NEXT:    %[[ADDR:.*]] = fir.box_addr %[[RET]]
 106 // CHECK-NEXT:    %[[SHIFT:.*]] = fir.shape_shift %[[BOX_DIMS]]#0, %[[BOX_DIMS]]#1
 107 // CHECK-NEXT:    %[[TMP:.*]]:2 = hlfir.declare %[[ADDR]](%[[SHIFT]]) {uniq_name = ".tmp.intrinsic_result"}
 108 // CHECK:         %[[EXPR:.*]] = hlfir.as_expr %[[TMP]]#0 move %[[TRUE]] : (!fir.box<!fir.array<?x!fir.logical<4>>>, i1) -> !hlfir.expr<?x!fir.logical<4>>
 109 // CHECK:         hlfir.assign %[[EXPR]] to %[[RES]]
 110 // CHECK:         hlfir.destroy %[[EXPR]]
 111 // CHECK-NEXT:    return
 112 // CHECK-NEXT:  }
 113
 114 // any with dim from pointer
 115 func.func @_QPany4(%arg0: !fir.box<!fir.array<?x?x!fir.logical<4>>> {fir.bindc_name = "a"}, %arg1: !fir.box<!fir.array<?x!fir.logical<4>>> {fir.bindc_name = "s"}, %arg2: !fir.ref<!fir.box<!fir.ptr<i32>>> {fir.bindc_name = "d"}) {
 116   %0:2 = hlfir.declare %arg0 {uniq_name = "_QFany4Ea"} : (!fir.box<!fir.array<?x?x!fir.logical<4>>>) -> (!fir.box<!fir.array<?x?x!fir.logical<4>>>, !fir.box<!fir.array<?x?x!fir.logical<4>>>)
 117   %1:2 = hlfir.declare %arg2 {fortran_attrs = #fir.var_attrs<pointer>, uniq_name = "_QFany4Ed"} : (!fir.ref<!fir.box<!fir.ptr<i32>>>) -> (!fir.ref<!fir.box<!fir.ptr<i32>>>, !fir.ref<!fir.box<!fir.ptr<i32>>>)
 118   %2:2 = hlfir.declare %arg1 {uniq_name = "_QFany4Es"} : (!fir.box<!fir.array<?x!fir.logical<4>>>) -> (!fir.box<!fir.array<?x!fir.logical<4>>>, !fir.box<!fir.array<?x!fir.logical<4>>>)
 119   %3 = fir.load %1#0 : !fir.ref<!fir.box<!fir.ptr<i32>>>
 120   %4 = fir.box_addr %3 : (!fir.box<!fir.ptr<i32>>) -> !fir.ptr<i32>
 121   %5 = fir.load %4 : !fir.ptr<i32>
 122   %6 = hlfir.no_reassoc %5 : i32
 123   %7 = hlfir.any %0#0 dim %6 : (!fir.box<!fir.array<?x?x!fir.logical<4>>>, i32) -> !hlfir.expr<?x!fir.logical<4>>
 124   hlfir.assign %7 to %2#0 : !hlfir.expr<?x!fir.logical<4>>, !fir.box<!fir.array<?x!fir.logical<4>>>
 125   hlfir.destroy %7 : !hlfir.expr<?x!fir.logical<4>>
 126   return
 127 }
 128 // CHECK-LABEL:  func.func @_QPany4(
 129 // CHECK:           %[[ARG0:.*]]: !fir.box<!fir.array<?x?x!fir.logical<4>>>
 130 // CHECK:           %[[ARG1:.*]]: !fir.box<!fir.array<?x!fir.logical<4>>>
 131 // CHECK:           %[[ARG2:.*]]: !fir.ref<!fir.box<!fir.ptr<i32>>>
 132 // CHECK-DAG:     %[[TRUE:.*]] = arith.constant true
 133 // CHECK-DAG:     %[[MASK:.*]]:2 = hlfir.declare %[[ARG0]]
 134 // CHECK-DAG:     %[[DIM_ARG:.*]]:2 = hlfir.declare %[[ARG2]]
 135 // CHECK-DAG:     %[[RES:.*]]:2 = hlfir.declare %[[ARG1]]
 136
 137 // CHECK-DAG:     %[[RET_BOX:.*]] = fir.alloca !fir.box<!fir.heap<!fir.array<?x!fir.logical<4>>>>
 138 // CHECK-DAG:     %[[DIM_PTR:.*]] = fir.load %[[DIM_ARG]]#0 : !fir.ref<!fir.box<!fir.ptr<i32>>>
 139 // CHECK-DAG:     %[[DIM_ADDR:.*]] = fir.box_addr %[[DIM_PTR]]
 140 // CHECK-DAG:     %[[DIM_VAR:.*]] = fir.load %[[DIM_ADDR]]
 141 // CHECK-DAG:     %[[DIM:.*]] = hlfir.no_reassoc %[[DIM_VAR]]
 142
 143 // CHECK-DAG:     %[[C0:.*]] = arith.constant 0 : index
 144 // CHECK-DAG:     %[[RET_ADDR:.*]] = fir.zero_bits !fir.heap<!fir.array<?x!fir.logical<4>>>
 145 // CHECK-DAG:     %[[RET_SHAPE:.*]] = fir.shape %[[C0]] : (index) -> !fir.shape<1>
 146 // CHECK-DAG:     %[[RET_EMBOX:.*]] = fir.embox %[[RET_ADDR]](%[[RET_SHAPE]])
 147 // CHECK-DAG:     fir.store %[[RET_EMBOX]] to %[[RET_BOX]]
 148 // CHECK-DAG:     %[[RET_ARG:.*]] = fir.convert %[[RET_BOX]]
 149 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK]]#1
 150
 151 // CHECK:         %[[NONE:.*]] = fir.call @_FortranAAnyDim(%[[RET_ARG]], %[[MASK_ARG]], %[[DIM]], %[[LOC_STR:.*]], %[[LOC_N:.*]]) : (!fir.ref<!fir.box<none>>, !fir.box<none>, i32, !fir.ref<i8>, i32) -> none
 152 // CHECK:         %[[RET:.*]] = fir.load %[[RET_BOX]]
 153 // CHECK:         %[[BOX_DIMS:.*]]:3 = fir.box_dims %[[RET]]
 154 // CHECK-NEXT:    %[[ADDR:.*]] = fir.box_addr %[[RET]]
 155 // CHECK-NEXT:    %[[SHIFT:.*]] = fir.shape_shift %[[BOX_DIMS]]#0, %[[BOX_DIMS]]#1
 156 // CHECK-NEXT:    %[[TMP:.*]]:2 = hlfir.declare %[[ADDR]](%[[SHIFT]]) {uniq_name = ".tmp.intrinsic_result"}
 157 // CHECK:         %[[EXPR:.*]] = hlfir.as_expr %[[TMP]]#0 move %[[TRUE]] : (!fir.box<!fir.array<?x!fir.logical<4>>>, i1) -> !hlfir.expr<?x!fir.logical<4>>
 158 // CHECK:         hlfir.assign %[[EXPR]] to %[[RES]]
 159 // CHECK:         hlfir.destroy %[[EXPR]]
 160 // CHECK-NEXT:    return
 161 // CHECK-NEXT:  }