llvm/test/Transforms/GlobalOpt/invariant.group.ll

   1 ; RUN: opt -S -passes=globalopt < %s | FileCheck %s
   2
   3 ; CHECK: @llvm.global_ctors = appending global [1 x {{.*}}@_GLOBAL__I_c
   4 @llvm.global_ctors = appending global [3 x { i32, ptr, ptr }] [{ i32, ptr, ptr } { i32 65535, ptr @_GLOBAL__I_a, ptr null }, { i32, ptr, ptr } { i32 65535, ptr @_GLOBAL__I_b, ptr null }, { i32, ptr, ptr } { i32 65535, ptr @_GLOBAL__I_c, ptr null }]
   5
   6 ; CHECK: @tmp = local_unnamed_addr global i32 42
   7 ; CHECK: @tmp2 = local_unnamed_addr global i32 42
   8 ; CHECK: @tmp3 = global i32 42
   9 @tmp = global i32 0
  10 @tmp2 = global i32 0
  11 @tmp3 = global i32 0
  12 @ptrToTmp3 = global ptr null
  13
  14 define i32 @TheAnswerToLifeTheUniverseAndEverything() {
  15   ret i32 42
  16 }
  17
  18 define void @_GLOBAL__I_a() {
  19 enter:
  20   call void @_optimizable()
  21   call void @_not_optimizable()
  22   ret void
  23 }
  24
  25 define void @_optimizable() {
  26 enter:
  27   %valptr = alloca i32
  28
  29   %val = call i32 @TheAnswerToLifeTheUniverseAndEverything()
  30   store i32 %val, ptr @tmp
  31   store i32 %val, ptr %valptr
  32
  33   %barr = call ptr @llvm.launder.invariant.group(ptr %valptr)
  34
  35   %val2 = load i32, ptr %barr
  36   store i32 %val2, ptr @tmp2
  37   ret void
  38 }
  39
  40 ; We can't step through launder.invariant.group here, because that would change
  41 ; this load in @usage_of_globals()
  42 ; %val = load i32, ptr %ptrVal, !invariant.group !0
  43 ; into
  44 ; %val = load i32, ptr @tmp3, !invariant.group !0
  45 ; and then we could assume that %val and %val2 to be the same, which coud be
  46 ; false, because @changeTmp3ValAndCallBarrierInside() may change the value
  47 ; of @tmp3.
  48 define void @_not_optimizable() {
  49 enter:
  50   store i32 13, ptr @tmp3, !invariant.group !0
  51
  52   %barr = call ptr @llvm.launder.invariant.group(ptr @tmp3)
  53
  54   store ptr %barr, ptr @ptrToTmp3
  55   store i32 42, ptr %barr, !invariant.group !0
  56
  57   ret void
  58 }
  59
  60 define void @usage_of_globals() {
  61 entry:
  62   %ptrVal = load ptr, ptr @ptrToTmp3
  63   %val = load i32, ptr %ptrVal, !invariant.group !0
  64
  65   call void @changeTmp3ValAndCallBarrierInside()
  66   %val2 = load i32, ptr @tmp3, !invariant.group !0
  67   ret void;
  68 }
  69
  70 @tmp4 = global i32 0
  71
  72 define void @_GLOBAL__I_b() {
  73 enter:
  74   %val = call i32 @TheAnswerToLifeTheUniverseAndEverything()
  75   %p2 = call ptr @llvm.strip.invariant.group.p0(ptr @tmp4)
  76   store i32 %val, ptr %p2
  77   ret void
  78 }
  79
  80 @tmp5 = global i32 0
  81 @tmp6 = global ptr null
  82 ; CHECK: @tmp6 = local_unnamed_addr global ptr null
  83
  84 define ptr @_dont_return_param(ptr %p) {
  85   %p2 = call ptr @llvm.launder.invariant.group(ptr %p)
  86   ret ptr %p2
  87 }
  88
  89 ; We should bail out if we return any pointers derived via invariant.group intrinsics at any point.
  90 define void @_GLOBAL__I_c() {
  91 enter:
  92   %tmp5 = call ptr @_dont_return_param(ptr @tmp5)
  93   store ptr %tmp5, ptr @tmp6
  94   ret void
  95 }
  96
  97
  98 declare void @changeTmp3ValAndCallBarrierInside()
  99
 100 declare ptr @llvm.launder.invariant.group(ptr)
 101 declare ptr @llvm.strip.invariant.group.p0(ptr)
 102
 103 !0 = !{}