polly/test/Simplify/notredundant_synthesizable_unknownit.ll

   1 ; RUN: opt %loadPolly -polly-stmt-granularity=bb -polly-print-simplify -disable-output < %s | FileCheck %s -match-full-lines
   2 ; RUN: opt %loadNPMPolly -polly-stmt-granularity=bb "-passes=scop(print<polly-simplify>)" -disable-output -aa-pipeline=basic-aa < %s | FileCheck %s -match-full-lines
   3 ;
   4 ; Do not remove the scalar value write of %i.trunc in inner.for.
   5 ; It is used by body.
   6 ; %i.trunc is synthesizable in inner.for, so some code might think it is
   7 ; synthesizable everywhere such that no scalar write would be needed.
   8 ;
   9 ; Note that -polly-simplify rightfully removes %inner.cond. It should
  10 ; not have been added to the instruction list in the first place.
  11 ;
  12 define void @func(i32 %n, ptr noalias nonnull %A) {
  13 entry:
  14   br label %for
  15
  16 for:
  17   %j = phi i32 [0, %entry], [%j.inc, %inc]
  18   %j.cmp = icmp slt i32 %j, %n
  19   %zero = sext i32 0 to i64
  20   br i1 %j.cmp, label %inner.for, label %exit
  21
  22
  23     ; This loop has some unusual properties:
  24     ; * It has a known iteration count (1), therefore SCoP-compatible.
  25     ; * %i.trunc is synthesizable within the loop ({1,+,1}<%while.body>).
  26     ; * %i.trunc is not synthesizable outside of the loop, because its value is
  27     ;   unknown when exiting.
  28     ;   (should be 1, but ScalarEvolution currently seems unable to derive that)
  29     ;
  30     ; ScalarEvolution currently seems to not able to handle the %zero.
  31     ; If it becomes more intelligent, there might be other such loop constructs.
  32     inner.for:
  33       %i = phi i64 [%zero, %for], [%i.inc, %inner.for]
  34       %i.inc = add nuw nsw i64 %i, 1
  35       %i.trunc = trunc i64 %i.inc to i32
  36       %i.and = and i32 %i.trunc, 6
  37       %inner.cond = icmp eq i32 %i.and, 0
  38       br i1 %inner.cond, label %body, label %inner.for
  39
  40     body:
  41       store i32 %i.trunc, ptr %A
  42       br label %inc
  43
  44
  45 inc:
  46   %j.inc = add nuw nsw i32 %j, 1
  47   br label %for
  48
  49 exit:
  50   br label %return
  51
  52 return:
  53   ret void
  54 }
  55
  56
  57 ; CHECK:      After accesses {
  58 ; CHECK-NEXT:     Stmt_inner_for
  59 ; CHECK-NEXT:             MustWriteAccess :=  [Reduction Type: NONE] [Scalar: 1]
  60 ; CHECK-NEXT:                 [n] -> { Stmt_inner_for[i0, i1] -> MemRef_i_trunc[] };
  61 ; CHECK-NEXT:     Stmt_body
  62 ; CHECK-NEXT:             MustWriteAccess :=  [Reduction Type: NONE] [Scalar: 0]
  63 ; CHECK-NEXT:                 [n] -> { Stmt_body[i0] -> MemRef_A[0] };
  64 ; CHECK-NEXT:             ReadAccess :=       [Reduction Type: NONE] [Scalar: 1]
  65 ; CHECK-NEXT:                 [n] -> { Stmt_body[i0] -> MemRef_i_trunc[] };
  66 ; CHECK-NEXT: }