mlir/test/Target/LLVMIR/openmp-parallel-reduction-cleanup.mlir

   1 // RUN: mlir-translate -mlir-to-llvmir -split-input-file %s | FileCheck %s
   2
   3 // test a parallel reduction with a cleanup region
   4
   5   omp.declare_reduction @add_reduction_i_32 : !llvm.ptr init {
   6   ^bb0(%arg0: !llvm.ptr):
   7     %0 = llvm.mlir.constant(0 : i32) : i32
   8     %c4 = llvm.mlir.constant(4 : i64) : i64
   9     %2 = llvm.call @malloc(%c4) : (i64) -> !llvm.ptr
  10     llvm.store %0, %2 : i32, !llvm.ptr
  11     omp.yield(%2 : !llvm.ptr)
  12   } combiner {
  13   ^bb0(%arg0: !llvm.ptr, %arg1: !llvm.ptr):
  14     %0 = llvm.load %arg0 : !llvm.ptr -> i32
  15     %1 = llvm.load %arg1 : !llvm.ptr -> i32
  16     %2 = llvm.add %0, %1  : i32
  17     llvm.store %2, %arg0 : i32, !llvm.ptr
  18     omp.yield(%arg0 : !llvm.ptr)
  19   } cleanup {
  20   ^bb0(%arg0: !llvm.ptr):
  21     llvm.call @free(%arg0) : (!llvm.ptr) -> ()
  22     omp.yield
  23   }
  24
  25   // CHECK-LABEL: @main
  26   llvm.func @main()  {
  27     %0 = llvm.mlir.constant(-1 : i32) : i32
  28     %1 = llvm.mlir.addressof @i : !llvm.ptr
  29     %2 = llvm.mlir.addressof @j : !llvm.ptr
  30     omp.parallel reduction(byref @add_reduction_i_32 %1 -> %arg0, byref @add_reduction_i_32 %2 -> %arg1 : !llvm.ptr, !llvm.ptr) {
  31       llvm.store %0, %arg0 : i32, !llvm.ptr
  32       llvm.store %0, %arg1 : i32, !llvm.ptr
  33       omp.terminator
  34     }
  35     llvm.return
  36   }
  37   llvm.mlir.global internal @i() {addr_space = 0 : i32} : i32 {
  38     %0 = llvm.mlir.constant(0 : i32) : i32
  39     llvm.return %0 : i32
  40   }
  41   llvm.mlir.global internal @j() {addr_space = 0 : i32} : i32 {
  42     %0 = llvm.mlir.constant(0 : i32) : i32
  43     llvm.return %0 : i32
  44   }
  45   llvm.func @malloc(%arg0 : i64) -> !llvm.ptr
  46   llvm.func @free(%arg0 : !llvm.ptr) -> ()
  47
  48 // CHECK: %{{.+}} =
  49 // Call to the outlined function.
  50 // CHECK: call void {{.*}} @__kmpc_fork_call
  51 // CHECK-SAME: @[[OUTLINED:[A-Za-z_.][A-Za-z0-9_.]*]]
  52
  53 // Outlined function.
  54 // CHECK: define internal void @[[OUTLINED]]
  55
  56 // Private reduction variable and its initialization.
  57 // CHECK: %tid.addr.local = alloca i32
  58 // CHECK: %[[PRIV_PTR_I:.+]] = alloca ptr
  59 // CHECK: %[[PRIV_PTR_J:.+]] = alloca ptr
  60 // CHECK: %[[MALLOC_I:.+]] = call ptr @malloc(i64 4)
  61 // CHECK: store ptr %[[MALLOC_I]], ptr %[[PRIV_PTR_I]]
  62 // CHECK: %[[MALLOC_J:.+]] = call ptr @malloc(i64 4)
  63 // CHECK: store ptr %[[MALLOC_J]], ptr %[[PRIV_PTR_J]]
  64
  65 // Call to the reduction function.
  66 // CHECK: call i32 @__kmpc_reduce
  67 // CHECK-SAME: @[[REDFUNC:[A-Za-z_.][A-Za-z0-9_.]*]]
  68
  69
  70 // Non-atomic reduction:
  71 // CHECK: %[[PRIV_VAL_PTR_I:.+]] = load ptr, ptr %[[PRIV_PTR_I]]
  72 // CHECK: %[[LOAD_I:.+]] = load i32, ptr @i
  73 // CHECK: %[[PRIV_VAL_I:.+]] = load i32, ptr %[[PRIV_VAL_PTR_I]]
  74 // CHECK: %[[SUM_I:.+]] = add i32 %[[LOAD_I]], %[[PRIV_VAL_I]]
  75 // CHECK: store i32 %[[SUM_I]], ptr @i
  76 // CHECK: %[[PRIV_VAL_PTR_J:.+]] = load ptr, ptr %[[PRIV_PTR_J]]
  77 // CHECK: %[[LOAD_J:.+]] = load i32, ptr @j
  78 // CHECK: %[[PRIV_VAL_J:.+]] = load i32, ptr %[[PRIV_VAL_PTR_J]]
  79 // CHECK: %[[SUM_J:.+]] = add i32 %[[LOAD_J]], %[[PRIV_VAL_J]]
  80 // CHECK: store i32 %[[SUM_J]], ptr @j
  81 // CHECK: call void @__kmpc_end_reduce
  82 // CHECK: br label %[[FINALIZE:.+]]
  83
  84 // CHECK: [[FINALIZE]]:
  85 // CHECK: br label %[[OMP_FINALIZE:.+]]
  86
  87 // Cleanup region:
  88 // CHECK: [[OMP_FINALIZE]]:
  89 // CHECK: %[[PRIV_I:.+]] = load ptr, ptr %[[PRIV_PTR_I]], align 8
  90 // CHECK: call void @free(ptr %[[PRIV_I]])
  91 // CHECK: %[[PRIV_J:.+]] = load ptr, ptr %[[PRIV_PTR_J]], align 8
  92 // CHECK: call void @free(ptr %[[PRIV_J]])
  93
  94 // Reduction function.
  95 // CHECK: define internal void @[[REDFUNC]]
  96 // CHECK: add i32