mlir/test/mlir-vulkan-runner/addf.mlir

   1 // RUN: mlir-opt %s -test-vulkan-runner-pipeline \
   2 // RUN:   | mlir-vulkan-runner - --shared-libs=%vulkan-runtime-wrappers,%mlir_runner_utils --entry-point-result=void | FileCheck %s
   3
   4 // CHECK: [3.3,  3.3,  3.3,  3.3,  3.3,  3.3,  3.3,  3.3]
   5 module attributes {
   6   gpu.container_module,
   7   spirv.target_env = #spirv.target_env<
   8     #spirv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>, #spirv.resource_limits<>>
   9 } {
  10   gpu.module @kernels {
  11     gpu.func @kernel_add(%arg0 : memref<8xf32>, %arg1 : memref<8xf32>, %arg2 : memref<8xf32>)
  12       kernel attributes { spirv.entry_point_abi = #spirv.entry_point_abi<workgroup_size = [1, 1, 1]>} {
  13       %0 = gpu.block_id x
  14       %1 = memref.load %arg0[%0] : memref<8xf32>
  15       %2 = memref.load %arg1[%0] : memref<8xf32>
  16       %3 = arith.addf %1, %2 : f32
  17       memref.store %3, %arg2[%0] : memref<8xf32>
  18       gpu.return
  19     }
  20   }
  21
  22   func.func @main() {
  23     %arg0 = memref.alloc() : memref<8xf32>
  24     %arg1 = memref.alloc() : memref<8xf32>
  25     %arg2 = memref.alloc() : memref<8xf32>
  26     %0 = arith.constant 0 : i32
  27     %1 = arith.constant 1 : i32
  28     %2 = arith.constant 2 : i32
  29     %value0 = arith.constant 0.0 : f32
  30     %value1 = arith.constant 1.1 : f32
  31     %value2 = arith.constant 2.2 : f32
  32     %arg3 = memref.cast %arg0 : memref<8xf32> to memref<?xf32>
  33     %arg4 = memref.cast %arg1 : memref<8xf32> to memref<?xf32>
  34     %arg5 = memref.cast %arg2 : memref<8xf32> to memref<?xf32>
  35     call @fillResource1DFloat(%arg3, %value1) : (memref<?xf32>, f32) -> ()
  36     call @fillResource1DFloat(%arg4, %value2) : (memref<?xf32>, f32) -> ()
  37     call @fillResource1DFloat(%arg5, %value0) : (memref<?xf32>, f32) -> ()
  38
  39     %cst1 = arith.constant 1 : index
  40     %cst8 = arith.constant 8 : index
  41     gpu.launch_func @kernels::@kernel_add
  42         blocks in (%cst8, %cst1, %cst1) threads in (%cst1, %cst1, %cst1)
  43         args(%arg0 : memref<8xf32>, %arg1 : memref<8xf32>, %arg2 : memref<8xf32>)
  44     %arg6 = memref.cast %arg5 : memref<?xf32> to memref<*xf32>
  45     call @printMemrefF32(%arg6) : (memref<*xf32>) -> ()
  46     return
  47   }
  48   func.func private @fillResource1DFloat(%0 : memref<?xf32>, %1 : f32)
  49   func.func private @printMemrefF32(%ptr : memref<*xf32>)
  50 }
  51