mlir/test/mlir-vulkan-runner/time.mlir

   1 // RUN: mlir-vulkan-runner %s --shared-libs=%vulkan-runtime-wrappers,%mlir_runner_utils --entry-point-result=void | FileCheck %s
   2
   3 // CHECK: Compute shader execution time
   4 // CHECK: Command buffer submit time
   5 // CHECK: Wait idle time
   6
   7 module attributes {
   8   gpu.container_module,
   9   spirv.target_env = #spirv.target_env<
  10     #spirv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>, #spirv.resource_limits<>>
  11 } {
  12   gpu.module @kernels {
  13     gpu.func @kernel_add(%arg0 : memref<16384xf32>, %arg1 : memref<16384xf32>, %arg2 : memref<16384xf32>)
  14       kernel attributes { spirv.entry_point_abi = #spirv.entry_point_abi<workgroup_size = [128, 1, 1]>} {
  15       %bid = gpu.block_id x
  16       %tid = gpu.thread_id x
  17       %cst = arith.constant 128 : index
  18       %b = arith.muli %bid, %cst : index
  19       %0 = arith.addi %b, %tid : index
  20       %1 = memref.load %arg0[%0] : memref<16384xf32>
  21       %2 = memref.load %arg1[%0] : memref<16384xf32>
  22       %3 = arith.addf %1, %2 : f32
  23       memref.store %3, %arg2[%0] : memref<16384xf32>
  24       gpu.return
  25     }
  26   }
  27
  28   func.func @main() {
  29     %arg0 = memref.alloc() : memref<16384xf32>
  30     %arg1 = memref.alloc() : memref<16384xf32>
  31     %arg2 = memref.alloc() : memref<16384xf32>
  32     %0 = arith.constant 0 : i32
  33     %1 = arith.constant 1 : i32
  34     %2 = arith.constant 2 : i32
  35     %value0 = arith.constant 0.0 : f32
  36     %value1 = arith.constant 1.1 : f32
  37     %value2 = arith.constant 2.2 : f32
  38     %arg3 = memref.cast %arg0 : memref<16384xf32> to memref<?xf32>
  39     %arg4 = memref.cast %arg1 : memref<16384xf32> to memref<?xf32>
  40     %arg5 = memref.cast %arg2 : memref<16384xf32> to memref<?xf32>
  41     call @fillResource1DFloat(%arg3, %value1) : (memref<?xf32>, f32) -> ()
  42     call @fillResource1DFloat(%arg4, %value2) : (memref<?xf32>, f32) -> ()
  43     call @fillResource1DFloat(%arg5, %value0) : (memref<?xf32>, f32) -> ()
  44
  45     %cst1 = arith.constant 1 : index
  46     %cst128 = arith.constant 128 : index
  47     gpu.launch_func @kernels::@kernel_add
  48         blocks in (%cst128, %cst1, %cst1) threads in (%cst128, %cst1, %cst1)
  49         args(%arg0 : memref<16384xf32>, %arg1 : memref<16384xf32>, %arg2 : memref<16384xf32>)
  50     %arg6 = memref.cast %arg5 : memref<?xf32> to memref<*xf32>
  51     return
  52   }
  53   func.func private @fillResource1DFloat(%0 : memref<?xf32>, %1 : f32)
  54   func.func private @printMemrefF32(%ptr : memref<*xf32>)
  55 }
  56