mlir/test/mlir-vulkan-runner/addf_if.mlir

   1 // RUN: mlir-opt %s -test-vulkan-runner-pipeline \
   2 // RUN:   | mlir-vulkan-runner - --shared-libs=%vulkan-runtime-wrappers,%mlir_runner_utils --entry-point-result=void | FileCheck %s
   3
   4 // CHECK: [3.3,  3.3,  3.3,  3.3,  0,  0,  0,  0]
   5 module attributes {
   6   gpu.container_module,
   7   spirv.target_env = #spirv.target_env<
   8     #spirv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>, #spirv.resource_limits<>>
   9 } {
  10   gpu.module @kernels {
  11     gpu.func @kernel_add(%arg0 : memref<8xf32>, %arg1 : memref<8xf32>, %arg2 : memref<8xf32>)
  12       kernel attributes { spirv.entry_point_abi = #spirv.entry_point_abi<workgroup_size = [1, 1, 1]>} {
  13       %0 = gpu.block_id x
  14       %limit = arith.constant 4 : index
  15       %cond = arith.cmpi slt, %0, %limit : index
  16       scf.if %cond {
  17         %1 = memref.load %arg0[%0] : memref<8xf32>
  18         %2 = memref.load %arg1[%0] : memref<8xf32>
  19         %3 = arith.addf %1, %2 : f32
  20         memref.store %3, %arg2[%0] : memref<8xf32>
  21       }
  22       gpu.return
  23     }
  24   }
  25
  26   func.func @main() {
  27     %arg0 = memref.alloc() : memref<8xf32>
  28     %arg1 = memref.alloc() : memref<8xf32>
  29     %arg2 = memref.alloc() : memref<8xf32>
  30     %0 = arith.constant 0 : i32
  31     %1 = arith.constant 1 : i32
  32     %2 = arith.constant 2 : i32
  33     %value0 = arith.constant 0.0 : f32
  34     %value1 = arith.constant 1.1 : f32
  35     %value2 = arith.constant 2.2 : f32
  36     %arg3 = memref.cast %arg0 : memref<8xf32> to memref<?xf32>
  37     %arg4 = memref.cast %arg1 : memref<8xf32> to memref<?xf32>
  38     %arg5 = memref.cast %arg2 : memref<8xf32> to memref<?xf32>
  39     call @fillResource1DFloat(%arg3, %value1) : (memref<?xf32>, f32) -> ()
  40     call @fillResource1DFloat(%arg4, %value2) : (memref<?xf32>, f32) -> ()
  41     call @fillResource1DFloat(%arg5, %value0) : (memref<?xf32>, f32) -> ()
  42
  43     %cst1 = arith.constant 1 : index
  44     %cst8 = arith.constant 8 : index
  45     gpu.launch_func @kernels::@kernel_add
  46         blocks in (%cst8, %cst1, %cst1) threads in (%cst1, %cst1, %cst1)
  47         args(%arg0 : memref<8xf32>, %arg1 : memref<8xf32>, %arg2 : memref<8xf32>)
  48     %arg6 = memref.cast %arg5 : memref<?xf32> to memref<*xf32>
  49     call @printMemrefF32(%arg6) : (memref<*xf32>) -> ()
  50     return
  51   }
  52   func.func private @fillResource1DFloat(%0 : memref<?xf32>, %1 : f32)
  53   func.func private @printMemrefF32(%ptr : memref<*xf32>)
  54 }
  55