openmp/cmake/OpenMPTesting.cmake

   1 # Keep track if we have all dependencies.
   2 set(ENABLE_CHECK_TARGETS TRUE)
   3
   4 # Function to find required dependencies for testing.
   5 function(find_standalone_test_dependencies)
   6   find_package (Python3 COMPONENTS Interpreter)
   7
   8   if (NOT Python3_Interpreter_FOUND)
   9     message(STATUS "Could not find Python.")
  10     message(WARNING "The check targets will not be available!")
  11     set(ENABLE_CHECK_TARGETS FALSE PARENT_SCOPE)
  12     return()
  13   endif()
  14
  15   # Find executables.
  16   find_program(OPENMP_LLVM_LIT_EXECUTABLE
  17     NAMES llvm-lit.py llvm-lit lit.py lit
  18     PATHS ${OPENMP_LLVM_TOOLS_DIR})
  19   if (NOT OPENMP_LLVM_LIT_EXECUTABLE)
  20     message(STATUS "Cannot find llvm-lit.")
  21     message(STATUS "Please put llvm-lit in your PATH, set OPENMP_LLVM_LIT_EXECUTABLE to its full path, or point OPENMP_LLVM_TOOLS_DIR to its directory.")
  22     message(WARNING "The check targets will not be available!")
  23     set(ENABLE_CHECK_TARGETS FALSE PARENT_SCOPE)
  24     return()
  25   endif()
  26
  27   find_program(OPENMP_FILECHECK_EXECUTABLE
  28     NAMES FileCheck
  29     PATHS ${OPENMP_LLVM_TOOLS_DIR})
  30   if (NOT OPENMP_FILECHECK_EXECUTABLE)
  31     message(STATUS "Cannot find FileCheck.")
  32     message(STATUS "Please put FileCheck in your PATH, set OPENMP_FILECHECK_EXECUTABLE to its full path, or point OPENMP_LLVM_TOOLS_DIR to its directory.")
  33     message(WARNING "The check targets will not be available!")
  34     set(ENABLE_CHECK_TARGETS FALSE PARENT_SCOPE)
  35     return()
  36   endif()
  37
  38   find_program(OPENMP_NOT_EXECUTABLE
  39     NAMES not
  40     PATHS ${OPENMP_LLVM_TOOLS_DIR})
  41   if (NOT OPENMP_NOT_EXECUTABLE)
  42     message(STATUS "Cannot find 'not'.")
  43     message(STATUS "Please put 'not' in your PATH, set OPENMP_NOT_EXECUTABLE to its full path, or point OPENMP_LLVM_TOOLS_DIR to its directory.")
  44     message(WARNING "The check targets will not be available!")
  45     set(ENABLE_CHECK_TARGETS FALSE PARENT_SCOPE)
  46     return()
  47   endif()
  48 endfunction()
  49
  50 if (${OPENMP_STANDALONE_BUILD})
  51   find_standalone_test_dependencies()
  52
  53   # Set lit arguments.
  54   set(DEFAULT_LIT_ARGS "-sv --show-unsupported --show-xfail")
  55   if (MSVC OR XCODE)
  56     set(DEFAULT_LIT_ARGS "${DEFAULT_LIT_ARGS} --no-progress-bar")
  57   endif()
  58   if (${CMAKE_SYSTEM_NAME} MATCHES "AIX")
  59     set(DEFAULT_LIT_ARGS "${DEFAULT_LIT_ARGS} --time-tests --timeout=1800")
  60   endif()
  61   set(OPENMP_LIT_ARGS "${DEFAULT_LIT_ARGS}" CACHE STRING "Options for lit.")
  62   separate_arguments(OPENMP_LIT_ARGS)
  63 else()
  64   if (NOT TARGET "FileCheck")
  65     message(STATUS "Cannot find 'FileCheck'.")
  66     message(WARNING "The check targets will not be available!")
  67     set(ENABLE_CHECK_TARGETS FALSE)
  68   else()
  69     set(OPENMP_FILECHECK_EXECUTABLE ${LLVM_RUNTIME_OUTPUT_INTDIR}/FileCheck)
  70   endif()
  71   set(OPENMP_NOT_EXECUTABLE ${LLVM_RUNTIME_OUTPUT_INTDIR}/not)
  72 endif()
  73
  74 # Macro to extract information about compiler from file. (no own scope)
  75 macro(extract_test_compiler_information lang file)
  76   file(READ ${file} information)
  77   list(GET information 0 path)
  78   list(GET information 1 id)
  79   list(GET information 2 version)
  80   list(GET information 3 openmp_flags)
  81   list(GET information 4 has_tsan_flags)
  82   list(GET information 5 has_omit_frame_pointer_flags)
  83   list(GET information 6 has_omp_h)
  84
  85   set(OPENMP_TEST_${lang}_COMPILER_PATH ${path})
  86   set(OPENMP_TEST_${lang}_COMPILER_ID ${id})
  87   set(OPENMP_TEST_${lang}_COMPILER_VERSION ${version})
  88   set(OPENMP_TEST_${lang}_COMPILER_OPENMP_FLAGS ${openmp_flags})
  89   set(OPENMP_TEST_${lang}_COMPILER_HAS_TSAN_FLAGS ${has_tsan_flags})
  90   set(OPENMP_TEST_${lang}_COMPILER_HAS_OMIT_FRAME_POINTER_FLAGS ${has_omit_frame_pointer_flags})
  91   set(OPENMP_TEST_${lang}_COMPILER_HAS_OMP_H ${has_omp_h})
  92 endmacro()
  93
  94 # Function to set variables with information about the test compiler.
  95 function(set_test_compiler_information dir)
  96   extract_test_compiler_information(C ${dir}/CCompilerInformation.txt)
  97   extract_test_compiler_information(CXX ${dir}/CXXCompilerInformation.txt)
  98   if (NOT("${OPENMP_TEST_C_COMPILER_ID}" STREQUAL "${OPENMP_TEST_CXX_COMPILER_ID}" AND
  99           "${OPENMP_TEST_C_COMPILER_VERSION}" STREQUAL "${OPENMP_TEST_CXX_COMPILER_VERSION}"))
 100     message(STATUS "Test compilers for C and C++ don't match.")
 101     message(WARNING "The check targets will not be available!")
 102     set(ENABLE_CHECK_TARGETS FALSE PARENT_SCOPE)
 103   else()
 104     set(OPENMP_TEST_COMPILER_ID "${OPENMP_TEST_C_COMPILER_ID}" PARENT_SCOPE)
 105     set(OPENMP_TEST_COMPILER_VERSION "${OPENMP_TEST_C_COMPILER_VERSION}" PARENT_SCOPE)
 106     set(OPENMP_TEST_COMPILER_OPENMP_FLAGS "${OPENMP_TEST_C_COMPILER_OPENMP_FLAGS}" PARENT_SCOPE)
 107     set(OPENMP_TEST_COMPILER_HAS_TSAN_FLAGS "${OPENMP_TEST_C_COMPILER_HAS_TSAN_FLAGS}" PARENT_SCOPE)
 108     set(OPENMP_TEST_COMPILER_HAS_OMIT_FRAME_POINTER_FLAGS "${OPENMP_TEST_C_COMPILER_HAS_OMIT_FRAME_POINTER_FLAGS}" PARENT_SCOPE)
 109     set(OPENMP_TEST_COMPILER_HAS_OMP_H "${OPENMP_TEST_C_COMPILER_HAS_OMP_H}" PARENT_SCOPE)
 110
 111     # Determine major version.
 112     string(REGEX MATCH "[0-9]+" major "${OPENMP_TEST_C_COMPILER_VERSION}")
 113     string(REGEX MATCH "[0-9]+\\.[0-9]+" majorminor "${OPENMP_TEST_C_COMPILER_VERSION}")
 114     set(OPENMP_TEST_COMPILER_VERSION_MAJOR "${major}" PARENT_SCOPE)
 115     set(OPENMP_TEST_COMPILER_VERSION_MAJOR_MINOR "${majorminor}" PARENT_SCOPE)
 116   endif()
 117 endfunction()
 118
 119 if (${OPENMP_STANDALONE_BUILD})
 120   # Detect compiler that should be used for testing.
 121   # We cannot use ExternalProject_Add() because its configuration runs when this
 122   # project is built which is too late for detecting the compiler...
 123   file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/DetectTestCompiler)
 124   execute_process(
 125     COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${CMAKE_CURRENT_LIST_DIR}/DetectTestCompiler
 126       -DCMAKE_C_COMPILER=${OPENMP_TEST_C_COMPILER}
 127       -DCMAKE_CXX_COMPILER=${OPENMP_TEST_CXX_COMPILER}
 128     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/DetectTestCompiler
 129     OUTPUT_VARIABLE DETECT_COMPILER_OUT
 130     ERROR_VARIABLE DETECT_COMPILER_ERR
 131     RESULT_VARIABLE DETECT_COMPILER_RESULT)
 132   if (DETECT_COMPILER_RESULT)
 133     message(STATUS "Could not detect test compilers.")
 134     message(WARNING "The check targets will not be available!")
 135     set(ENABLE_CHECK_TARGETS FALSE)
 136   else()
 137     set_test_compiler_information(${CMAKE_CURRENT_BINARY_DIR}/DetectTestCompiler)
 138   endif()
 139 else()
 140   # Set the information that we know.
 141   set(OPENMP_TEST_COMPILER_ID "Clang")
 142   # Cannot use CLANG_VERSION because we are not guaranteed that this is already set.
 143   set(OPENMP_TEST_COMPILER_VERSION "${LLVM_VERSION}")
 144   set(OPENMP_TEST_COMPILER_VERSION_MAJOR "${LLVM_VERSION_MAJOR}")
 145   set(OPENMP_TEST_COMPILER_VERSION_MAJOR_MINOR "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}")
 146   # Unfortunately the top-level cmake/config-ix.cmake file mangles CMake's
 147   # CMAKE_THREAD_LIBS_INIT variable from the FindThreads package, so work
 148   # around that, until it is fixed there.
 149   if("${CMAKE_THREAD_LIBS_INIT}" STREQUAL "-lpthread")
 150     set(OPENMP_TEST_COMPILER_THREAD_FLAGS "-pthread")
 151   else()
 152     set(OPENMP_TEST_COMPILER_THREAD_FLAGS "${CMAKE_THREAD_LIBS_INIT}")
 153   endif()
 154   if(TARGET tsan)
 155     set(OPENMP_TEST_COMPILER_HAS_TSAN_FLAGS 1)
 156   else()
 157     set(OPENMP_TEST_COMPILER_HAS_TSAN_FLAGS 0)
 158   endif()
 159   set(OPENMP_TEST_COMPILER_HAS_OMP_H 1)
 160   set(OPENMP_TEST_COMPILER_OPENMP_FLAGS "-fopenmp ${OPENMP_TEST_COMPILER_THREAD_FLAGS}")
 161   set(OPENMP_TEST_COMPILER_HAS_OMIT_FRAME_POINTER_FLAGS 1)
 162 endif()
 163
 164 # Function to set compiler features for use in lit.
 165 function(update_test_compiler_features)
 166   set(FEATURES "[")
 167   set(first TRUE)
 168   foreach(feat IN LISTS OPENMP_TEST_COMPILER_FEATURE_LIST)
 169     if (NOT first)
 170       string(APPEND FEATURES ", ")
 171     endif()
 172     set(first FALSE)
 173     string(APPEND FEATURES "'${feat}'")
 174   endforeach()
 175   string(APPEND FEATURES "]")
 176   set(OPENMP_TEST_COMPILER_FEATURES ${FEATURES} PARENT_SCOPE)
 177 endfunction()
 178
 179 function(set_test_compiler_features)
 180   if ("${OPENMP_TEST_COMPILER_ID}" STREQUAL "GNU")
 181     set(comp "gcc")
 182   elseif ("${OPENMP_TEST_COMPILER_ID}" STREQUAL "Intel")
 183     set(comp "icc")
 184   else()
 185     # Just use the lowercase of the compiler ID as fallback.
 186     string(TOLOWER "${OPENMP_TEST_COMPILER_ID}" comp)
 187   endif()
 188   set(OPENMP_TEST_COMPILER_FEATURE_LIST ${comp} ${comp}-${OPENMP_TEST_COMPILER_VERSION_MAJOR} ${comp}-${OPENMP_TEST_COMPILER_VERSION_MAJOR_MINOR} ${comp}-${OPENMP_TEST_COMPILER_VERSION} PARENT_SCOPE)
 189 endfunction()
 190 set_test_compiler_features()
 191 update_test_compiler_features()
 192
 193 # Function to add a testsuite for an OpenMP runtime library.
 194 function(add_openmp_testsuite target comment)
 195   if (NOT ENABLE_CHECK_TARGETS)
 196     add_custom_target(${target}
 197       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, dependencies not found.")
 198     message(STATUS "${target} does nothing.")
 199     return()
 200   endif()
 201
 202   cmake_parse_arguments(ARG "EXCLUDE_FROM_CHECK_ALL" "" "DEPENDS;ARGS" ${ARGN})
 203   # EXCLUDE_FROM_CHECK_ALL excludes the test ${target} out of check-openmp.
 204   if (NOT ARG_EXCLUDE_FROM_CHECK_ALL)
 205     # Register the testsuites and depends for the check-openmp rule.
 206     set_property(GLOBAL APPEND PROPERTY OPENMP_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
 207     set_property(GLOBAL APPEND PROPERTY OPENMP_LIT_DEPENDS ${ARG_DEPENDS})
 208   endif()
 209
 210   if (${OPENMP_STANDALONE_BUILD})
 211     set(LIT_ARGS ${OPENMP_LIT_ARGS} ${ARG_ARGS})
 212     add_custom_target(${target}
 213       COMMAND ${Python3_EXECUTABLE} ${OPENMP_LLVM_LIT_EXECUTABLE} ${LIT_ARGS} ${ARG_UNPARSED_ARGUMENTS}
 214       COMMENT ${comment}
 215       DEPENDS ${ARG_DEPENDS}
 216       USES_TERMINAL
 217     )
 218   else()
 219     if (ARG_EXCLUDE_FROM_CHECK_ALL)
 220       add_lit_testsuite(${target}
 221         ${comment}
 222         ${ARG_UNPARSED_ARGUMENTS}
 223         EXCLUDE_FROM_CHECK_ALL
 224         DEPENDS clang FileCheck not ${ARG_DEPENDS}
 225         ARGS ${ARG_ARGS}
 226       )
 227     else()
 228       add_lit_testsuite(${target}
 229         ${comment}
 230         ${ARG_UNPARSED_ARGUMENTS}
 231         DEPENDS clang FileCheck not ${ARG_DEPENDS}
 232         ARGS ${ARG_ARGS}
 233       )
 234     endif()
 235   endif()
 236 endfunction()
 237
 238 function(construct_check_openmp_target)
 239   get_property(OPENMP_LIT_TESTSUITES GLOBAL PROPERTY OPENMP_LIT_TESTSUITES)
 240   get_property(OPENMP_LIT_DEPENDS GLOBAL PROPERTY OPENMP_LIT_DEPENDS)
 241
 242   # We already added the testsuites themselves, no need to do that again.
 243   add_openmp_testsuite(check-openmp "Running OpenMP tests" ${OPENMP_LIT_TESTSUITES} EXCLUDE_FROM_CHECK_ALL DEPENDS ${OPENMP_LIT_DEPENDS})
 244 endfunction()