llvm/test/Transforms/Coroutines/coro-alloca-04.ll

   1 ; Tests that CoroSplit can succesfully determine allocas should live on the frame
   2 ; if their aliases are used across suspension points through PHINode.
   3 ; RUN: opt < %s -passes='cgscc(coro-split),simplifycfg,early-cse' -S | FileCheck %s
   4
   5 define ptr @f(i1 %n) presplitcoroutine {
   6 entry:
   7   %x = alloca i64
   8   br i1 %n, label %flag_true, label %flag_false
   9
  10 flag_true:
  11   br label %merge
  12
  13 flag_false:
  14   br label %merge
  15
  16 merge:
  17   %alias_phi = phi ptr [ %x, %flag_true ], [ %x, %flag_false ]
  18   %id = call token @llvm.coro.id(i32 0, ptr null, ptr null, ptr null)
  19   %size = call i32 @llvm.coro.size.i32()
  20   %alloc = call ptr @malloc(i32 %size)
  21   %hdl = call ptr @llvm.coro.begin(token %id, ptr %alloc)
  22   %sp1 = call i8 @llvm.coro.suspend(token none, i1 false)
  23   switch i8 %sp1, label %suspend [i8 0, label %resume
  24                                   i8 1, label %cleanup]
  25 resume:
  26   call void @print(ptr %alias_phi)
  27   br label %cleanup
  28
  29 cleanup:
  30   %mem = call ptr @llvm.coro.free(token %id, ptr %hdl)
  31   call void @free(ptr %mem)
  32   br label %suspend
  33
  34 suspend:
  35   call i1 @llvm.coro.end(ptr %hdl, i1 0, token none)
  36   ret ptr %hdl
  37 }
  38
  39 ; both %x and %alias_phi would go to the frame.
  40 ; CHECK:       %f.Frame = type { ptr, ptr, i64, ptr, i1 }
  41 ; CHECK-LABEL: @f(
  42 ; CHECK:         store ptr @f.destroy, ptr %destroy.addr
  43 ; CHECK-NEXT:    %0 = getelementptr inbounds %f.Frame, ptr %hdl, i32 0, i32 2
  44 ; CHECK:         %alias_phi.spill.addr = getelementptr inbounds %f.Frame, ptr %hdl, i32 0, i32 3
  45 ; CHECK-NEXT:    store ptr %0, ptr %alias_phi.spill.addr
  46
  47 declare ptr @llvm.coro.free(token, ptr)
  48 declare i32 @llvm.coro.size.i32()
  49 declare i8  @llvm.coro.suspend(token, i1)
  50 declare void @llvm.coro.resume(ptr)
  51 declare void @llvm.coro.destroy(ptr)
  52
  53 declare token @llvm.coro.id(i32, ptr, ptr, ptr)
  54 declare i1 @llvm.coro.alloc(token)
  55 declare ptr @llvm.coro.begin(token, ptr)
  56 declare i1 @llvm.coro.end(ptr, i1, token)
  57
  58 declare void @print(ptr)
  59 declare noalias ptr @malloc(i32)
  60 declare void @free(ptr)