libclc/generic/lib/math/clc_pown.cl

   1 /*
   2  * Copyright (c) 2014 Advanced Micro Devices, Inc.
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to deal
   6  * in the Software without restriction, including without limitation the rights
   7  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   8  * copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  19  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
  20  * THE SOFTWARE.
  21  */
  22
  23 #include <clc/clc.h>
  24 #include <clc/clcmacro.h>
  25 #include <clc/math/clc_fabs.h>
  26 #include <clc/math/clc_mad.h>
  27
  28 #include "config.h"
  29 #include "math.h"
  30 #include "tables.h"
  31
  32 // compute pow using log and exp
  33 // x^y = exp(y * log(x))
  34 //
  35 // we take care not to lose precision in the intermediate steps
  36 //
  37 // When computing log, calculate it in splits,
  38 //
  39 // r = f * (p_invead + p_inv_tail)
  40 // r = rh + rt
  41 //
  42 // calculate log polynomial using r, in end addition, do
  43 // poly = poly + ((rh-r) + rt)
  44 //
  45 // lth = -r
  46 // ltt = ((xexp * log2_t) - poly) + logT
  47 // lt = lth + ltt
  48 //
  49 // lh = (xexp * log2_h) + logH
  50 // l = lh + lt
  51 //
  52 // Calculate final log answer as gh and gt,
  53 // gh = l & higher-half bits
  54 // gt = (((ltt - (lt - lth)) + ((lh - l) + lt)) + (l - gh))
  55 //
  56 // yh = y & higher-half bits
  57 // yt = y - yh
  58 //
  59 // Before entering computation of exp,
  60 // vs = ((yt*gt + yt*gh) + yh*gt)
  61 // v = vs + yh*gh
  62 // vt = ((yh*gh - v) + vs)
  63 //
  64 // In calculation of exp, add vt to r that is used for poly
  65 // At the end of exp, do
  66 // ((((expT * poly) + expT) + expH*poly) + expH)
  67
  68 _CLC_DEF _CLC_OVERLOAD float __clc_pown(float x, int ny) {
  69   float y = (float)ny;
  70
  71   int ix = as_int(x);
  72   int ax = ix & EXSIGNBIT_SP32;
  73   int xpos = ix == ax;
  74
  75   int iy = as_int(y);
  76   int ay = iy & EXSIGNBIT_SP32;
  77   int ypos = iy == ay;
  78
  79   // Extra precise log calculation
  80   // First handle case that x is close to 1
  81   float r = 1.0f - as_float(ax);
  82   int near1 = __clc_fabs(r) < 0x1.0p-4f;
  83   float r2 = r * r;
  84
  85   // Coefficients are just 1/3, 1/4, 1/5 and 1/6
  86   float poly = __clc_mad(
  87       r,
  88       __clc_mad(r,
  89                 __clc_mad(r, __clc_mad(r, 0x1.24924ap-3f, 0x1.555556p-3f),
  90                           0x1.99999ap-3f),
  91                 0x1.000000p-2f),
  92       0x1.555556p-2f);
  93
  94   poly *= r2 * r;
  95
  96   float lth_near1 = -r2 * 0.5f;
  97   float ltt_near1 = -poly;
  98   float lt_near1 = lth_near1 + ltt_near1;
  99   float lh_near1 = -r;
 100   float l_near1 = lh_near1 + lt_near1;
 101
 102   // Computations for x not near 1
 103   int m = (int)(ax >> EXPSHIFTBITS_SP32) - EXPBIAS_SP32;
 104   float mf = (float)m;
 105   int ixs = as_int(as_float(ax | 0x3f800000) - 1.0f);
 106   float mfs = (float)((ixs >> EXPSHIFTBITS_SP32) - 253);
 107   int c = m == -127;
 108   int ixn = c ? ixs : ax;
 109   float mfn = c ? mfs : mf;
 110
 111   int indx = (ixn & 0x007f0000) + ((ixn & 0x00008000) << 1);
 112
 113   // F - Y
 114   float f = as_float(0x3f000000 | indx) -
 115             as_float(0x3f000000 | (ixn & MANTBITS_SP32));
 116
 117   indx = indx >> 16;
 118   float2 tv = USE_TABLE(log_inv_tbl_ep, indx);
 119   float rh = f * tv.s0;
 120   float rt = f * tv.s1;
 121   r = rh + rt;
 122
 123   poly = __clc_mad(r, __clc_mad(r, 0x1.0p-2f, 0x1.555556p-2f), 0x1.0p-1f) *
 124          (r * r);
 125   poly += (rh - r) + rt;
 126
 127   const float LOG2_HEAD = 0x1.62e000p-1f;  // 0.693115234
 128   const float LOG2_TAIL = 0x1.0bfbe8p-15f; // 0.0000319461833
 129   tv = USE_TABLE(loge_tbl, indx);
 130   float lth = -r;
 131   float ltt = __clc_mad(mfn, LOG2_TAIL, -poly) + tv.s1;
 132   float lt = lth + ltt;
 133   float lh = __clc_mad(mfn, LOG2_HEAD, tv.s0);
 134   float l = lh + lt;
 135
 136   // Select near 1 or not
 137   lth = near1 ? lth_near1 : lth;
 138   ltt = near1 ? ltt_near1 : ltt;
 139   lt = near1 ? lt_near1 : lt;
 140   lh = near1 ? lh_near1 : lh;
 141   l = near1 ? l_near1 : l;
 142
 143   float gh = as_float(as_int(l) & 0xfffff000);
 144   float gt = ((ltt - (lt - lth)) + ((lh - l) + lt)) + (l - gh);
 145
 146   float yh = as_float(iy & 0xfffff000);
 147
 148   float yt = (float)(ny - (int)yh);
 149
 150   float ylogx_s = __clc_mad(gt, yh, __clc_mad(gh, yt, yt * gt));
 151   float ylogx = __clc_mad(yh, gh, ylogx_s);
 152   float ylogx_t = __clc_mad(yh, gh, -ylogx) + ylogx_s;
 153
 154   // Extra precise exp of ylogx
 155   // 64/log2 : 92.332482616893657
 156   const float R_64_BY_LOG2 = 0x1.715476p+6f;
 157   int n = convert_int(ylogx * R_64_BY_LOG2);
 158   float nf = (float)n;
 159
 160   int j = n & 0x3f;
 161   m = n >> 6;
 162   int m2 = m << EXPSHIFTBITS_SP32;
 163
 164   // log2/64 lead: 0.0108032227
 165   const float R_LOG2_BY_64_LD = 0x1.620000p-7f;
 166   // log2/64 tail: 0.0000272020388
 167   const float R_LOG2_BY_64_TL = 0x1.c85fdep-16f;
 168   r = __clc_mad(nf, -R_LOG2_BY_64_TL, __clc_mad(nf, -R_LOG2_BY_64_LD, ylogx)) +
 169       ylogx_t;
 170
 171   // Truncated Taylor series for e^r
 172   poly = __clc_mad(__clc_mad(__clc_mad(r, 0x1.555556p-5f, 0x1.555556p-3f), r,
 173                              0x1.000000p-1f),
 174                    r * r, r);
 175
 176   tv = USE_TABLE(exp_tbl_ep, j);
 177
 178   float expylogx =
 179       __clc_mad(tv.s0, poly, __clc_mad(tv.s1, poly, tv.s1)) + tv.s0;
 180   float sexpylogx = expylogx * as_float(0x1 << (m + 149));
 181   float texpylogx = as_float(as_int(expylogx) + m2);
 182   expylogx = m < -125 ? sexpylogx : texpylogx;
 183
 184   // Result is +-Inf if (ylogx + ylogx_t) > 128*log2
 185   expylogx = ((ylogx > 0x1.62e430p+6f) |
 186               (ylogx == 0x1.62e430p+6f & ylogx_t > -0x1.05c610p-22f))
 187                  ? as_float(PINFBITPATT_SP32)
 188                  : expylogx;
 189
 190   // Result is 0 if ylogx < -149*log2
 191   expylogx = ylogx < -0x1.9d1da0p+6f ? 0.0f : expylogx;
 192
 193   // Classify y:
 194   //   inty = 0 means not an integer.
 195   //   inty = 1 means odd integer.
 196   //   inty = 2 means even integer.
 197
 198   int inty = 2 - (ny & 1);
 199
 200   float signval = as_float((as_uint(expylogx) ^ SIGNBIT_SP32));
 201   expylogx = ((inty == 1) & !xpos) ? signval : expylogx;
 202   int ret = as_int(expylogx);
 203
 204   // Corner case handling
 205   int xinf = xpos ? PINFBITPATT_SP32 : NINFBITPATT_SP32;
 206   ret = ((ax == 0) & !ypos & (inty == 1)) ? xinf : ret;
 207   ret = ((ax == 0) & !ypos & (inty == 2)) ? PINFBITPATT_SP32 : ret;
 208   ret = ((ax == 0) & ypos & (inty == 2)) ? 0 : ret;
 209   int xzero = !xpos ? 0x80000000 : 0L;
 210   ret = ((ax == 0) & ypos & (inty == 1)) ? xzero : ret;
 211   ret = ((ix == NINFBITPATT_SP32) & !ypos & (inty == 1)) ? 0x80000000 : ret;
 212   ret = ((ix == NINFBITPATT_SP32) & !ypos & (inty != 1)) ? 0 : ret;
 213   ret =
 214       ((ix == NINFBITPATT_SP32) & ypos & (inty == 1)) ? NINFBITPATT_SP32 : ret;
 215   ret =
 216       ((ix == NINFBITPATT_SP32) & ypos & (inty != 1)) ? PINFBITPATT_SP32 : ret;
 217   ret = ((ix == PINFBITPATT_SP32) & !ypos) ? 0 : ret;
 218   ret = ((ix == PINFBITPATT_SP32) & ypos) ? PINFBITPATT_SP32 : ret;
 219   ret = ax > PINFBITPATT_SP32 ? ix : ret;
 220   ret = ny == 0 ? 0x3f800000 : ret;
 221
 222   return as_float(ret);
 223 }
 224 _CLC_BINARY_VECTORIZE(_CLC_DEF _CLC_OVERLOAD, float, __clc_pown, float, int)
 225
 226 #ifdef cl_khr_fp64
 227 _CLC_DEF _CLC_OVERLOAD double __clc_pown(double x, int ny) {
 228   const double real_log2_tail = 5.76999904754328540596e-08;
 229   const double real_log2_lead = 6.93147122859954833984e-01;
 230
 231   double y = (double)ny;
 232
 233   long ux = as_long(x);
 234   long ax = ux & (~SIGNBIT_DP64);
 235   int xpos = ax == ux;
 236
 237   long uy = as_long(y);
 238   long ay = uy & (~SIGNBIT_DP64);
 239   int ypos = ay == uy;
 240
 241   // Extended precision log
 242   double v, vt;
 243   {
 244     int exp = (int)(ax >> 52) - 1023;
 245     int mask_exp_1023 = exp == -1023;
 246     double xexp = (double)exp;
 247     long mantissa = ax & 0x000FFFFFFFFFFFFFL;
 248
 249     long temp_ux = as_long(as_double(0x3ff0000000000000L | mantissa) - 1.0);
 250     exp = ((temp_ux & 0x7FF0000000000000L) >> 52) - 2045;
 251     double xexp1 = (double)exp;
 252     long mantissa1 = temp_ux & 0x000FFFFFFFFFFFFFL;
 253
 254     xexp = mask_exp_1023 ? xexp1 : xexp;
 255     mantissa = mask_exp_1023 ? mantissa1 : mantissa;
 256
 257     long rax = (mantissa & 0x000ff00000000000) +
 258                ((mantissa & 0x0000080000000000) << 1);
 259     int index = rax >> 44;
 260
 261     double F = as_double(rax | 0x3FE0000000000000L);
 262     double Y = as_double(mantissa | 0x3FE0000000000000L);
 263     double f = F - Y;
 264     double2 tv = USE_TABLE(log_f_inv_tbl, index);
 265     double log_h = tv.s0;
 266     double log_t = tv.s1;
 267     double f_inv = (log_h + log_t) * f;
 268     double r1 = as_double(as_long(f_inv) & 0xfffffffff8000000L);
 269     double r2 = fma(-F, r1, f) * (log_h + log_t);
 270     double r = r1 + r2;
 271
 272     double poly = fma(
 273         r, fma(r, fma(r, fma(r, 1.0 / 7.0, 1.0 / 6.0), 1.0 / 5.0), 1.0 / 4.0),
 274         1.0 / 3.0);
 275     poly = poly * r * r * r;
 276
 277     double hr1r1 = 0.5 * r1 * r1;
 278     double poly0h = r1 + hr1r1;
 279     double poly0t = r1 - poly0h + hr1r1;
 280     poly = fma(r1, r2, fma(0.5 * r2, r2, poly)) + r2 + poly0t;
 281
 282     tv = USE_TABLE(powlog_tbl, index);
 283     log_h = tv.s0;
 284     log_t = tv.s1;
 285
 286     double resT_t = fma(xexp, real_log2_tail, +log_t) - poly;
 287     double resT = resT_t - poly0h;
 288     double resH = fma(xexp, real_log2_lead, log_h);
 289     double resT_h = poly0h;
 290
 291     double H = resT + resH;
 292     double H_h = as_double(as_long(H) & 0xfffffffff8000000L);
 293     double T = (resH - H + resT) + (resT_t - (resT + resT_h)) + (H - H_h);
 294     H = H_h;
 295
 296     double y_head = as_double(uy & 0xfffffffff8000000L);
 297     double y_tail = y - y_head;
 298
 299     int mask_2_24 = ay > 0x4170000000000000; // 2^24
 300     int nyh = convert_int(y_head);
 301     int nyt = ny - nyh;
 302     double y_tail1 = (double)nyt;
 303     y_tail = mask_2_24 ? y_tail1 : y_tail;
 304
 305     double temp = fma(y_tail, H, fma(y_head, T, y_tail * T));
 306     v = fma(y_head, H, temp);
 307     vt = fma(y_head, H, -v) + temp;
 308   }
 309
 310   // Now calculate exp of (v,vt)
 311
 312   double expv;
 313   {
 314     const double max_exp_arg = 709.782712893384;
 315     const double min_exp_arg = -745.1332191019411;
 316     const double sixtyfour_by_lnof2 = 92.33248261689366;
 317     const double lnof2_by_64_head = 0.010830424260348081;
 318     const double lnof2_by_64_tail = -4.359010638708991e-10;
 319
 320     double temp = v * sixtyfour_by_lnof2;
 321     int n = (int)temp;
 322     double dn = (double)n;
 323     int j = n & 0x0000003f;
 324     int m = n >> 6;
 325
 326     double2 tv = USE_TABLE(two_to_jby64_ep_tbl, j);
 327     double f1 = tv.s0;
 328     double f2 = tv.s1;
 329     double f = f1 + f2;
 330
 331     double r1 = fma(dn, -lnof2_by_64_head, v);
 332     double r2 = dn * lnof2_by_64_tail;
 333     double r = (r1 + r2) + vt;
 334
 335     double q = fma(
 336         r,
 337         fma(r,
 338             fma(r,
 339                 fma(r, 1.38889490863777199667e-03, 8.33336798434219616221e-03),
 340                 4.16666666662260795726e-02),
 341             1.66666666665260878863e-01),
 342         5.00000000000000008883e-01);
 343     q = fma(r * r, q, r);
 344
 345     expv = fma(f, q, f2) + f1;
 346     expv = ldexp(expv, m);
 347
 348     expv = v > max_exp_arg ? as_double(0x7FF0000000000000L) : expv;
 349     expv = v < min_exp_arg ? 0.0 : expv;
 350   }
 351
 352   // See whether y is an integer.
 353   // inty = 0 means not an integer.
 354   // inty = 1 means odd integer.
 355   // inty = 2 means even integer.
 356
 357   int inty = 2 - (ny & 1);
 358
 359   expv *= ((inty == 1) & !xpos) ? -1.0 : 1.0;
 360
 361   long ret = as_long(expv);
 362
 363   // Now all the edge cases
 364   long xinf = xpos ? PINFBITPATT_DP64 : NINFBITPATT_DP64;
 365   ret = ((ax == 0L) & !ypos & (inty == 1)) ? xinf : ret;
 366   ret = ((ax == 0L) & !ypos & (inty == 2)) ? PINFBITPATT_DP64 : ret;
 367   ret = ((ax == 0L) & ypos & (inty == 2)) ? 0L : ret;
 368   long xzero = !xpos ? 0x8000000000000000L : 0L;
 369   ret = ((ax == 0L) & ypos & (inty == 1)) ? xzero : ret;
 370   ret = ((ux == NINFBITPATT_DP64) & !ypos & (inty == 1)) ? 0x8000000000000000L
 371                                                          : ret;
 372   ret = ((ux == NINFBITPATT_DP64) & !ypos & (inty != 1)) ? 0L : ret;
 373   ret =
 374       ((ux == NINFBITPATT_DP64) & ypos & (inty == 1)) ? NINFBITPATT_DP64 : ret;
 375   ret =
 376       ((ux == NINFBITPATT_DP64) & ypos & (inty != 1)) ? PINFBITPATT_DP64 : ret;
 377   ret = ((ux == PINFBITPATT_DP64) & !ypos) ? 0L : ret;
 378   ret = ((ux == PINFBITPATT_DP64) & ypos) ? PINFBITPATT_DP64 : ret;
 379   ret = ax > PINFBITPATT_DP64 ? ux : ret;
 380   ret = ny == 0 ? 0x3ff0000000000000L : ret;
 381
 382   return as_double(ret);
 383 }
 384 _CLC_BINARY_VECTORIZE(_CLC_DEF _CLC_OVERLOAD, double, __clc_pown, double, int)
 385 #endif
 386
 387 #ifdef cl_khr_fp16
 388
 389 #pragma OPENCL EXTENSION cl_khr_fp16 : enable
 390
 391 _CLC_OVERLOAD _CLC_DEF half __clc_pown(half x, int y) {
 392     return (half)__clc_pown((float)x, y);
 393 }
 394
 395 _CLC_BINARY_VECTORIZE(_CLC_OVERLOAD _CLC_DEF, half, __clc_pown, half, int);
 396
 397 #endif