polly/test/ScopInfo/multidim_only_ivs_3d.ll

   1 ; RUN: opt %loadPolly -polly-print-scops -disable-output < %s | FileCheck %s
   2 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   3
   4 ; void foo(long n, long m, long o, double A[n][m][o]) {
   5 ;
   6 ;   for (long i = 0; i < n; i++)
   7 ;     for (long j = 0; j < m; j++)
   8 ;       for (long k = 0; k < o; k++)
   9 ;         A[i][j][k] = 1.0;
  10 ; }
  11
  12 ; CHECK:      Assumed Context:
  13 ; CHECK-NEXT: [o, m, n] -> {  :  }
  14 ;
  15 ; CHECK:      p0: %o
  16 ; CHECK-NEXT: p1: %m
  17 ; CHECK-NEXT: p2: %n
  18 ; CHECK-NOT:  p3
  19 ;
  20 ; CHECK:      Statements {
  21 ; CHECK-NEXT:     Stmt_for_k
  22 ; CHECK-NEXT:         Domain :=
  23 ; CHECK-NEXT:             [o, m, n] -> { Stmt_for_k[i0, i1, i2] : 0 <= i0 < n and 0 <= i1 < m and 0 <= i2 < o };
  24 ; CHECK-NEXT:         Schedule :=
  25 ; CHECK-NEXT:             [o, m, n] -> { Stmt_for_k[i0, i1, i2] -> [i0, i1, i2] };
  26 ; CHECK-NEXT:         MustWriteAccess :=    [Reduction Type: NONE] [Scalar: 0]
  27 ; CHECK-NEXT:             [o, m, n] -> { Stmt_for_k[i0, i1, i2] -> MemRef_A[i0, i1, i2] };
  28 ; CHECK-NEXT: }
  29
  30 define void @foo(i64 %n, i64 %m, i64 %o, ptr %A) {
  31 entry:
  32   br label %for.i
  33
  34 for.i:
  35   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  36   br label %for.j
  37
  38 for.j:
  39   %j = phi i64 [ 0, %for.i ], [ %j.inc, %for.j.inc ]
  40   br label %for.k
  41
  42 for.k:
  43   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  44   %subscript0 = mul i64 %i, %m
  45   %subscript1 = add i64 %j, %subscript0
  46   %subscript2 = mul i64 %subscript1, %o
  47   %subscript = add i64 %subscript2, %k
  48   %idx = getelementptr inbounds double, ptr %A, i64 %subscript
  49   store double 1.0, ptr %idx
  50   br label %for.k.inc
  51
  52 for.k.inc:
  53   %k.inc = add nsw i64 %k, 1
  54   %k.exitcond = icmp eq i64 %k.inc, %o
  55   br i1 %k.exitcond, label %for.j.inc, label %for.k
  56
  57 for.j.inc:
  58   %j.inc = add nsw i64 %j, 1
  59   %j.exitcond = icmp eq i64 %j.inc, %m
  60   br i1 %j.exitcond, label %for.i.inc, label %for.j
  61
  62 for.i.inc:
  63   %i.inc = add nsw i64 %i, 1
  64   %i.exitcond = icmp eq i64 %i.inc, %n
  65   br i1 %i.exitcond, label %end, label %for.i
  66
  67 end:
  68   ret void
  69 }