polly/test/ScopInfo/multidim_ivs_and_parameteric_offsets_3d.ll

   1 ; RUN: opt %loadPolly -polly-precise-fold-accesses -polly-print-scops -disable-output < %s | FileCheck %s
   2 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   3
   4 ; void foo(long n, long m, long o, double A[n][m][o], long p, long q, long r) {
   5 ;
   6 ;   for (long i = 0; i < n; i++)
   7 ;     for (long j = 0; j < m; j++)
   8 ;       for (long k = 0; k < o; k++)
   9 ;         A[i+p][j+q][k+r] = 1.0;
  10 ; }
  11 ;
  12 ; Access function:
  13 ;    {{{((8 * ((((%m * %p) + %q) * %o) + %r)) + %A),+,(8 * %m * %o)}<%for.i>,+,
  14 ;        (8 * %o)}<%for.j>,+,8}<%for.k>
  15
  16 ; CHECK:      Assumed Context:
  17 ; CHECK-NEXT: [o, m, n, p, q, r] -> {  : -m <= q <= 1 and ((-m < q <= 0 and -o < r < 0) or (r = 0 and q <= 0) or (r = -o and q > -m)) }
  18 ;
  19 ; CHECK:      p0: %o
  20 ; CHECK-NEXT: p1: %m
  21 ; CHECK-NEXT: p2: %n
  22 ; CHECK-NEXT: p3: %p
  23 ; CHECK-NEXT: p4: %q
  24 ; CHECK-NEXT: p5: %r
  25 ; CHECK-NOT:  p6
  26 ;
  27 ; CHECK:      Statements {
  28 ; CHECK-NEXT:     Stmt_for_k
  29 ; CHECK-NEXT:         Domain :=
  30 ; CHECK-NEXT:             [o, m, n, p, q, r] -> { Stmt_for_k[i0, i1, i2] : 0 <= i0 < n and 0 <= i1 < m and 0 <= i2 < o };
  31 ; CHECK-NEXT:         Schedule :=
  32 ; CHECK-NEXT:             [o, m, n, p, q, r] -> { Stmt_for_k[i0, i1, i2] -> [i0, i1, i2] };
  33 ; CHECK-NEXT:         MustWriteAccess :=    [Reduction Type: NONE] [Scalar: 0]
  34 ; CHECK-NEXT:             [o, m, n, p, q, r] -> { Stmt_for_k[i0, i1, i2] -> MemRef_A[-1 + p + i0, -1 + m + q + i1, o + r + i2] : i1 <= -q and i2 < -r; Stmt_for_k[i0, i1, i2] -> MemRef_A[p + i0, -1 + q + i1, o + r + i2] : i1 > -q and i2 < -r; Stmt_for_k[i0, i1, i2] -> MemRef_A[-1 + p + i0, m + q + i1, r + i2] : i1 < -q and i2 >= -r; Stmt_for_k[i0, i1, i2] -> MemRef_A[p + i0, q + i1, r + i2] : i1 >= -q and i2 >= -r };
  35 ; CHECK-NEXT: }
  36
  37 define void @foo(i64 %n, i64 %m, i64 %o, ptr %A, i64 %p, i64 %q, i64 %r) {
  38 entry:
  39   br label %for.i
  40
  41 for.i:
  42   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  43   br label %for.j
  44
  45 for.j:
  46   %j = phi i64 [ 0, %for.i ], [ %j.inc, %for.j.inc ]
  47   br label %for.k
  48
  49 for.k:
  50   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  51   %offset0 = add nsw i64 %i, %p
  52   %subscript0 = mul i64 %offset0, %m
  53   %offset1 = add nsw i64 %j, %q
  54   %subscript1 = add i64 %offset1, %subscript0
  55   %subscript2 = mul i64 %subscript1, %o
  56   %offset2 = add nsw i64 %k, %r
  57   %subscript = add i64 %subscript2, %offset2
  58   %idx = getelementptr inbounds double, ptr %A, i64 %subscript
  59   store double 1.0, ptr %idx
  60   br label %for.k.inc
  61
  62 for.k.inc:
  63   %k.inc = add nsw i64 %k, 1
  64   %k.exitcond = icmp eq i64 %k.inc, %o
  65   br i1 %k.exitcond, label %for.j.inc, label %for.k
  66
  67 for.j.inc:
  68   %j.inc = add nsw i64 %j, 1
  69   %j.exitcond = icmp eq i64 %j.inc, %m
  70   br i1 %j.exitcond, label %for.i.inc, label %for.j
  71
  72 for.i.inc:
  73   %i.inc = add nsw i64 %i, 1
  74   %i.exitcond = icmp eq i64 %i.inc, %n
  75   br i1 %i.exitcond, label %end, label %for.i
  76
  77 end:
  78   ret void
  79 }