libc/startup/linux/CMakeLists.txt

   1 # This function merges multiple objects into a single relocatable object
   2 #                     cc -r obj1.o obj2.o -o obj.o
   3 # A relocatable object is an object file that is not fully linked into an
   4 # executable or a shared library. It is an intermediate file format that can
   5 # be passed into the linker.
   6 # A crt object has arch-specific code and arch-agnostic code. To reduce code
   7 # duplication, the implementation is split into multiple units. As a result,
   8 # we need to merge them into a single relocatable object.
   9 # See also:  https://maskray.me/blog/2022-11-21-relocatable-linking
  10 function(merge_relocatable_object name)
  11   set(obj_list "")
  12   set(fq_link_libraries "")
  13   get_fq_deps_list(fq_dep_list ${ARGN})
  14   foreach(target IN LISTS fq_dep_list)
  15     list(APPEND obj_list "$<TARGET_OBJECTS:${target}>")
  16     get_target_property(libs ${target} DEPS)
  17     list(APPEND fq_link_libraries "${libs}")
  18   endforeach()
  19   list(REMOVE_DUPLICATES obj_list)
  20   list(REMOVE_DUPLICATES fq_link_libraries)
  21   get_fq_target_name(${name} fq_name)
  22   set(relocatable_target "${fq_name}.__relocatable__")
  23   add_executable(
  24     ${relocatable_target}
  25     ${obj_list}
  26   )
  27   # Pass -r to the driver is much cleaner than passing -Wl,-r: the compiler knows it is
  28   # a relocatable linking and will not pass other irrelevant flags to the linker.
  29   target_link_options(${relocatable_target} PRIVATE -r -nostdlib)
  30   set_target_properties(
  31     ${relocatable_target}
  32     PROPERTIES
  33       RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  34       OUTPUT_NAME ${name}.o
  35   )
  36   add_library(${fq_name} OBJECT IMPORTED GLOBAL)
  37   add_dependencies(${fq_name} ${relocatable_target})
  38   target_link_libraries(${fq_name} INTERFACE ${fq_link_libraries})
  39   set_target_properties(
  40     ${fq_name}
  41     PROPERTIES
  42       LINKER_LANGUAGE CXX
  43       IMPORTED_OBJECTS ${CMAKE_CURRENT_BINARY_DIR}/${name}.o
  44       TARGET_TYPE ${OBJECT_LIBRARY_TARGET_TYPE}
  45       DEPS "${fq_link_libraries}"
  46   )
  47 endfunction()
  48
  49 function(add_startup_object name)
  50   cmake_parse_arguments(
  51     "ADD_STARTUP_OBJECT"
  52     "" # Option argument
  53     "SRC"   # Single value arguments
  54     "DEPENDS;COMPILE_OPTIONS" # Multi value arguments
  55     ${ARGN}
  56   )
  57
  58   get_fq_target_name(${name} fq_target_name)
  59
  60   add_object_library(
  61     ${name}
  62     SRCS ${ADD_STARTUP_OBJECT_SRC}
  63     DEPENDS ${ADD_STARTUP_OBJECT_DEPENDS}
  64     COMPILE_OPTIONS ${ADD_STARTUP_OBJECT_COMPILE_OPTIONS}
  65   )
  66   set_target_properties(
  67     ${fq_target_name}
  68     PROPERTIES
  69       OUTPUT_NAME ${name}.o
  70   )
  71 endfunction()
  72
  73 check_cxx_compiler_flag("-r" LIBC_LINKER_SUPPORTS_RELOCATABLE)
  74
  75 if(NOT LIBC_LINKER_SUPPORTS_RELOCATABLE)
  76   message(STATUS "Skipping startup for target architecture ${LIBC_TARGET_ARCHITECTURE}: linker does not support -r")
  77   return()
  78 endif()
  79
  80 if(NOT (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${LIBC_TARGET_ARCHITECTURE}))
  81   message(STATUS "Skipping startup for target architecture ${LIBC_TARGET_ARCHITECTURE}")
  82   return()
  83 endif()
  84
  85 add_subdirectory(${LIBC_TARGET_ARCHITECTURE})
  86
  87 add_object_library(
  88   do_start
  89   SRCS
  90     do_start.cpp
  91   HDRS
  92     do_start.h
  93   DEPENDS
  94     libc.config.linux.app_h
  95     libc.include.sys_mman
  96     libc.include.sys_syscall
  97     libc.src.__support.threads.thread
  98     libc.src.__support.OSUtil.osutil
  99     libc.src.stdlib.exit
 100     libc.src.stdlib.atexit
 101     libc.src.unistd.environ
 102   COMPILE_OPTIONS
 103     -ffreestanding       # To avoid compiler warnings about calling the main function.
 104     -fno-builtin         # avoid emit unexpected calls
 105     -fno-stack-protector # stack protect canary is not available yet.
 106 )
 107
 108 # TODO: factor out crt1 into multiple objects
 109 merge_relocatable_object(
 110   crt1
 111   .${LIBC_TARGET_ARCHITECTURE}.start
 112   .${LIBC_TARGET_ARCHITECTURE}.tls
 113   .do_start
 114 )
 115
 116 add_startup_object(
 117   crti
 118   SRC
 119     crti.cpp
 120 )
 121
 122 add_startup_object(
 123   crtn
 124   SRC
 125     crtn.cpp
 126 )
 127
 128 add_custom_target(libc-startup)
 129 set(startup_components crt1 crti crtn)
 130 foreach(target IN LISTS startup_components)
 131   set(fq_target_name libc.startup.linux.${target})
 132   add_dependencies(libc-startup ${fq_target_name})
 133   install(FILES $<TARGET_OBJECTS:${fq_target_name}>
 134           DESTINATION ${CMAKE_INSTALL_LIBDIR}
 135           RENAME $<TARGET_PROPERTY:${fq_target_name},OUTPUT_NAME>
 136           COMPONENT libc)
 137 endforeach()