llvm/test/CodeGen/AArch64/func-calls.ll

   1 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64-none-linux-gnu | FileCheck %s
   2 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64-none-linux-gnu -mattr=-neon | FileCheck --check-prefix=CHECK-NONEON %s
   3 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64-none-linux-gnu -mattr=-fp-armv8 | FileCheck --check-prefix=CHECK-NOFP %s
   4 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64_be-none-linux-gnu | FileCheck --check-prefix=CHECK-BE %s
   5
   6 %myStruct = type { i64 , i8, i32 }
   7
   8 @var8 = dso_local global i8 0
   9 @var8_2 = dso_local global i8 0
  10 @var32 = dso_local global i32 0
  11 @var64 = dso_local global i64 0
  12 @var128 = dso_local global i128 0
  13 @varfloat = dso_local global float 0.0
  14 @varfloat_2 = dso_local global float 0.0
  15 @vardouble = dso_local global double 0.0
  16 @varstruct = dso_local global %myStruct zeroinitializer
  17 @varsmallstruct = dso_local global [2 x i64] zeroinitializer
  18
  19 declare void @take_i8s(i8 %val1, i8 %val2)
  20 declare void @take_floats(float %val1, float %val2)
  21
  22 define dso_local void @simple_args() {
  23 ; CHECK-LABEL: simple_args:
  24   %char1 = load i8, ptr @var8
  25   %char2 = load i8, ptr @var8_2
  26   call void @take_i8s(i8 %char1, i8 %char2)
  27 ; CHECK-DAG: ldrb w0, [{{x[0-9]+}}, {{#?}}:lo12:var8]
  28 ; CHECK-DAG: ldrb w1, [{{x[0-9]+}}, {{#?}}:lo12:var8_2]
  29 ; CHECK: bl take_i8s
  30
  31   %float1 = load float, ptr @varfloat
  32   %float2 = load float, ptr @varfloat_2
  33   call void @take_floats(float %float1, float %float2)
  34 ; CHECK-DAG: ldr s1, [{{x[0-9]+}}, {{#?}}:lo12:varfloat_2]
  35 ; CHECK-DAG: ldr s0, [{{x[0-9]+}}, {{#?}}:lo12:varfloat]
  36 ; CHECK: bl take_floats
  37 ; CHECK-NOFP-NOT: ldr s1,
  38 ; CHECK-NOFP-NOT: ldr s0,
  39
  40   ret void
  41 }
  42
  43 declare i32 @return_int()
  44 declare double @return_double()
  45 declare [2 x i64] @return_smallstruct()
  46 declare void @return_large_struct(ptr sret(%myStruct) %retval)
  47
  48 define dso_local void @simple_rets() {
  49 ; CHECK-LABEL: simple_rets:
  50
  51   %int = call i32 @return_int()
  52   store i32 %int, ptr @var32
  53 ; CHECK: bl return_int
  54 ; CHECK: str w0, [{{x[0-9]+}}, {{#?}}:lo12:var32]
  55
  56   %dbl = call double @return_double()
  57   store double %dbl, ptr @vardouble
  58 ; CHECK: bl return_double
  59 ; CHECK: str d0, [{{x[0-9]+}}, {{#?}}:lo12:vardouble]
  60 ; CHECK-NOFP-NOT: str d0,
  61
  62   %arr = call [2 x i64] @return_smallstruct()
  63   store [2 x i64] %arr, ptr @varsmallstruct
  64 ; CHECK: bl return_smallstruct
  65 ; CHECK: add x[[VARSMALLSTRUCT:[0-9]+]], {{x[0-9]+}}, :lo12:varsmallstruct
  66 ; CHECK: stp x0, x1, [x[[VARSMALLSTRUCT]]]
  67
  68   call void @return_large_struct(ptr sret(%myStruct) @varstruct)
  69 ; CHECK: add x8, {{x[0-9]+}}, {{#?}}:lo12:varstruct
  70 ; CHECK: bl return_large_struct
  71
  72   ret void
  73 }
  74
  75
  76 declare i32 @struct_on_stack(i8 %var0, i16 %var1, i32 %var2, i64 %var3, i128 %var45,
  77                              ptr %var6, ptr byval(%myStruct) %struct, i32 %stacked,
  78                              double %notstacked)
  79 declare void @stacked_fpu(float %var0, double %var1, float %var2, float %var3,
  80                           float %var4, float %var5, float %var6, float %var7,
  81                           float %var8)
  82
  83 define dso_local void @check_stack_args() {
  84 ; CHECK-LABEL: check_stack_args:
  85   call i32 @struct_on_stack(i8 0, i16 12, i32 42, i64 99, i128 1,
  86                             ptr @var32, ptr byval(%myStruct) @varstruct,
  87                             i32 999, double 1.0)
  88   ; Want to check that the final double is passed in registers and
  89   ; that varstruct is passed on the stack. Rather dependent on how a
  90   ; memcpy gets created, but the following works for now.
  91
  92 ; CHECK-DAG: str {{q[0-9]+}}, [sp]
  93 ; CHECK-DAG: fmov d0, #1.0
  94
  95 ; CHECK-NONEON-DAG: str {{q[0-9]+}}, [sp]
  96 ; CHECK-NONEON-DAG: fmov d0, #1.0
  97
  98 ; CHECK: bl struct_on_stack
  99 ; CHECK-NOFP-NOT: fmov
 100
 101   call void @stacked_fpu(float -1.0, double 1.0, float 4.0, float 2.0,
 102                          float -2.0, float -8.0, float 16.0, float 1.0,
 103                          float 64.0)
 104
 105 ; CHECK:  mov [[SIXTY_FOUR:w[0-9]+]], #1115684864
 106 ; CHECK: str [[SIXTY_FOUR]], [sp]
 107
 108 ; CHECK-NONEON:  mov [[SIXTY_FOUR:w[0-9]+]], #1115684864
 109 ; CHECK-NONEON: str [[SIXTY_FOUR]], [sp]
 110
 111 ; CHECK: bl stacked_fpu
 112   ret void
 113 }
 114
 115
 116 declare void @check_i128_stackalign(i32 %val0, i32 %val1, i32 %val2, i32 %val3,
 117                                     i32 %val4, i32 %val5, i32 %val6, i32 %val7,
 118                                     i32 %stack1, i128 %stack2)
 119
 120 declare void @check_i128_regalign(i32 %val0, i128 %val1)
 121
 122
 123 define dso_local void @check_i128_align() {
 124 ; CHECK-LABEL: check_i128_align:
 125   %val = load i128, ptr @var128
 126   call void @check_i128_stackalign(i32 0, i32 1, i32 2, i32 3,
 127                                    i32 4, i32 5, i32 6, i32 7,
 128                                    i32 42, i128 %val)
 129 ; CHECK: add x[[VAR128:[0-9]+]], {{x[0-9]+}}, :lo12:var128
 130 ; CHECK: ldp [[I128LO:x[0-9]+]], [[I128HI:x[0-9]+]], [x[[VAR128]]]
 131 ; CHECK: stp [[I128HI]], {{x[0-9]+}}, [sp, #24]
 132
 133 ; CHECK-NONEON: add x[[VAR128:[0-9]+]], {{x[0-9]+}}, :lo12:var128
 134 ; CHECK-NONEON: ldp [[I128LO:x[0-9]+]], [[I128HI:x[0-9]+]], [x[[VAR128]]]
 135 ; CHECK-NONEON: stp [[I128HI]], {{x[0-9]+}}, [sp, #24]
 136 ; CHECK: bl check_i128_stackalign
 137
 138   call void @check_i128_regalign(i32 0, i128 42)
 139 ; CHECK-NOT: mov x1
 140 ; CHECK-LE: mov x2, #{{0x2a|42}}
 141 ; CHECK-LE: mov x3, xzr
 142 ; CHECK-BE: mov x2, xzr
 143 ; CHECK-BE: mov {{x|w}}3, #{{0x2a|42}}
 144 ; CHECK: bl check_i128_regalign
 145
 146   ret void
 147 }
 148
 149 @fptr = dso_local global ptr null
 150
 151 define dso_local void @check_indirect_call() {
 152 ; CHECK-LABEL: check_indirect_call:
 153   %func = load ptr, ptr @fptr
 154   call void %func()
 155 ; CHECK: ldr [[FPTR:x[0-9]+]], [{{x[0-9]+}}, {{#?}}:lo12:fptr]
 156 ; CHECK: blr [[FPTR]]
 157
 158   ret void
 159 }