llvm/test/CodeGen/AArch64/cgdata-merge-local.ll

   1 ; This test checks if two similar functions, f1 and f2, can be merged locally within a single module
   2 ; while parameterizing a difference in their global variables, g1 and g2.
   3 ; To achieve this, we create two instances of the global merging function, f1.Tgm and f2.Tgm,
   4 ; which are tail-called from thunks f1 and f2 respectively.
   5 ; These identical functions, f1.Tgm and f2.Tgm, will be folded by the linker via Identical Code Folding (ICF).
   6
   7 ; RUN: opt -mtriple=arm64-apple-darwin -S --passes=global-merge-func %s | FileCheck %s
   8
   9 ; A merging instance is created with additional parameter.
  10 ; CHECK: define internal i32 @f1.Tgm(i32 %0, ptr %1)
  11 ; CHECK-NEXT: entry:
  12 ; CHECK-NEXT:  %idxprom = sext i32 %0 to i64
  13 ; CHECK-NEXT:  %arrayidx = getelementptr inbounds [0 x i32], ptr @g, i64 0, i64 %idxprom
  14 ; CHECK-NEXT:  %2 = load i32, ptr %arrayidx, align 4
  15 ; CHECK-NEXT:  %3 = load volatile i32, ptr %1, align 4
  16 ; CHECK-NEXT:  %mul = mul nsw i32 %3, %2
  17 ; CHECK-NEXT:  %add = add nsw i32 %mul, 1
  18 ; CHECK-NEXT:  ret i32 %add
  19
  20 ; The original function becomes a thunk passing g1.
  21 ; CHECK: define i32 @f1(i32 %a)
  22 ; CHECK-NEXT:  %1 = tail call i32 @f1.Tgm(i32 %a, ptr @g1)
  23 ; CHECK-NEXT:  ret i32 %1
  24
  25 ; A same sequence is produced for f2.Tgm.
  26 ; CHECK: define internal i32 @f2.Tgm(i32 %0, ptr %1)
  27 ; CHECK-NEXT: entry:
  28 ; CHECK-NEXT:  %idxprom = sext i32 %0 to i64
  29 ; CHECK-NEXT:  %arrayidx = getelementptr inbounds [0 x i32], ptr @g, i64 0, i64 %idxprom
  30 ; CHECK-NEXT:  %2 = load i32, ptr %arrayidx, align 4
  31 ; CHECK-NEXT:  %3 = load volatile i32, ptr %1, align 4
  32 ; CHECK-NEXT:  %mul = mul nsw i32 %3, %2
  33 ; CHECK-NEXT:  %add = add nsw i32 %mul, 1
  34 ; CHECK-NEXT:  ret i32 %add
  35
  36 ; The original function becomes a thunk passing g2.
  37 ; CHECK: define i32 @f2(i32 %a)
  38 ; CHECK-NEXT:  %1 = tail call i32 @f2.Tgm(i32 %a, ptr @g2)
  39 ; CHECK-NEXT:  ret i32 %1
  40
  41 ; RUN: llc -mtriple=arm64-apple-darwin -enable-global-merge-func=true < %s | FileCheck %s --check-prefix=MERGE
  42 ; RUN: llc -mtriple=arm64-apple-darwin -enable-global-merge-func=false < %s | FileCheck %s --check-prefix=NOMERGE
  43
  44 ; MERGE: _f1.Tgm
  45 ; MERGE: _f2.Tgm
  46
  47 ; NOMERGE-NOT: _f1.Tgm
  48 ; NOMERGE-NOT: _f2.Tgm
  49
  50 @g = external local_unnamed_addr global [0 x i32], align 4
  51 @g1 = external global i32, align 4
  52 @g2 = external global i32, align 4
  53
  54 define i32 @f1(i32 %a) {
  55 entry:
  56   %idxprom = sext i32 %a to i64
  57   %arrayidx = getelementptr inbounds [0 x i32], [0 x i32]* @g, i64 0, i64 %idxprom
  58   %0 = load i32, i32* %arrayidx, align 4
  59   %1 = load volatile i32, i32* @g1, align 4
  60   %mul = mul nsw i32 %1, %0
  61   %add = add nsw i32 %mul, 1
  62   ret i32 %add
  63 }
  64
  65 define i32 @f2(i32 %a) {
  66 entry:
  67   %idxprom = sext i32 %a to i64
  68   %arrayidx = getelementptr inbounds [0 x i32], [0 x i32]* @g, i64 0, i64 %idxprom
  69   %0 = load i32, i32* %arrayidx, align 4
  70   %1 = load volatile i32, i32* @g2, align 4
  71   %mul = mul nsw i32 %1, %0
  72   %add = add nsw i32 %mul, 1
  73   ret i32 %add
  74 }