libc/AOR_v20.02/math/tools/log_abs.sollya

   1 // polynomial for approximating log(1+x)
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6
   7 deg = 6; // poly degree
   8 // interval ~= 1/(2*N), where N is the table entries
   9 a = -0x1.fp-9;
  10 b =  0x1.fp-9;
  11
  12 // find log(1+x) polynomial with minimal absolute error
  13 f = log(1+x);
  14
  15 // return p that minimizes |f(x) - poly(x) - x^d*p(x)|
  16 approx = proc(poly,d) {
  17   return remez(f(x) - poly(x), deg-d, [a;b], x^d, 1e-10);
  18 };
  19
  20 // first coeff is fixed, iteratively find optimal double prec coeffs
  21 poly = x;
  22 for i from 2 to deg do {
  23   p = roundcoefficients(approx(poly,i), [|D ...|]);
  24   poly = poly + x^i*coeff(p,0);
  25 };
  26
  27 display = hexadecimal;
  28 print("abs error:", accurateinfnorm(f(x)-poly(x), [a;b], 30));
  29 // relative error computation fails if f(0)==0
  30 // g = f(x)/x = log(1+x)/x; using taylor series
  31 g = 0;
  32 for i from 0 to 60 do { g = g + (-x)^i/(i+1); };
  33 print("rel error:", accurateinfnorm(1-poly(x)/x/g(x), [a;b], 30));
  34 print("in [",a,b,"]");
  35 print("coeffs:");
  36 for i from 0 to deg do coeff(poly,i);