lldb/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.20.0)
   2 set(LLVM_SUBPROJECT_TITLE "LLDB")
   3
   4 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
   5   set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   6 endif()
   7 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   8   NO_POLICY_SCOPE)
   9
  10 # Add path for custom modules.
  11 set(CMAKE_MODULE_PATH
  12   ${CMAKE_MODULE_PATH}
  13   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  14   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  15   )
  16
  17 # If we are not building as part of LLVM, build LLDB as a standalone project,
  18 # using LLVM as an external library.
  19 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  20   project(lldb)
  21   set(LLDB_BUILT_STANDALONE TRUE)
  22   set(LLVM_INCLUDE_TESTS ON CACHE INTERNAL "")
  23 endif()
  24
  25 # Must go below project(..)
  26 include(GNUInstallDirs)
  27
  28 option(LLDB_INCLUDE_TESTS "Generate build targets for the LLDB unit tests." ${LLVM_INCLUDE_TESTS})
  29
  30 if(LLDB_BUILT_STANDALONE)
  31   set(CMAKE_CXX_STANDARD 17 CACHE STRING "C++ standard to conform to")
  32   set(CMAKE_CXX_STANDARD_REQUIRED YES)
  33   set(CMAKE_CXX_EXTENSIONS NO)
  34
  35   include(LLDBStandalone)
  36 endif()
  37
  38 include(LLDBConfig)
  39 include(AddLLDB)
  40
  41 # Define the LLDB_CONFIGURATION_xxx matching the build type.
  42 if(uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  43   add_definitions(-DLLDB_CONFIGURATION_DEBUG)
  44 endif()
  45
  46 if (WIN32)
  47   add_definitions(-D_ENABLE_EXTENDED_ALIGNED_STORAGE)
  48   if (NOT MSVC)
  49     # _BSD_SOURCE is required for MinGW's getopt.h to define optreset
  50     add_definitions(-D_BSD_SOURCE)
  51   endif()
  52 endif()
  53
  54 if (LLDB_ENABLE_PYTHON)
  55   set(cachestring_LLDB_PYTHON_RELATIVE_PATH
  56     "Path where Python modules are installed, relative to LLDB's install prefix")
  57   set(cachestring_LLDB_PYTHON_EXE_RELATIVE_PATH
  58     "Path to python interpreter exectuable, relative to python's install prefix")
  59   set(cachestring_LLDB_PYTHON_EXT_SUFFIX
  60     "Filename extension for native code python modules")
  61
  62   foreach(var LLDB_PYTHON_RELATIVE_PATH LLDB_PYTHON_EXE_RELATIVE_PATH LLDB_PYTHON_EXT_SUFFIX)
  63     if(NOT DEFINED ${var} AND NOT CMAKE_CROSSCOMPILING)
  64       execute_process(
  65         COMMAND ${Python3_EXECUTABLE}
  66           ${CMAKE_CURRENT_SOURCE_DIR}/bindings/python/get-python-config.py
  67           ${var}
  68         OUTPUT_VARIABLE value
  69         OUTPUT_STRIP_TRAILING_WHITESPACE)
  70       file(TO_CMAKE_PATH "${value}" value)
  71       set(${var} ${value} CACHE STRING ${cachestring_${var}})
  72     else()
  73       if ("${${var}}" STREQUAL "")
  74         message(FATAL_ERROR
  75           "Crosscompiling LLDB with Python requires manually setting ${var}.")
  76       endif()
  77     endif()
  78   endforeach()
  79   # Make sure lldb extension has "_d" suffix on Windows in Debug mode.
  80   if(WIN32 AND CMAKE_BUILD_TYPE STREQUAL Debug)
  81     string(SUBSTRING ${LLDB_PYTHON_EXT_SUFFIX} 0 2 FIRST_2_CHARS)
  82     # Add "_d" manually if LLDB_PYTHON_EXT_SUFFIX lacks it due to release Python configuration.
  83     if(NOT FIRST_2_CHARS STREQUAL "_d")
  84       set(LLDB_PYTHON_EXT_SUFFIX "_d${LLDB_PYTHON_EXT_SUFFIX}")
  85     endif()
  86   endif()
  87 endif ()
  88
  89 if (LLDB_ENABLE_LUA)
  90   find_program(Lua_EXECUTABLE lua5.3)
  91   set(LLDB_LUA_DEFAULT_RELATIVE_PATH "lib/lua/5.3")
  92   set(LLDB_LUA_RELATIVE_PATH ${LLDB_LUA_DEFAULT_RELATIVE_PATH}
  93     CACHE STRING "Path where Lua modules are installed, relative to install prefix")
  94 endif ()
  95
  96 if (LLDB_ENABLE_PYTHON OR LLDB_ENABLE_LUA)
  97   add_subdirectory(bindings)
  98 endif ()
  99
 100 # We need the headers generated by instrinsics_gen before we can compile
 101 # any source file in LLDB as the imported Clang modules might include
 102 # some of these generated headers. This approach is copied from Clang's main
 103 # CMakeLists.txt, so it should kept in sync the code in Clang which was added
 104 # in llvm-svn 308844.
 105 if(LLVM_ENABLE_MODULES)
 106   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 107 endif()
 108
 109 if(CMAKE_CROSSCOMPILING AND LLDB_BUILT_STANDALONE AND NOT LLDB_TABLEGEN_EXE)
 110   set(LLVM_USE_HOST_TOOLS ON)
 111   include(CrossCompile)
 112   if (NOT NATIVE_LLVM_DIR OR NOT NATIVE_Clang_DIR)
 113     message(FATAL_ERROR
 114       "Crosscompiling standalone requires the variables NATIVE_{CLANG,LLVM}_DIR
 115       for building the native lldb-tblgen used during the build process.")
 116   endif()
 117   llvm_create_cross_target(lldb NATIVE "" Release
 118     -DLLVM_DIR=${NATIVE_LLVM_DIR}
 119     -DClang_DIR=${NATIVE_Clang_DIR})
 120 endif()
 121
 122 # TableGen
 123 add_subdirectory(utils/TableGen)
 124
 125 add_subdirectory(source)
 126 add_subdirectory(tools)
 127 add_subdirectory(docs)
 128
 129 if (LLDB_ENABLE_PYTHON)
 130   if(LLDB_BUILD_FRAMEWORK)
 131     set(lldb_python_target_dir "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/Resources/Python/lldb")
 132   else()
 133     set(lldb_python_target_dir "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${LLDB_PYTHON_RELATIVE_PATH}/lldb")
 134   endif()
 135   get_target_property(lldb_python_bindings_dir swig_wrapper_python BINARY_DIR)
 136   finish_swig_python("lldb-python" "${lldb_python_bindings_dir}" "${lldb_python_target_dir}")
 137 endif()
 138
 139 if (LLDB_ENABLE_LUA)
 140   if(LLDB_BUILD_FRAMEWORK)
 141     set(lldb_lua_target_dir "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/Resources/Lua")
 142   else()
 143     set(lldb_lua_target_dir "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${LLDB_LUA_RELATIVE_PATH}")
 144   endif()
 145   get_target_property(lldb_lua_bindings_dir swig_wrapper_lua BINARY_DIR)
 146   finish_swig_lua("lldb-lua" "${lldb_lua_bindings_dir}" "${lldb_lua_target_dir}")
 147 endif()
 148
 149 set(LLDB_INCLUDE_UNITTESTS ON)
 150 if (NOT TARGET llvm_gtest)
 151   set(LLDB_INCLUDE_UNITTESTS OFF)
 152 endif()
 153
 154 if(LLDB_INCLUDE_TESTS)
 155   add_subdirectory(test)
 156   if (LLDB_INCLUDE_UNITTESTS)
 157     add_subdirectory(unittests)
 158   endif()
 159   add_subdirectory(utils)
 160 endif()
 161
 162 if(LLDB_BUILT_STANDALONE AND NOT LLVM_ENABLE_IDE)
 163   llvm_distribution_add_targets()
 164 endif()