flang/test/Fir/rebox-susbtring.fir

   1 // Test translation to llvm IR of fir.rebox with substring array sections.
   2
   3 // RUN: fir-opt -o - -cg-rewrite --fir-to-llvm-ir -cse %s | FileCheck %s
   4 // RUN: tco -o - -cg-rewrite --fir-to-llvm-ir -cse %s | FileCheck %s
   5
   6 // Test a fir.rebox with a substring on a character array with constant
   7 // length (like c(:)(2:*) where c is a fir.box array with constant length).
   8
   9 // CHECK-LABEL: llvm.func @char_section(
  10 // CHECK-SAME:                          %[[VAL_0:.*]]: !llvm.ptr<[[char20_descriptor_t:.*]]>)>>) {
  11 func.func @char_section(%arg0: !fir.box<!fir.array<?x!fir.char<1,20>>>) {
  12   %c7_i64 = arith.constant 7 : i64
  13   %c1_i64 = arith.constant 1 : i64
  14   %c0 = arith.constant 0 : index
  15   %c1 = arith.constant 1 : index
  16   %0:3 = fir.box_dims %arg0, %c0 : (!fir.box<!fir.array<?x!fir.char<1,20>>>, index) -> (index, index, index)
  17   %1 = fir.slice %c1, %0#1, %c1_i64 substr %c1_i64, %c7_i64 : (index, index, i64, i64, i64) -> !fir.slice<1>
  18
  19 // Only test the computation of the base address offset computation accounting for the substring
  20
  21 // CHECK:         %[[VAL_4:.*]] = llvm.mlir.constant(1 : i64) : i64
  22
  23 // CHECK:         %[[VAL_37:.*]] = llvm.getelementptr %[[VAL_0]]{{\[}}0, 0] : (!llvm.ptr<[[char20_descriptor_t]]>)>>) -> !llvm.ptr<ptr<array<20 x i8>>>
  24 // CHECK:         %[[VAL_38:.*]] = llvm.load %[[VAL_37]] : !llvm.ptr<ptr<array<20 x i8>>>
  25 // CHECK:         %[[VAL_30:.*]] = llvm.mlir.constant(0 : i64) : i64
  26 // CHECK:         %[[VAL_39:.*]] = llvm.bitcast %[[VAL_38]] : !llvm.ptr<array<20 x i8>> to !llvm.ptr<array<20 x i8>>
  27 // CHECK:         %[[VAL_40:.*]] = llvm.getelementptr %[[VAL_39]]{{\[}}%[[VAL_30]], %[[VAL_4]]] : (!llvm.ptr<array<20 x i8>>, i64, i64) -> !llvm.ptr<i8>
  28 // CHECK:         llvm.bitcast %[[VAL_40]] : !llvm.ptr<i8> to !llvm.ptr<i8>
  29
  30 // More offset computation with descriptor strides and triplets that is not character specific ...
  31
  32   %2 = fir.rebox %arg0 [%1] : (!fir.box<!fir.array<?x!fir.char<1,20>>>, !fir.slice<1>) -> !fir.box<!fir.array<?x!fir.char<1,?>>>
  33   fir.call @bar(%2) : (!fir.box<!fir.array<?x!fir.char<1,?>>>) -> ()
  34   return
  35 }
  36
  37 // Test a rebox of an array section like x(3:60:9)%c(2:8) with both a triplet, a component and a substring where x is a fir.box.
  38
  39 // CHECK-LABEL: llvm.func @foo(
  40 // CHECK-SAME:                 %[[VAL_0:.*]]: !llvm.ptr<struct<(ptr<[[struct_t:.*]]>, i64, i32, i8, i8, i8, i8, array<1 x array<3 x i64>>, ptr<i8>, array<1 x i64>)>>) {
  41 func.func private @bar(!fir.box<!fir.array<?x!fir.char<1,?>>>)
  42 func.func @foo(%arg0: !fir.box<!fir.array<?x!fir.type<t{i:i32,c:!fir.char<1,10>}>>>) {
  43   %c7_i64 = arith.constant 7 : i64
  44   %c1_i64 = arith.constant 1 : i64
  45   %c9_i64 = arith.constant 9 : i64
  46   %c60_i64 = arith.constant 60 : i64
  47   %c3_i64 = arith.constant 3 : i64
  48   %0 = fir.field_index c, !fir.type<t{i:i32,c:!fir.char<1,10>}>
  49   %1 = fir.slice %c3_i64, %c60_i64, %c9_i64 path %0 substr %c1_i64, %c7_i64 : (i64, i64, i64, !fir.field, i64, i64) -> !fir.slice<1>
  50
  51 // Only test the computation of the base address offset computation accounting for the substring of the component
  52
  53 // CHECK:         %[[VAL_1:.*]] = llvm.mlir.constant(1 : i32) : i32
  54
  55 // CHECK:         %[[VAL_30:.*]] = llvm.getelementptr %[[VAL_0]]{{\[}}0, 0] : (!llvm.ptr<[[struct_t_descriptor:.*]]>) -> !llvm.ptr<ptr<[[struct_t]]>>
  56 // CHECK:         %[[VAL_31:.*]] = llvm.load %[[VAL_30]] : !llvm.ptr<ptr<[[struct_t]]>>
  57 // CHECK:         %[[VAL_21:.*]] = llvm.mlir.constant(0 : i64) : i64
  58 // CHECK:         %[[VAL_32:.*]] = llvm.bitcast %[[VAL_31]] : !llvm.ptr<[[struct_t]]> to !llvm.ptr<[[struct_t]]>
  59 // CHECK:         %[[VAL_33:.*]] = llvm.getelementptr %[[VAL_32]]{{\[}}%[[VAL_21]], 1, %[[VAL_4]]] : (!llvm.ptr<[[struct_t]]>, i64, i64) -> !llvm.ptr<i8>
  60 // CHECK:         llvm.bitcast %[[VAL_33]] : !llvm.ptr<i8> to !llvm.ptr<i8>
  61
  62 // More offset computation with descriptor strides and triplets that is not character specific ...
  63
  64   %2 = fir.rebox %arg0 [%1] : (!fir.box<!fir.array<?x!fir.type<t{i:i32,c:!fir.char<1,10>}>>>, !fir.slice<1>) -> !fir.box<!fir.array<?x!fir.char<1,?>>>
  65   fir.call @bar(%2) : (!fir.box<!fir.array<?x!fir.char<1,?>>>) -> ()
  66   return
  67 }