mlir/test/Integration/Dialect/Linalg/CPU/test-conv-3d-call.mlir

   1 // RUN: mlir-opt %s -convert-linalg-to-loops -convert-scf-to-std -convert-linalg-to-llvm -lower-affine -convert-scf-to-std --convert-memref-to-llvm -convert-std-to-llvm -reconcile-unrealized-casts | \
   2 // RUN: mlir-cpu-runner -e main -entry-point-result=void \
   3 // RUN:   -shared-libs=%mlir_integration_test_dir/libmlir_runner_utils%shlibext \
   4 // RUN: | FileCheck %s
   5
   6 // RUN: mlir-opt %s -linalg-tile="tile-sizes=2,2,2" -convert-linalg-to-loops -convert-scf-to-std \
   7 // RUN:   -convert-linalg-to-llvm -lower-affine -convert-scf-to-std --convert-memref-to-llvm -convert-std-to-llvm -reconcile-unrealized-casts | \
   8 // RUN: mlir-cpu-runner -e main -entry-point-result=void \
   9 // RUN:   -shared-libs=%mlir_integration_test_dir/libmlir_runner_utils%shlibext \
  10 // RUN: | FileCheck %s
  11
  12 func private @print_memref_f32(memref<*xf32>)
  13
  14 // Creates and returns 3-D buffer of size (%s1, %s2, %s3) filled with the value %f
  15 func @alloc_3d_filled_f32(%s1 : index, %s2 : index, %s3 : index, %f : f32) -> memref<?x?x?xf32> {
  16   %buf = memref.alloc(%s1, %s2, %s3) : memref<?x?x?xf32>
  17   linalg.fill(%f, %buf) : f32, memref<?x?x?xf32>
  18   return %buf : memref<?x?x?xf32>
  19 }
  20
  21 func @conv_3d(%arg0: memref<?x?x?xf32>, %arg1: memref<?x?x?xf32>, %arg2: memref<?x?x?xf32>) {
  22   linalg.conv_3d ins (%arg0, %arg1: memref<?x?x?xf32>, memref<?x?x?xf32>)
  23                 outs (%arg2: memref<?x?x?xf32>)
  24   return
  25 }
  26
  27 func @main() {
  28   %c0 = arith.constant 0 : index
  29   %c1 = arith.constant 1 : index
  30   %c3 = arith.constant 3 : index
  31   %c6 = arith.constant 6 : index
  32   %c8 = arith.constant 8 : index
  33   %f10 = arith.constant 10.00000e+00 : f32
  34   %val = arith.constant 2.00000e+00 : f32
  35   %zero = arith.constant 0.00000e+00 : f32
  36
  37   %filter3D = call @alloc_3d_filled_f32(%c3, %c3, %c3, %val) : (index, index, index, f32) -> (memref<?x?x?xf32>)
  38   %in3D = call @alloc_3d_filled_f32(%c8, %c8, %c8, %val) : (index, index, index, f32) -> (memref<?x?x?xf32>)
  39   %out3D = call @alloc_3d_filled_f32(%c6, %c6, %c6, %zero) : (index, index, index, f32) -> (memref<?x?x?xf32>)
  40
  41   memref.store %f10, %in3D[%c0, %c0, %c3] : memref<?x?x?xf32>
  42   call @conv_3d(%in3D, %filter3D, %out3D) : (memref<?x?x?xf32>, memref<?x?x?xf32>, memref<?x?x?xf32>) -> ()
  43   %out3D_ = memref.cast %out3D : memref<?x?x?xf32> to memref<*xf32>
  44   call @print_memref_f32(%out3D_): (memref<*xf32>) -> ()
  45
  46   memref.dealloc %filter3D : memref<?x?x?xf32>
  47   memref.dealloc %in3D : memref<?x?x?xf32>
  48   memref.dealloc %out3D : memref<?x?x?xf32>
  49   return
  50 }
  51
  52 // CHECK:       Unranked Memref {{.*}}
  53 // CHECK-NEXT:  [
  54 // CHECK-SAME:   [
  55 // CHECK-SAME:    [108,    124,    124,    124,    108,    108],
  56 // CHECK-COUNT-5: [108,    108,    108,    108,    108,    108]
  57 // CHECK-SAME:   ],
  58 // CHECK-NEXT:   [
  59 // CHECK-COUNT-6: [108,    108,    108,    108,    108,    108]
  60 // CHECK-SAME:   ],
  61 // CHECK-NEXT:   [
  62 // CHECK-COUNT-6: [108,    108,    108,    108,    108,    108]
  63 // CHECK-SAME:   ],
  64 // CHECK-NEXT:   [
  65 // CHECK-COUNT-6: [108,    108,    108,    108,    108,    108]
  66 // CHECK-SAME:   ],
  67 // CHECK-NEXT:   [
  68 // CHECK-COUNT-6: [108,    108,    108,    108,    108,    108]
  69 // CHECK-SAME:   ],
  70 // CHECK-NEXT:   [
  71 // CHECK-COUNT-6: [108,    108,    108,    108,    108,    108]
  72 // CHECK-SAME:   ]
  73 // CHECK-SAME:  ]