mlir/test/Target/LLVMIR/opaque-ptr.mlir

   1 // RUN: mlir-translate -mlir-to-llvmir -opaque-pointers %s | FileCheck %s
   2
   3 // CHECK-LABEL: @opaque_ptr_load
   4 llvm.func @opaque_ptr_load(%arg0: !llvm.ptr) -> i32 {
   5   // CHECK: load i32, ptr %{{.*}}
   6   %0 = llvm.load %arg0 : !llvm.ptr -> i32
   7   llvm.return %0 : i32
   8 }
   9
  10 // CHECK-LABEL: @opaque_ptr_store
  11 llvm.func @opaque_ptr_store(%arg0: i32, %arg1: !llvm.ptr){
  12   // CHECK: store i32 %{{.*}}, ptr %{{.*}}
  13   llvm.store %arg0, %arg1 : i32, !llvm.ptr
  14   llvm.return
  15 }
  16
  17 // CHECK-LABEL: @opaque_ptr_ptr_store
  18 llvm.func @opaque_ptr_ptr_store(%arg0: !llvm.ptr, %arg1: !llvm.ptr) {
  19   // CHECK: store ptr %{{.*}}, ptr %{{.*}}
  20   llvm.store %arg0, %arg1 : !llvm.ptr, !llvm.ptr
  21   llvm.return
  22 }
  23
  24 // CHECK-LABEL: @opaque_ptr_alloca
  25 llvm.func @opaque_ptr_alloca(%arg0: i32) -> !llvm.ptr {
  26   // CHECK: alloca float, i32 %{{.*}}
  27   %0 = llvm.alloca %arg0 x f32 : (i32) -> !llvm.ptr
  28   llvm.return %0 : !llvm.ptr
  29 }
  30
  31 // CHECK-LABEL: @opaque_ptr_gep
  32 llvm.func @opaque_ptr_gep(%arg0: !llvm.ptr, %arg1: i32) -> !llvm.ptr {
  33   // CHECK: getelementptr float, ptr %{{.*}}, i32 %{{.*}}
  34   %0 = llvm.getelementptr %arg0[%arg1] : (!llvm.ptr, i32) -> !llvm.ptr, f32
  35   llvm.return %0 : !llvm.ptr
  36 }
  37
  38 // CHECK-LABEL: @opaque_ptr_gep_struct
  39 llvm.func @opaque_ptr_gep_struct(%arg0: !llvm.ptr, %arg1: i32) -> !llvm.ptr {
  40   // CHECK: getelementptr { { float, double }, { i32, i64 } }, ptr %{{.*}}, i32 0, i32 1
  41   %0 = llvm.getelementptr %arg0[%arg1, 0, 1] : (!llvm.ptr, i32) -> !llvm.ptr, !llvm.struct<(struct<(f32, f64)>, struct<(i32, i64)>)>
  42   llvm.return %0 : !llvm.ptr
  43 }
  44
  45 // CHECK-LABEL: @opaque_ptr_matrix_load_store
  46 llvm.func @opaque_ptr_matrix_load_store(%ptr: !llvm.ptr, %stride: i64) -> vector<48 x f32> {
  47   // CHECK: call <48 x float> @llvm.matrix.column.major.load.v48f32.i64
  48   // CHECK: (ptr {{.*}}, i64 %{{.*}}
  49   %0 = llvm.intr.matrix.column.major.load %ptr, <stride=%stride>
  50     { isVolatile = 0: i1, rows = 3: i32, columns = 16: i32} :
  51     vector<48 x f32> from !llvm.ptr stride i64
  52   // CHECK: call void @llvm.matrix.column.major.store.v48f32.i64
  53   // CHECK: <48 x float> %{{.*}}, ptr {{.*}}, i64
  54   llvm.intr.matrix.column.major.store %0, %ptr, <stride=%stride>
  55     { isVolatile = 0: i1, rows = 3: i32, columns = 16: i32} :
  56     vector<48 x f32> to !llvm.ptr stride i64
  57   llvm.return %0 : vector<48 x f32>
  58 }
  59
  60 // CHECK-LABEL: @opaque_ptr_masked_load
  61 llvm.func @opaque_ptr_masked_load(%arg0: !llvm.ptr, %arg1: vector<7xi1>) -> vector<7xf32> {
  62   // CHECK: call <7 x float> @llvm.masked.load.v7f32.p0(ptr
  63   %0 = llvm.intr.masked.load %arg0, %arg1 { alignment = 1: i32} :
  64     (!llvm.ptr, vector<7xi1>) -> vector<7xf32>
  65   llvm.return %0 : vector<7 x f32>
  66 }
  67
  68 // CHECK-LABEL: @opaque_ptr_gather
  69 llvm.func @opaque_ptr_gather(%M: !llvm.vec<7 x ptr>, %mask: vector<7xi1>) -> vector<7xf32> {
  70   // CHECK: call <7 x float> @llvm.masked.gather.v7f32.v7p0(<7 x ptr> {{.*}}, i32
  71   %a = llvm.intr.masked.gather %M, %mask { alignment = 1: i32} :
  72       (!llvm.vec<7 x ptr>, vector<7xi1>) -> vector<7xf32>
  73   llvm.return %a : vector<7xf32>
  74 }