llvm/test/Transforms/LoopDistribute/unknown-bounds-for-memchecks.ll

   1 ; RUN: opt -passes=loop-distribute -enable-loop-distribute -S < %s | FileCheck %s
   2
   3 ; If we can't find the bounds for one of the arrays in order to generate the
   4 ; memchecks (e.g., C[i * i] below), loop shold not get distributed.
   5 ;
   6 ;   for (i = 0; i < n; i++) {
   7 ;     A[i + 1] = A[i] * 3;
   8 ; -------------------------------
   9 ;     C[i * i] = B[i] * 2;
  10 ;   }
  11
  12 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
  13
  14 ; Verify that we didn't distribute by checking that we still have the original
  15 ; number of branches.
  16
  17 @A = common global ptr null, align 8
  18 @B = common global ptr null, align 8
  19 @C = common global ptr null, align 8
  20
  21 define void @f() {
  22 entry:
  23   %a = load ptr, ptr @A, align 8
  24   %b = load ptr, ptr @B, align 8
  25   %c = load ptr, ptr @C, align 8
  26   br label %for.body
  27 ; CHECK: br
  28
  29 for.body:                                         ; preds = %for.body, %entry
  30   %ind = phi i64 [ 0, %entry ], [ %add, %for.body ]
  31
  32   %arrayidxA = getelementptr inbounds i32, ptr %a, i64 %ind
  33   %loadA = load i32, ptr %arrayidxA, align 4
  34
  35   %mulA = mul i32 %loadA, 3
  36
  37   %add = add nuw nsw i64 %ind, 1
  38   %arrayidxA_plus_4 = getelementptr inbounds i32, ptr %a, i64 %add
  39   store i32 %mulA, ptr %arrayidxA_plus_4, align 4
  40
  41   %arrayidxB = getelementptr inbounds i32, ptr %b, i64 %ind
  42   %loadB = load i32, ptr %arrayidxB, align 4
  43
  44   %mulC = mul i32 %loadB, 2
  45
  46   %ind_2 = mul i64 %ind, %ind
  47   %arrayidxC = getelementptr inbounds i32, ptr %c, i64 %ind_2
  48   store i32 %mulC, ptr %arrayidxC, align 4
  49
  50   %exitcond = icmp eq i64 %add, 20
  51   br i1 %exitcond, label %for.end, label %for.body
  52 ; CHECK: br
  53 ; CHECK-NOT: br
  54
  55 for.end:                                          ; preds = %for.body
  56   ret void
  57 }