mlir/test/mlir-vulkan-runner/addi.mlir

   1 // RUN: mlir-vulkan-runner %s --shared-libs=%vulkan-runtime-wrappers,%mlir_runner_utils --entry-point-result=void | FileCheck %s
   2
   3 // CHECK-COUNT-64: [3, 3, 3, 3, 3, 3, 3, 3]
   4 module attributes {
   5   gpu.container_module,
   6   spirv.target_env = #spirv.target_env<
   7     #spirv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>, #spirv.resource_limits<>>
   8 } {
   9   gpu.module @kernels {
  10     gpu.func @kernel_addi(%arg0 : memref<8xi32>, %arg1 : memref<8x8xi32>, %arg2 : memref<8x8x8xi32>)
  11       kernel attributes { spirv.entry_point_abi = #spirv.entry_point_abi<workgroup_size = [1, 1, 1]>} {
  12       %x = gpu.block_id x
  13       %y = gpu.block_id y
  14       %z = gpu.block_id z
  15       %0 = memref.load %arg0[%x] : memref<8xi32>
  16       %1 = memref.load %arg1[%y, %x] : memref<8x8xi32>
  17       %2 = arith.addi %0, %1 : i32
  18       memref.store %2, %arg2[%z, %y, %x] : memref<8x8x8xi32>
  19       gpu.return
  20     }
  21   }
  22
  23   func.func @main() {
  24     %arg0 = memref.alloc() : memref<8xi32>
  25     %arg1 = memref.alloc() : memref<8x8xi32>
  26     %arg2 = memref.alloc() : memref<8x8x8xi32>
  27     %value0 = arith.constant 0 : i32
  28     %value1 = arith.constant 1 : i32
  29     %value2 = arith.constant 2 : i32
  30     %arg3 = memref.cast %arg0 : memref<8xi32> to memref<?xi32>
  31     %arg4 = memref.cast %arg1 : memref<8x8xi32> to memref<?x?xi32>
  32     %arg5 = memref.cast %arg2 : memref<8x8x8xi32> to memref<?x?x?xi32>
  33     call @fillResource1DInt(%arg3, %value1) : (memref<?xi32>, i32) -> ()
  34     call @fillResource2DInt(%arg4, %value2) : (memref<?x?xi32>, i32) -> ()
  35     call @fillResource3DInt(%arg5, %value0) : (memref<?x?x?xi32>, i32) -> ()
  36
  37     %cst1 = arith.constant 1 : index
  38     %cst8 = arith.constant 8 : index
  39     gpu.launch_func @kernels::@kernel_addi
  40         blocks in (%cst8, %cst8, %cst8) threads in (%cst1, %cst1, %cst1)
  41         args(%arg0 : memref<8xi32>, %arg1 : memref<8x8xi32>, %arg2 : memref<8x8x8xi32>)
  42     %arg6 = memref.cast %arg5 : memref<?x?x?xi32> to memref<*xi32>
  43     call @printMemrefI32(%arg6) : (memref<*xi32>) -> ()
  44     return
  45   }
  46   func.func private @fillResource1DInt(%0 : memref<?xi32>, %1 : i32)
  47   func.func private @fillResource2DInt(%0 : memref<?x?xi32>, %1 : i32)
  48   func.func private @fillResource3DInt(%0 : memref<?x?x?xi32>, %1 : i32)
  49   func.func private @printMemrefI32(%ptr : memref<*xi32>)
  50 }
  51