mlir/test/Target/SPIRV/physical-storage-buffer.mlir

   1 // RUN: mlir-translate --no-implicit-module --test-spirv-roundtrip %s | FileCheck %s
   2
   3 // Test file showing how the Physical Storage Buffer extension works end-2-end.
   4
   5 !f32_binding = !spirv.struct<binding_f32_t, (!spirv.rtarray<f32, stride=4> [0])>
   6 !f32_binding_ptr = !spirv.ptr<!f32_binding, PhysicalStorageBuffer>
   7
   8 !set_0 = !spirv.struct<set_0_t, (!f32_binding_ptr [0],
   9                                  !f32_binding_ptr [8],
  10                                  !f32_binding_ptr [16])>
  11 !set_0_ptr = !spirv.ptr<!set_0, StorageBuffer>
  12
  13 !set_1 = !spirv.struct<set_1_t, (!f32_binding_ptr [0],
  14                                  !f32_binding_ptr [8])>
  15 !set_1_ptr = !spirv.ptr<!set_1, StorageBuffer>
  16
  17 spirv.module PhysicalStorageBuffer64 GLSL450 requires #spirv.vce<v1.5,
  18     [Shader, Int64, PhysicalStorageBufferAddresses], [SPV_KHR_physical_storage_buffer]> {
  19
  20   spirv.GlobalVariable @set_0 bind(3, 0) : !set_0_ptr
  21   spirv.GlobalVariable @set_1 bind(3, 1) : !set_1_ptr
  22
  23   // CHECK-LABEL: spirv.func @main() "None"
  24   spirv.func @main() "None" {
  25     %idx0 = spirv.Constant 0 : i64
  26     %idx1 = spirv.Constant 1 : i64
  27     %idx2 = spirv.Constant 2 : i64
  28     %set_0_addr = spirv.mlir.addressof @set_0 : !set_0_ptr
  29     %s0_b2_ptr = spirv.AccessChain %set_0_addr[%idx2] : !set_0_ptr, i64 -> !spirv.ptr<!f32_binding_ptr, StorageBuffer>
  30     %b2_ptr = spirv.Load "StorageBuffer" %s0_b2_ptr : !f32_binding_ptr
  31     %b2_data_ptr = spirv.AccessChain %b2_ptr[%idx0, %idx0] : !f32_binding_ptr, i64, i64 -> !spirv.ptr<f32, PhysicalStorageBuffer>
  32
  33     // CHECK: spirv.Load "PhysicalStorageBuffer"
  34     %b2_data = spirv.Load "PhysicalStorageBuffer" %b2_data_ptr ["Aligned", 4] : f32
  35
  36     %set_1_addr = spirv.mlir.addressof @set_1 : !set_1_ptr
  37     %s1_b1_ptr = spirv.AccessChain %set_1_addr[%idx1] : !set_1_ptr, i64 -> !spirv.ptr<!f32_binding_ptr, StorageBuffer>
  38     %b1_ptr = spirv.Load "StorageBuffer" %s1_b1_ptr : !f32_binding_ptr
  39     %b1_data_ptr = spirv.AccessChain %b1_ptr[%idx0, %idx0] : !f32_binding_ptr, i64, i64 -> !spirv.ptr<f32, PhysicalStorageBuffer>
  40
  41     // CHECK: spirv.Store "PhysicalStorageBuffer"
  42     spirv.Store "PhysicalStorageBuffer" %b1_data_ptr, %b2_data ["Aligned", 4] : f32
  43
  44     spirv.Return
  45   }
  46
  47   spirv.EntryPoint "GLCompute" @main, @set_0, @set_1
  48 }