llvm/test/Transforms/Coroutines/coro-debug-frame-variable.ll

   1 ; RUN: opt < %s -passes='default<O0>' -S | FileCheck %s
   2 ; RUN: opt --try-experimental-debuginfo-iterators < %s -passes='default<O0>' -S | FileCheck %s
   3
   4 ; Define a function 'f' that resembles the Clang frontend's output for the
   5 ; following C++ coroutine:
   6 ;
   7 ;   void foo() {
   8 ;     int i = 0;
   9 ;     ++i;
  10 ;     int x = {};
  11 ;     print(i);  // Prints '1'
  12 ;
  13 ;     co_await suspend_always();
  14 ;
  15 ;     int j = 0;
  16 ;     x[0] = 1;
  17 ;     x[1] = 2;
  18 ;     ++i;
  19 ;     print(i);  // Prints '2'
  20 ;     ++j;
  21 ;     print(j);  // Prints '1'
  22 ;     print(x);  // Print '1'
  23 ;   }
  24 ;
  25 ; The CHECKs verify that dbg.declare intrinsics are created for the coroutine
  26 ; funclet 'f.resume', and that they reference the address of the variables on
  27 ; the coroutine frame. The debug locations for the original function 'f' are
  28 ; static (!11 and !13), whereas the coroutine funclet will have its own new
  29 ; ones with identical line and column numbers.
  30 ;
  31 ; CHECK-LABEL: define void @f() {{.*}} {
  32 ; CHECK:       entry:
  33 ; CHECK:         %j = alloca i32, align 4
  34 ; CHECK:         #dbg_declare(ptr %j, ![[JVAR:[0-9]+]], !DIExpression(), ![[JDBGLOC:[0-9]+]]
  35 ; CHECK:         %[[MEMORY:.*]] = call ptr @new({{.+}}), !dbg ![[IDBGLOC:[0-9]+]]
  36 ; CHECK:         #dbg_declare(ptr %[[MEMORY]], ![[XVAR:[0-9]+]], !DIExpression(DW_OP_plus_uconst, 32), ![[IDBGLOC]]
  37 ; CHECK:         #dbg_declare(ptr %[[MEMORY]], ![[IVAR:[0-9]+]], !DIExpression(DW_OP_plus_uconst, 20), ![[IDBGLOC]]
  38 ; CHECK:       await.ready:
  39 ;
  40 ; CHECK-LABEL: define internal fastcc void @f.resume({{.*}}) {{.*}} {
  41 ; CHECK:       entry.resume:
  42 ; CHECK-NEXT:    %[[DBG_PTR:.*]] = alloca ptr
  43 ; CHECK-NEXT:    #dbg_declare(ptr %[[DBG_PTR]], ![[XVAR_RESUME:[0-9]+]],   !DIExpression(DW_OP_deref, DW_OP_plus_uconst, 32),
  44 ; CHECK-NEXT:    #dbg_declare(ptr %[[DBG_PTR]], ![[IVAR_RESUME:[0-9]+]], !DIExpression(DW_OP_deref, DW_OP_plus_uconst, 20), ![[IDBGLOC_RESUME:[0-9]+]]
  45 ; CHECK-NEXT:    #dbg_declare(ptr %[[DBG_PTR]], ![[FRAME_RESUME:[0-9]+]], !DIExpression(DW_OP_deref),
  46 ; CHECK-NEXT:    store ptr {{.*}}, ptr %[[DBG_PTR]]
  47 ; CHECK:         %[[J:.*]] = alloca i32, align 4
  48 ; CHECK-NEXT:    #dbg_declare(ptr %[[J]], ![[JVAR_RESUME:[0-9]+]], !DIExpression(), ![[JDBGLOC_RESUME:[0-9]+]]
  49 ; CHECK:       init.ready:
  50 ; CHECK:       await.ready:
  51 ;
  52 ; CHECK-DAG: ![[FRAME_RESUME]] = !DILocalVariable(name: "__coro_frame"
  53 ; CHECK-DAG: ![[IVAR]] = !DILocalVariable(name: "i"
  54 ; CHECK-DAG: ![[PROG_SCOPE:[0-9]+]] = distinct !DISubprogram(name: "foo", linkageName: "_Z3foov"
  55 ; CHECK-DAG: ![[BLK_SCOPE:[0-9]+]] = distinct !DILexicalBlock(scope: ![[PROG_SCOPE]], file: !1, line: 23, column: 12)
  56 ; CHECK-DAG: ![[IDBGLOC]] = !DILocation(line: 23, column: 6, scope: ![[PROG_SCOPE]])
  57 ; CHECK-DAG: ![[XVAR]] = !DILocalVariable(name: "x"
  58 ; CHECK-DAG: ![[JVAR]] = !DILocalVariable(name: "j"
  59 ; CHECK-DAG: ![[JDBGLOC]] = !DILocation(line: 32, column: 7, scope: ![[BLK_SCOPE]])
  60
  61 ; CHECK-DAG: ![[XVAR_RESUME]] = !DILocalVariable(name: "x"
  62 ; CHECK-DAG: ![[RESUME_PROG_SCOPE:[0-9]+]] = distinct !DISubprogram(name: "foo", linkageName: "_Z3foov"
  63 ; CHECK-DAG: ![[IDBGLOC_RESUME]] = !DILocation(line: 24, column: 7, scope: ![[RESUME_BLK_SCOPE:[0-9]+]])
  64 ; CHECK-DAG: ![[RESUME_BLK_SCOPE]] = distinct !DILexicalBlock(scope: ![[RESUME_PROG_SCOPE]], file: !1, line: 23, column: 12)
  65 ; CHECK-DAG: ![[IVAR_RESUME]] = !DILocalVariable(name: "i"
  66 ; CHECK-DAG: ![[JVAR_RESUME]] = !DILocalVariable(name: "j"
  67 ; CHECK-DAG: ![[JDBGLOC_RESUME]] = !DILocation(line: 32, column: 7, scope: ![[RESUME_BLK_SCOPE]])
  68 define void @f() presplitcoroutine !dbg !8 {
  69 entry:
  70   %__promise = alloca i8, align 8
  71   %i = alloca i32, align 4
  72   %j = alloca i32, align 4
  73   %x = alloca [10 x i32], align 16
  74   %id = call token @llvm.coro.id(i32 16, ptr %__promise, ptr null, ptr null)
  75   %alloc = call i1 @llvm.coro.alloc(token %id)
  76   br i1 %alloc, label %coro.alloc, label %coro.init
  77
  78 coro.alloc:                                       ; preds = %entry
  79   %size = call i64 @llvm.coro.size.i64(), !dbg !23
  80   %memory = call ptr @new(i64 %size), !dbg !23
  81   br label %coro.init, !dbg !23
  82
  83 coro.init:                                        ; preds = %coro.alloc, %entry
  84   %phi.entry.alloc = phi ptr [ null, %entry ], [ %memory, %coro.alloc ], !dbg !23
  85   %begin = call ptr @llvm.coro.begin(token %id, ptr %phi.entry.alloc), !dbg !23
  86   %ready = call i1 @await_ready()
  87   br i1 %ready, label %init.ready, label %init.suspend
  88
  89 init.suspend:                                     ; preds = %coro.init
  90   %save = call token @llvm.coro.save(ptr null)
  91   call void @await_suspend()
  92   %suspend = call i8 @llvm.coro.suspend(token %save, i1 false)
  93   switch i8 %suspend, label %coro.ret [
  94     i8 0, label %init.ready
  95     i8 1, label %init.cleanup
  96   ]
  97
  98 init.cleanup:                                     ; preds = %init.suspend
  99   br label %cleanup
 100
 101 init.ready:                                       ; preds = %init.suspend, %coro.init
 102   call void @await_resume()
 103   call void @llvm.dbg.declare(metadata ptr %i, metadata !6, metadata !DIExpression()), !dbg !11
 104   store i32 0, ptr %i, align 4
 105   %i.init.ready.load = load i32, ptr %i, align 4
 106   %i.init.ready.inc = add nsw i32 %i.init.ready.load, 1
 107   store i32 %i.init.ready.inc, ptr %i, align 4
 108   call void @llvm.dbg.declare(metadata ptr %x, metadata !14, metadata !DIExpression()), !dbg !11
 109   call void @llvm.memset.p0.i64(ptr align 16 %x, i8 0, i64 40, i1 false), !dbg !11
 110   %i.init.ready.reload = load i32, ptr %i, align 4
 111   call void @print(i32 %i.init.ready.reload)
 112   %ready.again = call zeroext i1 @await_ready()
 113   br i1 %ready.again, label %await.ready, label %await.suspend
 114
 115 await.suspend:                                    ; preds = %init.ready
 116   %save.again = call token @llvm.coro.save(ptr null)
 117   %from.address = call ptr @from_address(ptr %begin)
 118   call void @await_suspend()
 119   %suspend.again = call i8 @llvm.coro.suspend(token %save.again, i1 false)
 120   switch i8 %suspend.again, label %coro.ret [
 121     i8 0, label %await.ready
 122     i8 1, label %await.cleanup
 123   ]
 124
 125 await.cleanup:                                    ; preds = %await.suspend
 126   br label %cleanup
 127
 128 await.ready:                                      ; preds = %await.suspend, %init.ready
 129   call void @await_resume()
 130   call void @llvm.dbg.declare(metadata ptr %j, metadata !12, metadata !DIExpression()), !dbg !13
 131   store i32 0, ptr %j, align 4
 132   store i32 1, ptr %x, align 16, !dbg !19
 133   %arrayidx1 = getelementptr inbounds [10 x i32], ptr %x, i64 0, i64 1, !dbg !20
 134   store i32 2, ptr %arrayidx1, align 4, !dbg !21
 135   %i.await.ready.load = load i32, ptr %i, align 4
 136   %i.await.ready.inc = add nsw i32 %i.await.ready.load, 1
 137   store i32 %i.await.ready.inc, ptr %i, align 4
 138   %j.await.ready.load = load i32, ptr %j, align 4
 139   %j.await.ready.inc = add nsw i32 %j.await.ready.load, 1
 140   store i32 %j.await.ready.inc, ptr %j, align 4
 141   %i.await.ready.reload = load i32, ptr %i, align 4
 142   call void @print(i32 %i.await.ready.reload)
 143   %j.await.ready.reload = load i32, ptr %j, align 4
 144   call void @print(i32 %j.await.ready.reload)
 145   call void @return_void()
 146   br label %coro.final
 147
 148 coro.final:                                       ; preds = %await.ready
 149   call void @final_suspend()
 150   %coro.final.await_ready = call i1 @await_ready()
 151   br i1 %coro.final.await_ready, label %final.ready, label %final.suspend
 152
 153 final.suspend:                                    ; preds = %coro.final
 154   %final.suspend.coro.save = call token @llvm.coro.save(ptr null)
 155   %final.suspend.from_address = call ptr @from_address(ptr %begin)
 156   call void @await_suspend()
 157   %final.suspend.coro.suspend = call i8 @llvm.coro.suspend(token %final.suspend.coro.save, i1 true)
 158   switch i8 %final.suspend.coro.suspend, label %coro.ret [
 159     i8 0, label %final.ready
 160     i8 1, label %final.cleanup
 161   ]
 162
 163 final.cleanup:                                    ; preds = %final.suspend
 164   br label %cleanup
 165
 166 final.ready:                                      ; preds = %final.suspend, %coro.final
 167   call void @await_resume()
 168   br label %cleanup
 169
 170 cleanup:                                          ; preds = %final.ready, %final.cleanup, %await.cleanup, %init.cleanup
 171   %cleanup.dest.slot.0 = phi i32 [ 0, %final.ready ], [ 2, %final.cleanup ], [ 2, %await.cleanup ], [ 2, %init.cleanup ]
 172   %free.memory = call ptr @llvm.coro.free(token %id, ptr %begin)
 173   %free = icmp ne ptr %free.memory, null
 174   br i1 %free, label %coro.free, label %after.coro.free
 175
 176 coro.free:                                        ; preds = %cleanup
 177   call void @delete(ptr %free.memory)
 178   br label %after.coro.free
 179
 180 after.coro.free:                                  ; preds = %coro.free, %cleanup
 181   switch i32 %cleanup.dest.slot.0, label %unreachable [
 182     i32 0, label %cleanup.cont
 183     i32 2, label %coro.ret
 184   ]
 185
 186 cleanup.cont:                                     ; preds = %after.coro.free
 187   br label %coro.ret
 188
 189 coro.ret:                                         ; preds = %cleanup.cont, %after.coro.free, %final.suspend, %await.suspend, %init.suspend
 190   %end = call i1 @llvm.coro.end(ptr null, i1 false, token none)
 191   ret void
 192
 193 unreachable:                                      ; preds = %after.coro.free
 194   unreachable
 195 }
 196
 197 declare void @llvm.dbg.declare(metadata, metadata, metadata)
 198 declare token @llvm.coro.id(i32, ptr readnone, ptr nocapture readonly, ptr)
 199 declare i1 @llvm.coro.alloc(token)
 200 declare i64 @llvm.coro.size.i64()
 201 declare token @llvm.coro.save(ptr)
 202 declare ptr @llvm.coro.begin(token, ptr writeonly)
 203 declare i8 @llvm.coro.suspend(token, i1)
 204 declare ptr @llvm.coro.free(token, ptr nocapture readonly)
 205 declare i1 @llvm.coro.end(ptr, i1, token)
 206
 207 declare ptr @new(i64)
 208 declare void @delete(ptr)
 209 declare i1 @await_ready()
 210 declare void @await_suspend()
 211 declare void @await_resume()
 212 declare void @print(i32)
 213 declare ptr @from_address(ptr)
 214 declare void @return_void()
 215 declare void @final_suspend()
 216
 217 declare void @llvm.memset.p0.i64(ptr nocapture writeonly, i8, i64, i1 immarg)
 218
 219 !llvm.dbg.cu = !{!0}
 220 !llvm.linker.options = !{}
 221 !llvm.module.flags = !{!3, !4}
 222 !llvm.ident = !{!5}
 223
 224 !0 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus_14, file: !1, producer: "clang version 11.0.0", isOptimized: false, runtimeVersion: 0, emissionKind: FullDebug, enums: !2, retainedTypes: !2, splitDebugInlining: false, nameTableKind: None)
 225 !1 = !DIFile(filename: "repro.cpp", directory: ".")
 226 !2 = !{}
 227 !3 = !{i32 7, !"Dwarf Version", i32 4}
 228 !4 = !{i32 2, !"Debug Info Version", i32 3}
 229 !5 = !{!"clang version 11.0.0"}
 230 !6 = !DILocalVariable(name: "i", scope: !7, file: !1, line: 24, type: !10)
 231 !7 = distinct !DILexicalBlock(scope: !8, file: !1, line: 23, column: 12)
 232 !8 = distinct !DISubprogram(name: "foo", linkageName: "_Z3foov", scope: !1, file: !1, line: 23, type: !9, scopeLine: 23, flags: DIFlagPrototyped, spFlags: DISPFlagDefinition, unit: !0, retainedNodes: !2)
 233 !9 = !DISubroutineType(types: !2)
 234 !10 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
 235 !11 = !DILocation(line: 24, column: 7, scope: !7)
 236 !12 = !DILocalVariable(name: "j", scope: !7, file: !1, line: 32, type: !10)
 237 !13 = !DILocation(line: 32, column: 7, scope: !7)
 238 !14 = !DILocalVariable(name: "x", scope: !22, file: !1, line: 34, type: !15)
 239 !15 = !DICompositeType(tag: DW_TAG_array_type, baseType: !10, size: 320, elements: !16)
 240 !16 = !{!17}
 241 !17 = !DISubrange(count: 10)
 242 !18 = !DILocation(line: 42, column: 3, scope: !7)
 243 !19 = !DILocation(line: 42, column: 8, scope: !7)
 244 !20 = !DILocation(line: 43, column: 3, scope: !7)
 245 !21 = !DILocation(line: 43, column: 8, scope: !7)
 246 !22 = distinct !DILexicalBlock(scope: !8, file: !1, line: 23, column: 12)
 247 !23 = !DILocation(line: 23, column: 6, scope: !8)