flang/test/HLFIR/order_assignments/runtime-stack-temp.fir

   1 // Test code generation of hlfir.forall and hlfir.where when temporary
   2 // storage is needed and requires a runtime managed stack.
   3 // RUN: fir-opt %s --lower-hlfir-ordered-assignments | FileCheck %s
   4
   5 func.func @test_runtime_stack(%arg0: !fir.box<!fir.array<?xi32>>, %n: !fir.ref<i32>) {
   6   %c1 = arith.constant 1 : index
   7   %c0 = arith.constant 0 : index
   8   %c-1 = arith.constant -1 : index
   9   %c99_i32 = arith.constant 99 : i32
  10   %c100_i32 = arith.constant 100 : i32
  11   %c1_i32 = arith.constant 1 : i32
  12   %1:2 = hlfir.declare %n {uniq_name = "n"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
  13   %2:2 = hlfir.declare %arg0 {uniq_name = "x"} : (!fir.box<!fir.array<?xi32>>) -> (!fir.box<!fir.array<?xi32>>, !fir.box<!fir.array<?xi32>>)
  14   %3 = fir.load %1#1 : !fir.ref<i32>
  15   hlfir.forall lb {
  16     hlfir.yield %c1_i32 : i32
  17   } ub {
  18     hlfir.yield %c100_i32 : i32
  19   } step {
  20     hlfir.yield %3 : i32
  21   }  (%arg1: i32) {
  22     hlfir.region_assign {
  23       %4 = arith.subi %c100_i32, %arg1 : i32
  24       %5 = arith.subi %c99_i32, %arg1 : i32
  25       %6 = fir.load %1#0 : !fir.ref<i32>
  26       %7 = arith.subi %5, %6 : i32
  27       %8 = fir.convert %4 : (i32) -> index
  28       %9 = fir.convert %7 : (i32) -> index
  29       %10 = arith.subi %9, %8 : index
  30       %11 = arith.addi %10, %c-1 : index
  31       %12 = arith.divsi %11, %c-1 : index
  32       %13 = arith.cmpi sgt, %12, %c0 : index
  33       %14 = arith.select %13, %12, %c0 : index
  34       %15 = fir.shape %14 : (index) -> !fir.shape<1>
  35       %16 = hlfir.designate %2#0 (%8:%9:%c-1)  shape %15 : (!fir.box<!fir.array<?xi32>>, index, index, index, !fir.shape<1>) -> !fir.box<!fir.array<?xi32>>
  36       hlfir.yield %16 : !fir.box<!fir.array<?xi32>>
  37     } to {
  38       %4 = fir.load %1#0 : !fir.ref<i32>
  39       %5 = arith.addi %arg1, %4 : i32
  40       %6 = arith.subi %5, %c1_i32 : i32
  41       %7 = fir.convert %arg1 : (i32) -> index
  42       %8 = fir.convert %6 : (i32) -> index
  43       %9 = arith.subi %8, %7 : index
  44       %10 = arith.addi %9, %c1 : index
  45       %11 = arith.cmpi sgt, %10, %c0 : index
  46       %12 = arith.select %11, %10, %c0 : index
  47       %13 = fir.shape %12 : (index) -> !fir.shape<1>
  48       %14 = hlfir.designate %2#0 (%7:%8:%c1)  shape %13 : (!fir.box<!fir.array<?xi32>>, index, index, index, !fir.shape<1>) -> !fir.box<!fir.array<?xi32>>
  49       hlfir.yield %14 : !fir.box<!fir.array<?xi32>>
  50     }
  51   }
  52   return
  53 }
  54
  55 // CHECK-LABEL:   func.func @test_runtime_stack(
  56 // CHECK-SAME:                                  %[[VAL_0:.*]]: !fir.box<!fir.array<?xi32>>,
  57 // CHECK-SAME:                                  %[[VAL_1:.*]]: !fir.ref<i32>) {
  58 // CHECK:           %[[VAL_2:.*]] = fir.alloca !fir.box<!fir.heap<!fir.array<?xi32>>>
  59 // CHECK:           %[[VAL_3:.*]] = fir.alloca i64
  60 // CHECK:           %[[VAL_4:.*]] = arith.constant 1 : index
  61 // CHECK:           %[[VAL_5:.*]] = arith.constant 0 : index
  62 // CHECK:           %[[VAL_6:.*]] = arith.constant -1 : index
  63 // CHECK:           %[[VAL_7:.*]] = arith.constant 99 : i32
  64 // CHECK:           %[[VAL_8:.*]] = arith.constant 100 : i32
  65 // CHECK:           %[[VAL_9:.*]] = arith.constant 1 : i32
  66 // CHECK:           %[[VAL_10:.*]]:2 = hlfir.declare %[[VAL_1]] {uniq_name = "n"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
  67 // CHECK:           %[[VAL_11:.*]]:2 = hlfir.declare %[[VAL_0]] {uniq_name = "x"} : (!fir.box<!fir.array<?xi32>>) -> (!fir.box<!fir.array<?xi32>>, !fir.box<!fir.array<?xi32>>)
  68 // CHECK:           %[[VAL_12:.*]] = fir.load %[[VAL_10]]#1 : !fir.ref<i32>
  69 // CHECK:           %[[VAL_13:.*]] = fir.convert %[[VAL_9]] : (i32) -> index
  70 // CHECK:           %[[VAL_14:.*]] = fir.convert %[[VAL_8]] : (i32) -> index
  71 // CHECK:           %[[VAL_15:.*]] = fir.convert %[[VAL_12]] : (i32) -> index
  72 // CHECK:           %[[VAL_16:.*]] = arith.constant 0 : i64
  73 // CHECK:           %[[VAL_17:.*]] = arith.constant 1 : i64
  74 // CHECK:           fir.store %[[VAL_16]] to %[[VAL_3]] : !fir.ref<i64>
  75 // CHECK:           %[[VAL_22:.*]] = fir.call @_FortranACreateValueStack(%{{.*}}, %{{.*}}) : (!fir.ref<i8>, i32) -> !fir.llvm_ptr<i8>
  76 // CHECK:           fir.do_loop %[[VAL_23:.*]] = %[[VAL_13]] to %[[VAL_14]] step %[[VAL_15]] {
  77 // CHECK:             %[[VAL_24:.*]] = fir.convert %[[VAL_23]] : (index) -> i32
  78 // CHECK:             %[[VAL_25:.*]] = arith.subi %[[VAL_8]], %[[VAL_24]] : i32
  79 // CHECK:             %[[VAL_26:.*]] = arith.subi %[[VAL_7]], %[[VAL_24]] : i32
  80 // CHECK:             %[[VAL_27:.*]] = fir.load %[[VAL_10]]#0 : !fir.ref<i32>
  81 // CHECK:             %[[VAL_28:.*]] = arith.subi %[[VAL_26]], %[[VAL_27]] : i32
  82 // CHECK:             %[[VAL_29:.*]] = fir.convert %[[VAL_25]] : (i32) -> index
  83 // CHECK:             %[[VAL_30:.*]] = fir.convert %[[VAL_28]] : (i32) -> index
  84 // CHECK:             %[[VAL_31:.*]] = arith.subi %[[VAL_30]], %[[VAL_29]] : index
  85 // CHECK:             %[[VAL_32:.*]] = arith.addi %[[VAL_31]], %[[VAL_6]] : index
  86 // CHECK:             %[[VAL_33:.*]] = arith.divsi %[[VAL_32]], %[[VAL_6]] : index
  87 // CHECK:             %[[VAL_34:.*]] = arith.cmpi sgt, %[[VAL_33]], %[[VAL_5]] : index
  88 // CHECK:             %[[VAL_35:.*]] = arith.select %[[VAL_34]], %[[VAL_33]], %[[VAL_5]] : index
  89 // CHECK:             %[[VAL_36:.*]] = fir.shape %[[VAL_35]] : (index) -> !fir.shape<1>
  90 // CHECK:             %[[VAL_37:.*]] = hlfir.designate %[[VAL_11]]#0 (%[[VAL_29]]:%[[VAL_30]]:%[[VAL_6]])  shape %[[VAL_36]] : (!fir.box<!fir.array<?xi32>>, index, index, index, !fir.shape<1>) -> !fir.box<!fir.array<?xi32>>
  91 // CHECK:             %[[VAL_38:.*]] = fir.convert %[[VAL_37]] : (!fir.box<!fir.array<?xi32>>) -> !fir.box<none>
  92 // CHECK:             %[[VAL_39:.*]] = fir.call @_FortranAPushValue(%[[VAL_22]], %[[VAL_38]]) : (!fir.llvm_ptr<i8>, !fir.box<none>) -> none
  93 // CHECK:           }
  94 // CHECK:           %[[VAL_40:.*]] = fir.convert %[[VAL_9]] : (i32) -> index
  95 // CHECK:           %[[VAL_41:.*]] = fir.convert %[[VAL_8]] : (i32) -> index
  96 // CHECK:           %[[VAL_42:.*]] = fir.convert %[[VAL_12]] : (i32) -> index
  97 // CHECK:           fir.store %[[VAL_16]] to %[[VAL_3]] : !fir.ref<i64>
  98 // CHECK:           fir.do_loop %[[VAL_43:.*]] = %[[VAL_40]] to %[[VAL_41]] step %[[VAL_42]] {
  99 // CHECK:             %[[VAL_44:.*]] = fir.convert %[[VAL_43]] : (index) -> i32
 100 // CHECK:             %[[VAL_45:.*]] = fir.load %[[VAL_3]] : !fir.ref<i64>
 101 // CHECK:             %[[VAL_46:.*]] = arith.addi %[[VAL_45]], %[[VAL_17]] : i64
 102 // CHECK:             fir.store %[[VAL_46]] to %[[VAL_3]] : !fir.ref<i64>
 103 // CHECK:             %[[VAL_47:.*]] = fir.convert %[[VAL_2]] : (!fir.ref<!fir.box<!fir.heap<!fir.array<?xi32>>>>) -> !fir.ref<!fir.box<none>>
 104 // CHECK:             %[[VAL_48:.*]] = fir.call @_FortranAValueAt(%[[VAL_22]], %[[VAL_45]], %[[VAL_47]]) : (!fir.llvm_ptr<i8>, i64, !fir.ref<!fir.box<none>>) -> none
 105 // CHECK:             %[[VAL_49:.*]] = fir.load %[[VAL_2]] : !fir.ref<!fir.box<!fir.heap<!fir.array<?xi32>>>>
 106 // CHECK:             %[[VAL_50:.*]] = fir.load %[[VAL_10]]#0 : !fir.ref<i32>
 107 // CHECK:             %[[VAL_51:.*]] = arith.addi %[[VAL_44]], %[[VAL_50]] : i32
 108 // CHECK:             %[[VAL_52:.*]] = arith.subi %[[VAL_51]], %[[VAL_9]] : i32
 109 // CHECK:             %[[VAL_53:.*]] = fir.convert %[[VAL_44]] : (i32) -> index
 110 // CHECK:             %[[VAL_54:.*]] = fir.convert %[[VAL_52]] : (i32) -> index
 111 // CHECK:             %[[VAL_55:.*]] = arith.subi %[[VAL_54]], %[[VAL_53]] : index
 112 // CHECK:             %[[VAL_56:.*]] = arith.addi %[[VAL_55]], %[[VAL_4]] : index
 113 // CHECK:             %[[VAL_57:.*]] = arith.cmpi sgt, %[[VAL_56]], %[[VAL_5]] : index
 114 // CHECK:             %[[VAL_58:.*]] = arith.select %[[VAL_57]], %[[VAL_56]], %[[VAL_5]] : index
 115 // CHECK:             %[[VAL_59:.*]] = fir.shape %[[VAL_58]] : (index) -> !fir.shape<1>
 116 // CHECK:             %[[VAL_60:.*]] = hlfir.designate %[[VAL_11]]#0 (%[[VAL_53]]:%[[VAL_54]]:%[[VAL_4]])  shape %[[VAL_59]] : (!fir.box<!fir.array<?xi32>>, index, index, index, !fir.shape<1>) -> !fir.box<!fir.array<?xi32>>
 117 // CHECK:             hlfir.assign %[[VAL_49]] to %[[VAL_60]] : !fir.box<!fir.heap<!fir.array<?xi32>>>, !fir.box<!fir.array<?xi32>>
 118 // CHECK:           }
 119 // CHECK:           %[[VAL_61:.*]] = fir.call @_FortranADestroyValueStack(%[[VAL_22]]) : (!fir.llvm_ptr<i8>) -> none
 120 // CHECK:           return
 121 // CHECK:         }
 122
 123
 124 // i1 needs to be passed as logical<> to be stored. Check converts are
 125 // introduced as expected.
 126 func.func @_QPdealing_with_i1(%x: !fir.ref<!fir.array<10x20xi32>>) {
 127   %c42_i32 = arith.constant 42 : i32
 128   %c10_i64 = arith.constant 10 : i64
 129   %c1_i64 = arith.constant 1 : i64
 130   hlfir.forall lb {
 131     hlfir.yield %c1_i64 : i64
 132   } ub {
 133     hlfir.yield %c10_i64 : i64
 134   }  (%arg1: i64) {
 135     hlfir.forall lb {
 136       hlfir.yield %c1_i64 : i64
 137     } ub {
 138       hlfir.yield %arg1 : i64
 139     }  (%arg2: i64) {
 140       hlfir.forall_mask {
 141         %1 = hlfir.designate %x (%arg2, %arg1)  : (!fir.ref<!fir.array<10x20xi32>>, i64, i64) -> !fir.ref<i32>
 142         %2 = fir.load %1 : !fir.ref<i32>
 143         %3 = arith.cmpi sgt, %2, %c42_i32 : i32
 144         hlfir.yield %3 : i1
 145       } do {
 146         hlfir.region_assign {
 147           hlfir.yield %c42_i32 : i32
 148         } to {
 149           %1 = hlfir.designate %x (%arg1, %arg2)  : (!fir.ref<!fir.array<10x20xi32>>, i64, i64) -> !fir.ref<i32>
 150           hlfir.yield %1 : !fir.ref<i32>
 151         }
 152       }
 153     }
 154   }
 155   return
 156 }
 157 // CHECK-LABEL:   func.func @_QPdealing_with_i1(
 158 // CHECK:           %[[VAL_1:.*]] = fir.alloca !fir.logical<1>
 159 // CHECK:           %[[VAL_2:.*]] = fir.alloca !fir.box<!fir.heap<!fir.logical<1>>>
 160 // CHECK:           fir.do_loop
 161 // CHECK:             fir.do_loop
 162 // CHECK:               %[[VAL_26:.*]] = arith.cmpi sgt
 163 // CHECK:               %[[VAL_27:.*]] = fir.convert %[[VAL_26]] : (i1) -> !fir.logical<1>
 164 // CHECK:               fir.store %[[VAL_27]] to %[[VAL_1]] : !fir.ref<!fir.logical<1>>
 165 // CHECK:               %[[VAL_28:.*]] = fir.embox %[[VAL_1]] : (!fir.ref<!fir.logical<1>>) -> !fir.box<!fir.logical<1>>
 166 // CHECK:               %[[VAL_29:.*]] = fir.convert %[[VAL_28]] : (!fir.box<!fir.logical<1>>) -> !fir.box<none>
 167 // CHECK:               %[[VAL_30:.*]] = fir.call @_FortranAPushValue(%{{.*}}, %[[VAL_29]]) : (!fir.llvm_ptr<i8>, !fir.box<none>) -> none
 168 // CHECK:             }
 169 // CHECK:           }
 170 // CHECK:           fir.do_loop
 171 // CHECK:             fir.do_loop
 172 // CHECK:               %[[VAL_43:.*]] = fir.convert %[[VAL_2]] : (!fir.ref<!fir.box<!fir.heap<!fir.logical<1>>>>) -> !fir.ref<!fir.box<none>>
 173 // CHECK:               %[[VAL_44:.*]] = fir.call @_FortranAValueAt(%{{.*}}, %{{.*}}, %[[VAL_43]])
 174 // CHECK:               %[[VAL_45:.*]] = fir.load %[[VAL_2]] : !fir.ref<!fir.box<!fir.heap<!fir.logical<1>>>>
 175 // CHECK:               %[[VAL_46:.*]] = fir.box_addr %[[VAL_45]] : (!fir.box<!fir.heap<!fir.logical<1>>>) -> !fir.heap<!fir.logical<1>>
 176 // CHECK:               %[[VAL_47:.*]] = fir.load %[[VAL_46]] : !fir.heap<!fir.logical<1>>
 177 // CHECK:               %[[VAL_48:.*]] = fir.convert %[[VAL_47]] : (!fir.logical<1>) -> i1
 178 // CHECK:             }
 179 // CHECK:           }