llvm/test/Transforms/AddDiscriminators/multiple.ll

   1 ; RUN: opt < %s -passes=add-discriminators -S | FileCheck %s
   2
   3 ; Discriminator support for multiple CFG paths on the same line.
   4 ;
   5 ;       void foo(int i) {
   6 ;         int x;
   7 ;         if (i < 10) x = i; else x = -i;
   8 ;       }
   9 ;
  10 ; The two stores inside the if-then-else line must have different discriminator
  11 ; values.
  12
  13 define void @foo(i32 %i) #0 !dbg !4 {
  14 entry:
  15   %i.addr = alloca i32, align 4
  16   %x = alloca i32, align 4
  17   store i32 %i, ptr %i.addr, align 4
  18   %0 = load i32, ptr %i.addr, align 4, !dbg !10
  19   %cmp = icmp slt i32 %0, 10, !dbg !10
  20   br i1 %cmp, label %if.then, label %if.else, !dbg !10
  21
  22 if.then:                                          ; preds = %entry
  23   %1 = load i32, ptr %i.addr, align 4, !dbg !10
  24 ; CHECK:  %1 = load i32, ptr %i.addr, align 4, !dbg ![[THEN:[0-9]+]]
  25
  26   store i32 %1, ptr %x, align 4, !dbg !10
  27 ; CHECK:  store i32 %1, ptr %x, align 4, !dbg ![[THEN]]
  28
  29   br label %if.end, !dbg !10
  30 ; CHECK:  br label %if.end, !dbg ![[THEN]]
  31
  32 if.else:                                          ; preds = %entry
  33   %2 = load i32, ptr %i.addr, align 4, !dbg !10
  34 ; CHECK:  %2 = load i32, ptr %i.addr, align 4, !dbg ![[ELSE:[0-9]+]]
  35
  36   %sub = sub nsw i32 0, %2, !dbg !10
  37 ; CHECK:  %sub = sub nsw i32 0, %2, !dbg ![[ELSE]]
  38
  39   store i32 %sub, ptr %x, align 4, !dbg !10
  40 ; CHECK:  store i32 %sub, ptr %x, align 4, !dbg ![[ELSE]]
  41
  42   br label %if.end
  43
  44 if.end:                                           ; preds = %if.else, %if.then
  45   ret void, !dbg !12
  46 }
  47
  48 attributes #0 = { nounwind uwtable "less-precise-fpmad"="false" "frame-pointer"="all" "no-infs-fp-math"="false" "no-nans-fp-math"="false" "stack-protector-buffer-size"="8" "unsafe-fp-math"="false" "use-soft-float"="false" }
  49
  50 !llvm.dbg.cu = !{!0}
  51 !llvm.module.flags = !{!7, !8}
  52 !llvm.ident = !{!9}
  53
  54 !0 = distinct !DICompileUnit(language: DW_LANG_C99, producer: "clang version 3.5 (trunk 199750) (llvm/trunk 199751)", isOptimized: false, emissionKind: NoDebug, file: !1, enums: !2, retainedTypes: !2, globals: !2, imports: !2)
  55 !1 = !DIFile(filename: "multiple.c", directory: ".")
  56 !2 = !{}
  57 !4 = distinct !DISubprogram(name: "foo", line: 1, isLocal: false, isDefinition: true, virtualIndex: 6, flags: DIFlagPrototyped, isOptimized: false, unit: !0, scopeLine: 1, file: !1, scope: !5, type: !6, retainedNodes: !2)
  58 !5 = !DIFile(filename: "multiple.c", directory: ".")
  59 !6 = !DISubroutineType(types: !{null, !13})
  60 !13 = !DIBasicType(encoding: DW_ATE_signed, name: "int", size: 32, align: 32)
  61 !7 = !{i32 2, !"Dwarf Version", i32 4}
  62 !8 = !{i32 1, !"Debug Info Version", i32 3}
  63 !9 = !{!"clang version 3.5 (trunk 199750) (llvm/trunk 199751)"}
  64 !10 = !DILocation(line: 3, scope: !11)
  65 !11 = distinct !DILexicalBlock(line: 3, column: 0, file: !1, scope: !4)
  66 !12 = !DILocation(line: 4, scope: !4)
  67
  68 ; CHECK: ![[THEN]] = !DILocation(line: 3, scope: ![[THENBLOCK:[0-9]+]])
  69 ; CHECK: ![[THENBLOCK]] = !DILexicalBlockFile(scope: ![[SCOPE:[0-9]+]],{{.*}} discriminator: 2)
  70 ; CHECK: ![[ELSE]] = !DILocation(line: 3, scope: ![[ELSEBLOCK:[0-9]+]])
  71 ; CHECK: ![[ELSEBLOCK]] = !DILexicalBlockFile(scope: ![[SCOPE]],{{.*}} discriminator: 4)