polly/test/DeLICM/reject_outofquota.ll

   1 ; RUN: opt %loadNPMPolly '-passes=print<polly-delicm>' -pass-remarks-analysis=polly-delicm -polly-delicm-max-ops=1 -disable-output < %s 2>&1 | FileCheck %s
   2 ; RUN: opt %loadNPMPolly '-passes=polly-delicm,print<polly-dependences>' -polly-delicm-max-ops=1 -polly-dependences-computeout=0 -disable-output < %s | FileCheck %s -check-prefix=DEP
   3 ;
   4 ;    void func(double *A) {
   5 ;      for (int j = 0; j < 2; j += 1) { /* outer */
   6 ;        double phi = 0.0;
   7 ;        for (int i = 0; i < 4; i += 1) /* reduction */
   8 ;          phi += 4.2;
   9 ;        A[j] = phi;
  10 ;      }
  11 ;    }
  12 ;
  13 define void @func(ptr noalias nonnull %A) {
  14 entry:
  15   br label %outer.preheader
  16
  17 outer.preheader:
  18   br label %outer.for
  19
  20 outer.for:
  21   %j = phi i32 [0, %outer.preheader], [%j.inc, %outer.inc]
  22   %j.cmp = icmp slt i32 %j, 2
  23   br i1 %j.cmp, label %reduction.preheader, label %outer.exit
  24
  25
  26     reduction.preheader:
  27       br label %reduction.for
  28
  29     reduction.for:
  30       %i = phi i32 [0, %reduction.preheader], [%i.inc, %reduction.inc]
  31       %phi = phi double [0.0, %reduction.preheader], [%add, %reduction.inc]
  32       %i.cmp = icmp slt i32 %i, 4
  33       br i1 %i.cmp, label %body, label %reduction.exit
  34
  35
  36
  37         body:
  38           %add = fadd double %phi, 4.2
  39           br label %reduction.inc
  40
  41
  42
  43     reduction.inc:
  44       %i.inc = add nuw nsw i32 %i, 1
  45       br label %reduction.for
  46
  47     reduction.exit:
  48       %A_idx = getelementptr inbounds double, ptr %A, i32 %j
  49       store double %phi, ptr %A_idx
  50       br label %outer.inc
  51
  52
  53
  54 outer.inc:
  55   %j.inc = add nuw nsw i32 %j, 1
  56   br label %outer.for
  57
  58 outer.exit:
  59   br label %return
  60
  61 return:
  62   ret void
  63 }
  64
  65
  66 ; CHECK: maximal number of operations exceeded during zone analysis
  67
  68 ; Check that even if the quota was exceeded in DeLICM, DependenceInfo is still
  69 ; successfull since it uses a different operations counter.
  70 ;
  71 ; DEP:     RAW dependences:
  72 ; DEP-NOT:        n/a
  73 ; DEP:     WAR dependences:
  74 ; DEP-NOT:        n/a
  75 ; DEP:     WAW dependences:
  76 ; DEP-NOT:        n/a
  77 ; DEP:     Reduction dependences:
  78 ; DEP-NOT:        n/a
  79 ; DEP:     Transitive closure of reduction dependences: