flang/test/HLFIR/product-lowering.fir

   1 // Test hlfir.product operation lowering to fir runtime call
   2 // RUN: fir-opt %s -lower-hlfir-intrinsics | FileCheck %s
   3
   4 // one argument product
   5 func.func @_QPproduct1(%arg0: !fir.box<!fir.array<?xi32>> {fir.bindc_name = "a"}, %arg1: !fir.ref<i32> {fir.bindc_name = "s"}) {
   6   %0:2 = hlfir.declare %arg0 {uniq_name = "_QFsum1Ea"} : (!fir.box<!fir.array<?xi32>>) -> (!fir.box<!fir.array<?xi32>>, !fir.box<!fir.array<?xi32>>)
   7   %1:2 = hlfir.declare %arg1 {uniq_name = "_QFsum1Es"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
   8   %2 = hlfir.product %0#0 {fastmath = #arith.fastmath<contract>} : (!fir.box<!fir.array<?xi32>>) -> i32
   9   hlfir.assign %2 to %1#0 : i32, !fir.ref<i32>
  10   return
  11 }
  12
  13 // CHECK-LABEL: func.func @_QPproduct1(
  14 // CHECK:           %[[ARG0:.*]]: !fir.box<!fir.array<?xi32>>
  15 // CHECK:           %[[ARG1:.*]]: !fir.ref<i32>
  16 // CHECK-DAG:     %[[ARRAY:.*]]:2 = hlfir.declare %[[ARG0]]
  17 // CHECK-DAG:     %[[RES:.*]]:2 = hlfir.declare %[[ARG1]]
  18 // CHECK-DAG:     %[[MASK:.*]] = fir.absent !fir.box<i1>
  19 // CHECK-DAG:     %[[ARRAY_ARG:.*]] = fir.convert %[[ARRAY]]#1 :  (!fir.box<!fir.array<?xi32>>) -> !fir.box<none>
  20 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK]] : (!fir.box<i1>) -> !fir.box<none>
  21 // CHECK:         %[[RET:.*]] = fir.call @_FortranAProductInteger4(%[[ARRAY_ARG]], %[[LOC_STR:.*]], %[[LOC_N:.*]], %[[INT:.*]], %[[MASK_ARG]]) fastmath<contract> : (!fir.box<none>, !fir.ref<i8>, i32, i32, !fir.box<none>) -> i32
  22 // CHECK-NEXT:    hlfir.assign %[[RET]] to %[[RES]]#0 : i32, !fir.ref<i32>
  23 // CHECK-NEXT:    return
  24 // CHECK-NEXT:  }
  25
  26 // product with DIM argument by-ref
  27 func.func @_QPproduct2(%arg0: !fir.box<!fir.array<?x?xi32>> {fir.bindc_name = "a"}, %arg1: !fir.box<!fir.array<?xi32>> {fir.bindc_name = "s"}, %arg2: !fir.ref<index> {fir.bindc_name = "d"}) {
  28   %0:2 = hlfir.declare %arg0 {uniq_name = "_QFproduct2Ea"} : (!fir.box<!fir.array<?x?xi32>>) -> (!fir.box<!fir.array<?x?xi32>>, !fir.box<!fir.array<?x?xi32>>)
  29   %1:2 = hlfir.declare %arg2 {uniq_name = "_QFproduct2Ed"} : (!fir.ref<index>) -> (!fir.ref<index>, !fir.ref<index>)
  30   %2:2 = hlfir.declare %arg1 {uniq_name = "_QFproduct2Es"} : (!fir.box<!fir.array<?xi32>>) -> (!fir.box<!fir.array<?xi32>>, !fir.box<!fir.array<?xi32>>)
  31   %3 = fir.load %1#0 : !fir.ref<index>
  32   %4 = hlfir.product %0#0 dim %3 {fastmath = #arith.fastmath<contract>} : (!fir.box<!fir.array<?x?xi32>>, index) -> !hlfir.expr<?xi32>
  33   hlfir.assign %4 to %2#0 : !hlfir.expr<?xi32>, !fir.box<!fir.array<?xi32>>
  34   hlfir.destroy %4 : !hlfir.expr<?xi32>
  35   return
  36 }
  37
  38 // CHECK-LABEL: func.func @_QPproduct2(
  39 // CHECK:           %[[ARG0:.*]]: !fir.box<!fir.array<?x?xi32>>
  40 // CHECK:           %[[ARG1:.*]]: !fir.box<!fir.array<?xi32>>
  41 // CHECK:           %[[ARG2:.*]]: !fir.ref<index>
  42 // CHECK-DAG:     %[[TRUE:.*]] = arith.constant true
  43 // CHECK-DAG:     %[[ARRAY:.*]]:2 = hlfir.declare %[[ARG0]]
  44 // CHECK-DAG:     %[[DIM_VAR:.*]]:2 = hlfir.declare %[[ARG2]]
  45 // CHECK-DAG:     %[[RES:.*]]:2 = hlfir.declare %[[ARG1]]
  46
  47 // CHECK-DAG:     %[[RET_BOX:.*]] = fir.alloca !fir.box<!fir.heap<!fir.array<?xi32>>>
  48 // CHECK-DAG:     %[[RET_ADDR:.*]] = fir.zero_bits !fir.heap<!fir.array<?xi32>>
  49 // CHECK-DAG:     %[[C0:.*]] = arith.constant 0 : index
  50 // CHECK-DAG:     %[[RET_SHAPE:.*]] = fir.shape %[[C0]] : (index) -> !fir.shape<1>
  51 // CHECK-DAG:     %[[RET_EMBOX:.*]] = fir.embox %[[RET_ADDR]](%[[RET_SHAPE]])
  52 // CHECK-DAG:     fir.store %[[RET_EMBOX]] to %[[RET_BOX]]
  53
  54 // CHECK-DAG:     %[[MASK:.*]] = fir.absent !fir.box<i1>
  55 // CHECK-DAG:     %[[DIM_IDX:.*]] = fir.load %[[DIM_VAR]]#0 : !fir.ref<index>
  56 // CHECK-DAG:     %[[DIM:.*]] = fir.convert %[[DIM_IDX]] : (index) -> i32
  57
  58 // CHECK-DAG:     %[[RET_ARG:.*]] = fir.convert %[[RET_BOX]]
  59 // CHECK-DAG:     %[[ARRAY_ARG:.*]] = fir.convert %[[ARRAY]]
  60 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK]]
  61
  62 // CHECK:         %[[NONE:.*]] = fir.call @_FortranAProductDim(%[[RET_ARG]], %[[ARRAY_ARG]], %[[DIM]], %[[LOC_STR:.*]], %[[LOC_N:.*]], %[[MASK_ARG]]) fastmath<contract> : (!fir.ref<!fir.box<none>>, !fir.box<none>, i32, !fir.ref<i8>, i32, !fir.box<none>) -> none
  63 // CHECK:         %[[RET:.*]] = fir.load %[[RET_BOX]]
  64 // CHECK:         %[[BOX_DIMS:.*]]:3 = fir.box_dims %[[RET]]
  65 // CHECK-NEXT:    %[[ADDR:.*]] = fir.box_addr %[[RET]]
  66 // CHECK-NEXT:    %[[SHIFT:.*]] = fir.shape_shift %[[BOX_DIMS]]#0, %[[BOX_DIMS]]#1
  67 // CHECK-NEXT:    %[[TMP:.*]]:2 = hlfir.declare %[[ADDR]](%[[SHIFT]]) {uniq_name = ".tmp.intrinsic_result"}
  68 // CHECK:         %[[EXPR:.*]] = hlfir.as_expr %[[TMP]]#0 move %[[TRUE]] : (!fir.box<!fir.array<?xi32>>, i1) -> !hlfir.expr<?xi32>
  69 // CHECK:         hlfir.assign %[[EXPR]] to %[[RES]]#0
  70 // CHECK:         hlfir.destroy %[[EXPR]]
  71 // CHECK-NEXT:    return
  72 // CHECK-NEXT:  }
  73
  74 // product with scalar mask
  75 func.func @_QPproduct3(%arg0: !fir.box<!fir.array<?xi32>> {fir.bindc_name = "a"}, %arg1: !fir.ref<i32> {fir.bindc_name = "s"}, %arg2: !fir.ref<!fir.logical<4>> {fir.bindc_name = "m"}) {
  76   %0:2 = hlfir.declare %arg0 {uniq_name = "_QFproduct3Ea"} : (!fir.box<!fir.array<?xi32>>) -> (!fir.box<!fir.array<?xi32>>, !fir.box<!fir.array<?xi32>>)
  77   %1:2 = hlfir.declare %arg2 {uniq_name = "_QFproduct3Em"} : (!fir.ref<!fir.logical<4>>) -> (!fir.ref<!fir.logical<4>>, !fir.ref<!fir.logical<4>>)
  78   %2:2 = hlfir.declare %arg1 {uniq_name = "_QFproduct3Es"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
  79   %3 = hlfir.product %0#0 mask %1#0 {fastmath = #arith.fastmath<contract>} : (!fir.box<!fir.array<?xi32>>, !fir.ref<!fir.logical<4>>) -> i32
  80   hlfir.assign %3 to %2#0 : i32, !fir.ref<i32>
  81   return
  82 }
  83
  84 // CHECK-LABEL: func.func @_QPproduct3(
  85 // CHECK:            %[[ARG0:.*]]: !fir.box<!fir.array<?xi32>>
  86 // CHECK:            %[[ARG1:.*]]: !fir.ref<i32>
  87 // CHECK:            %[[ARG2:.*]]: !fir.ref<!fir.logical<4>>
  88 // CHECK-DAG:      %[[ARRAY:.*]]:2 = hlfir.declare %[[ARG0]]
  89 // CHECK-DAG:      %[[RES:.*]]:2 = hlfir.declare %[[ARG1]]
  90 // CHECK-DAG:      %[[MASK:.*]]:2 = hlfir.declare %[[ARG2]]
  91 // CHECK-DAG:      %[[MASK_BOX:.*]] = fir.embox %[[MASK]]#1 : (!fir.ref<!fir.logical<4>>) -> !fir.box<!fir.logical<4>>
  92 // CHECK-DAG:      %[[ARRAY_ARG:.*]] = fir.convert %[[ARRAY]]#1 : (!fir.box<!fir.array<?xi32>>) -> !fir.box<none>
  93 // CHECK-DAG:      %[[MASK_ARG:.*]] = fir.convert %[[MASK_BOX]]  : (!fir.box<!fir.logical<4>>) -> !fir.box<none>
  94 // CHECK:          %[[RET:.*]] = fir.call @_FortranAProductInteger4(%[[ARRAY_ARG]], %[[LOC_STR:.*]], %[[LOC_N:.*]], %[[INT:.*]], %[[MASK_ARG]]) fastmath<contract> : (!fir.box<none>, !fir.ref<i8>, i32, i32, !fir.box<none>) -> i32
  95 // CHECK-NEXT:     hlfir.assign %[[RET]] to %[[RES]]#0 : i32, !fir.ref<i32>
  96 // CHECK-NEXT:     return
  97 // CHECK-NEXT:   }
  98
  99 // product with array mask
 100 func.func @_QPproduct4(%arg0: !fir.box<!fir.array<?xi32>> {fir.bindc_name = "a"}, %arg1: !fir.ref<i32> {fir.bindc_name = "s"}, %arg2: !fir.box<!fir.array<?x!fir.logical<4>>> {fir.bindc_name = "m"}) {
 101   %0:2 = hlfir.declare %arg0 {uniq_name = "_QFproduct4Ea"} : (!fir.box<!fir.array<?xi32>>) -> (!fir.box<!fir.array<?xi32>>, !fir.box<!fir.array<?xi32>>)
 102   %1:2 = hlfir.declare %arg2 {uniq_name = "_QFproduct4Em"} : (!fir.box<!fir.array<?x!fir.logical<4>>>) -> (!fir.box<!fir.array<?x!fir.logical<4>>>, !fir.box<!fir.array<?x!fir.logical<4>>>)
 103   %2:2 = hlfir.declare %arg1 {uniq_name = "_QFproduct4Es"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
 104   %3 = hlfir.product %0#0 mask %1#0 {fastmath = #arith.fastmath<contract>} : (!fir.box<!fir.array<?xi32>>, !fir.box<!fir.array<?x!fir.logical<4>>>) -> i32
 105   hlfir.assign %3 to %2#0 : i32, !fir.ref<i32>
 106   return
 107 }
 108
 109 // CHECK-LABEL: func.func @_QPproduct4(
 110 // CHECK:           %[[ARG0:.*]]: !fir.box<!fir.array<?xi32>
 111 // CHECK:           %[[ARG1:.*]]: !fir.ref<i32>
 112 // CHECK:           %[[ARG2:.*]]: !fir.box<!fir.array<?x!fir.logical<4>>>
 113 // CHECK-DAG:     %[[ARRAY]]:2 = hlfir.declare %[[ARG0]]
 114 // CHECK-DAG:     %[[RES]]:2 = hlfir.declare %[[ARG1]]
 115 // CHECK-DAG:     %[[MASK]]:2 = hlfir.declare %[[ARG2]]
 116 // CHECK-DAG:     %[[ARRAY_ARG:.*]] = fir.convert %[[ARRAY]]#1  : (!fir.box<!fir.array<?xi32>>) -> !fir.box<none>
 117 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK]]#1 : (!fir.box<!fir.array<?x!fir.logical<4>>>) -> !fir.box<none>
 118 // CHECK:         %[[RET:.*]] = fir.call @_FortranAProductInteger4(%[[ARRAY_ARG]], %[[LOC_STR:.*]], %[[LOC_N:.*]], %[[INT:.*]], %[[MASK_ARG]]) fastmath<contract> : (!fir.box<none>, !fir.ref<i8>, i32, i32, !fir.box<none>) -> i32
 119 // CHECK-NEXT:    hlfir.assign %[[RET]] to %[[RES]]#0 : i32, !fir.ref<i32>
 120 // CHECK-NEXT:    return
 121 // CHECK-NEXT:  }
 122
 123
 124 // product with all 3 arguments
 125 func.func @_QPproduct5(%arg0: !fir.ref<!fir.array<2xi32>> {fir.bindc_name = "s"}) {
 126   %0 = fir.address_of(@_QFproduct5Ea) : !fir.ref<!fir.array<2x2xi32>>
 127   %c2 = arith.constant 2 : index
 128   %c2_0 = arith.constant 2 : index
 129   %1 = fir.shape %c2, %c2_0 : (index, index) -> !fir.shape<2>
 130   %2:2 = hlfir.declare %0(%1) {uniq_name = "_QFproduct5Ea"} : (!fir.ref<!fir.array<2x2xi32>>, !fir.shape<2>) -> (!fir.ref<!fir.array<2x2xi32>>, !fir.ref<!fir.array<2x2xi32>>)
 131   %c2_1 = arith.constant 2 : index
 132   %3 = fir.shape %c2_1 : (index) -> !fir.shape<1>
 133   %4:2 = hlfir.declare %arg0(%3) {uniq_name = "_QFproduct5Es"} : (!fir.ref<!fir.array<2xi32>>, !fir.shape<1>) -> (!fir.ref<!fir.array<2xi32>>, !fir.ref<!fir.array<2xi32>>)
 134   %c1_i32 = arith.constant 1 : i32
 135   %true = arith.constant true
 136   %5 = hlfir.product %2#0 dim %c1_i32 mask %true {fastmath = #arith.fastmath<contract>} : (!fir.ref<!fir.array<2x2xi32>>, i32, i1) -> !hlfir.expr<2xi32>
 137   hlfir.assign %5 to %4#0 : !hlfir.expr<2xi32>, !fir.ref<!fir.array<2xi32>>
 138   hlfir.destroy %5 : !hlfir.expr<2xi32>
 139   return
 140 }
 141
 142 // CHECK-LABEL: func.func @_QPproduct5(
 143 // CHECK:           %[[ARG0:.*]]: !fir.ref<!fir.array<2xi32>>
 144 // CHECK-DAG:     %[[TRUE:.*]] = arith.constant true
 145 // CHECK-DAG:     %[[RET_BOX:.*]] = fir.alloca !fir.box<!fir.heap<!fir.array<?xi32>>>
 146 // CHECK-DAG:     %[[RET_ADDR:.*]] = fir.zero_bits !fir.heap<!fir.array<?xi32>>
 147 // CHECK-DAG:     %[[C0:.*]] = arith.constant 0 : index
 148 // CHECK-DAG:     %[[RET_SHAPE:.*]] = fir.shape %[[C0]] : (index) -> !fir.shape<1>
 149 // CHECK-DAG:     %[[RET_EMBOX:.*]] = fir.embox %[[RET_ADDR]](%[[RET_SHAPE]])
 150 // CHECK-DAG:     fir.store %[[RET_EMBOX]] to %[[RET_BOX]]
 151
 152 // CHECK-DAG:     %[[RES_VAR:.*]] = hlfir.declare %[[ARG0]](%[[RES_SHAPE:.*]])
 153
 154 // CHECK-DAG:     %[[MASK_ALLOC:.*]] = fir.alloca !fir.logical<4>
 155 // CHECK-DAG:     %[[MASK_VAL:.*]]  = fir.convert %[[TRUE]] : (i1) -> !fir.logical<4>
 156 // CHECK-DAG:     fir.store %[[MASK_VAL]] to %[[MASK_ALLOC]] : !fir.ref<!fir.logical<4>>
 157 // CHECK-DAG:     %[[MASK_BOX:.*]] = fir.embox %[[MASK_ALLOC]]
 158
 159 // CHECK-DAG:     %[[ARRAY_ADDR:.*]] = fir.address_of
 160 // CHECK-DAG:     %[[ARRAY_VAR:.*]]:2 = hlfir.declare %[[ARRAY_ADDR]](%[[ARRAY_SHAPE:.*]])
 161 // CHECK-DAG:     %[[ARRAY_BOX:.*]] = fir.embox %[[ARRAY_VAR]]#1(%[[ARRAY_SHAPE:.*]])
 162
 163 // CHECK-DAG:     %[[DIM:.*]] = arith.constant 1 : i32
 164
 165 // CHECK-DAG:     %[[RET_ARG:.*]] = fir.convert %[[RET_BOX]]
 166 // CHECK-DAG:     %[[ARRAY_ARG:.*]] = fir.convert %[[ARRAY_BOX]] : (!fir.box<!fir.array<2x2xi32>>) -> !fir.box<none>
 167 // CHECK-DAG:     %[[MASK_ARG:.*]] = fir.convert %[[MASK_BOX]] : (!fir.box<!fir.logical<4>>) -> !fir.box<none>
 168 // CHECK:         %[[NONE:.*]] = fir.call @_FortranAProductDim(%[[RET_ARG]], %[[ARRAY_ARG]], %[[DIM]], %[[LOC_STR:.*]], %[[LOC_N:.*]], %[[MASK_ARG]]) fastmath<contract> : (!fir.ref<!fir.box<none>>, !fir.box<none>, i32, !fir.ref<i8>, i32, !fir.box<none>) -> none