openmp/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.20.0)
   2
   3 set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   4
   5 # Add path for custom modules
   6 list(INSERT CMAKE_MODULE_PATH 0
   7   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
   8   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
   9   )
  10
  11 # llvm/runtimes/ will set OPENMP_STANDALONE_BUILD.
  12 if (OPENMP_STANDALONE_BUILD OR "${CMAKE_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_SOURCE_DIR}")
  13   set(OPENMP_STANDALONE_BUILD TRUE)
  14   project(openmp C CXX ASM)
  15 endif()
  16
  17 # Must go below project(..)
  18 include(GNUInstallDirs)
  19
  20 if (OPENMP_STANDALONE_BUILD)
  21   # CMAKE_BUILD_TYPE was not set, default to Release.
  22   if (NOT CMAKE_BUILD_TYPE)
  23     set(CMAKE_BUILD_TYPE Release)
  24   endif()
  25
  26   # Group common settings.
  27   set(OPENMP_ENABLE_WERROR FALSE CACHE BOOL
  28     "Enable -Werror flags to turn warnings into errors for supporting compilers.")
  29   set(OPENMP_LIBDIR_SUFFIX "" CACHE STRING
  30     "Suffix of lib installation directory, e.g. 64 => lib64")
  31   # Do not use OPENMP_LIBDIR_SUFFIX directly, use OPENMP_INSTALL_LIBDIR.
  32   set(OPENMP_INSTALL_LIBDIR "lib${OPENMP_LIBDIR_SUFFIX}" CACHE STRING
  33       "Path where built OpenMP libraries should be installed.")
  34
  35   # Group test settings.
  36   set(OPENMP_TEST_C_COMPILER ${CMAKE_C_COMPILER} CACHE STRING
  37     "C compiler to use for testing OpenMP runtime libraries.")
  38   set(OPENMP_TEST_CXX_COMPILER ${CMAKE_CXX_COMPILER} CACHE STRING
  39     "C++ compiler to use for testing OpenMP runtime libraries.")
  40   set(OPENMP_TEST_Fortran_COMPILER ${CMAKE_Fortran_COMPILER} CACHE STRING
  41     "FORTRAN compiler to use for testing OpenMP runtime libraries.")
  42   set(OPENMP_LLVM_TOOLS_DIR "" CACHE PATH "Path to LLVM tools for testing.")
  43
  44   set(CMAKE_CXX_STANDARD 17 CACHE STRING "C++ standard to conform to")
  45   set(CMAKE_CXX_STANDARD_REQUIRED NO)
  46   set(CMAKE_CXX_EXTENSIONS NO)
  47 else()
  48   set(OPENMP_ENABLE_WERROR ${LLVM_ENABLE_WERROR})
  49   # If building in tree, we honor the same install suffix LLVM uses.
  50   set(OPENMP_INSTALL_LIBDIR "lib${LLVM_LIBDIR_SUFFIX}" CACHE STRING
  51       "Path where built OpenMP libraries should be installed.")
  52
  53   if (NOT MSVC)
  54     set(OPENMP_TEST_C_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
  55     set(OPENMP_TEST_CXX_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++)
  56   else()
  57     set(OPENMP_TEST_C_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang.exe)
  58     set(OPENMP_TEST_CXX_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++.exe)
  59   endif()
  60
  61   # Check for flang
  62   if (NOT MSVC)
  63     set(OPENMP_TEST_Fortran_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/flang-new)
  64   else()
  65     set(OPENMP_TEST_Fortran_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/flang-new.exe)
  66   endif()
  67
  68   # Set fortran test compiler if flang is found
  69   if (EXISTS "${OPENMP_TEST_Fortran_COMPILER}")
  70     message("Using local flang build at ${OPENMP_TEST_Fortran_COMPILER}")
  71   else()
  72     unset(OPENMP_TEST_Fortran_COMPILER)
  73   endif()
  74
  75   # If not standalone, set CMAKE_CXX_STANDARD but don't set the global cache value,
  76   # only set it locally for OpenMP.
  77   set(CMAKE_CXX_STANDARD 17)
  78   set(CMAKE_CXX_STANDARD_REQUIRED NO)
  79   set(CMAKE_CXX_EXTENSIONS NO)
  80 endif()
  81
  82 # Check and set up common compiler flags.
  83 include(config-ix)
  84 include(HandleOpenMPOptions)
  85
  86 # Set up testing infrastructure.
  87 include(OpenMPTesting)
  88
  89 set(OPENMP_TEST_FLAGS "" CACHE STRING
  90   "Extra compiler flags to send to the test compiler.")
  91 set(OPENMP_TEST_OPENMP_FLAGS ${OPENMP_TEST_COMPILER_OPENMP_FLAGS} CACHE STRING
  92   "OpenMP compiler flag to use for testing OpenMP runtime libraries.")
  93
  94 set(ENABLE_LIBOMPTARGET ON)
  95 # Currently libomptarget cannot be compiled on Windows or MacOS X.
  96 # Since the device plugins are only supported on Linux anyway,
  97 # there is no point in trying to compile libomptarget on other OSes.
  98 # 32-bit systems are not supported either.
  99 if (APPLE OR WIN32 OR WASM OR NOT "cxx_std_17" IN_LIST CMAKE_CXX_COMPILE_FEATURES
 100     OR NOT CMAKE_SIZEOF_VOID_P EQUAL 8 OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 101   set(ENABLE_LIBOMPTARGET OFF)
 102 endif()
 103
 104 option(OPENMP_ENABLE_LIBOMPTARGET "Enable building libomptarget for offloading."
 105        ${ENABLE_LIBOMPTARGET})
 106 option(OPENMP_ENABLE_LIBOMP_PROFILING "Enable time profiling for libomp." OFF)
 107
 108 # Header install location
 109 if(${OPENMP_STANDALONE_BUILD})
 110   set(LIBOMP_HEADERS_INSTALL_PATH "${CMAKE_INSTALL_INCLUDEDIR}")
 111 else()
 112   include(GetClangResourceDir)
 113   get_clang_resource_dir(LIBOMP_HEADERS_INSTALL_PATH SUBDIR include)
 114 endif()
 115
 116 # Build host runtime library, after LIBOMPTARGET variables are set since they are needed
 117 # to enable time profiling support in the OpenMP runtime.
 118 add_subdirectory(runtime)
 119
 120 if (OPENMP_ENABLE_LIBOMPTARGET)
 121   # Check that the library can actually be built.
 122   if (APPLE OR WIN32)
 123     message(FATAL_ERROR "libomptarget cannot be built on Windows and MacOS X!")
 124   elseif (NOT "cxx_std_17" IN_LIST CMAKE_CXX_COMPILE_FEATURES)
 125     message(FATAL_ERROR "Host compiler must support C++17 to build libomptarget!")
 126   elseif (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
 127     message(FATAL_ERROR "libomptarget on 32-bit systems are not supported!")
 128   endif()
 129
 130   add_subdirectory(libomptarget)
 131 endif()
 132
 133 set(ENABLE_OMPT_TOOLS ON)
 134 # Currently tools are not tested well on Windows or MacOS X.
 135 if (APPLE OR WIN32)
 136   set(ENABLE_OMPT_TOOLS OFF)
 137 endif()
 138
 139 option(OPENMP_ENABLE_OMPT_TOOLS "Enable building ompt based tools for OpenMP."
 140        ${ENABLE_OMPT_TOOLS})
 141 if (OPENMP_ENABLE_OMPT_TOOLS)
 142   add_subdirectory(tools)
 143 endif()
 144
 145 option(OPENMP_MSVC_NAME_SCHEME "Build dll with MSVC naming scheme." OFF)
 146
 147 # Build libompd.so
 148 add_subdirectory(libompd)
 149
 150 # Build documentation
 151 add_subdirectory(docs)
 152
 153 # Now that we have seen all testsuites, create the check-openmp target.
 154 construct_check_openmp_target()