libc/AOR_v20.02/math/tools/cos.sollya

   1 // polynomial for approximating cos(x)
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6
   7 deg = 8;   // polynomial degree
   8 a = -pi/4; // interval
   9 b = pi/4;
  10
  11 // find even polynomial with minimal abs error compared to cos(x)
  12
  13 f = cos(x);
  14
  15 // return p that minimizes |f(x) - poly(x) - x^d*p(x)|
  16 approx = proc(poly,d) {
  17   return remez(f(x)-poly(x), deg-d, [a;b], x^d, 1e-10);
  18 };
  19
  20 // first coeff is fixed, iteratively find optimal double prec coeffs
  21 poly = 1;
  22 for i from 1 to deg/2 do {
  23   p = roundcoefficients(approx(poly,2*i), [|D ...|]);
  24   poly = poly + x^(2*i)*coeff(p,0);
  25 };
  26
  27 display = hexadecimal;
  28 print("rel error:", accurateinfnorm(1-poly(x)/f(x), [a;b], 30));
  29 print("abs error:", accurateinfnorm(f(x)-poly(x), [a;b], 30));
  30 print("in [",a,b,"]");
  31 print("coeffs:");
  32 for i from 0 to deg do coeff(poly,i);