mlir/test/Conversion/AsyncToLLVM/convert-coro-to-llvm.mlir

   1 // RUN: mlir-opt %s -convert-async-to-llvm | FileCheck %s
   2
   3 // CHECK-LABEL: @coro_id
   4 func @coro_id() {
   5   // CHECK: %0 = llvm.mlir.constant(0 : i32) : i32
   6   // CHECK: %1 = llvm.mlir.null : !llvm.ptr<i8>
   7   // CHECK: %2 = llvm.intr.coro.id %0, %1, %1, %1 : !llvm.token
   8   %0 = async.coro.id
   9   return
  10 }
  11
  12 // CHECK-LABEL: @coro_begin
  13 func @coro_begin() {
  14   // CHECK: %[[ID:.*]] = llvm.intr.coro.id
  15   %0 = async.coro.id
  16   // CHECK: %[[SIZE:.*]] = llvm.intr.coro.size : i64
  17   // CHECK: %[[ALLOC:.*]] = llvm.call @malloc(%[[SIZE]])
  18   // CHECK: %[[HDL:.*]] = llvm.intr.coro.begin %[[ID]], %[[ALLOC]]
  19   %1 = async.coro.begin %0
  20   return
  21 }
  22
  23 // CHECK-LABEL: @coro_free
  24 func @coro_free() {
  25   // CHECK: %[[ID:.*]] = llvm.intr.coro.id
  26   %0 = async.coro.id
  27   // CHECK: %[[HDL:.*]] = llvm.intr.coro.begin
  28   %1 = async.coro.begin %0
  29   // CHECK: %[[MEM:.*]] = llvm.intr.coro.free %[[ID]], %[[HDL]]
  30   // CHECK: llvm.call @free(%[[MEM]])
  31   async.coro.free %0, %1
  32   return
  33 }
  34
  35 // CHECK-LABEL: @coro_end
  36 func @coro_end() {
  37   %0 = async.coro.id
  38   // CHECK: %[[HDL:.*]] = llvm.intr.coro.begin
  39   %1 = async.coro.begin %0
  40   // CHECK: %[[FALSE:.*]] = llvm.mlir.constant(false) : i1
  41   // CHECK: llvm.intr.coro.end %[[HDL]], %[[FALSE]]
  42   async.coro.end %1
  43   return
  44 }
  45
  46 // CHECK-LABEL: @coro_save
  47 func @coro_save() {
  48   %0 = async.coro.id
  49   // CHECK: %[[HDL:.*]] = llvm.intr.coro.begin
  50   %1 = async.coro.begin %0
  51   // CHECK: llvm.intr.coro.save %[[HDL]]
  52   %2 = async.coro.save %1
  53   return
  54 }
  55
  56 // CHECK-LABEL: @coro_suspend
  57 func @coro_suspend() {
  58   %0 = async.coro.id
  59   // CHECK: %[[HDL:.*]] = llvm.intr.coro.begin
  60   %1 = async.coro.begin %0
  61   // CHECK: %[[STATE:.*]] = llvm.intr.coro.save %[[HDL]]
  62   %2 = async.coro.save %1
  63
  64   // CHECK: %[[FINAL:.*]] = llvm.mlir.constant(false) : i1
  65   // CHECK: %[[RET:.*]] = llvm.intr.coro.suspend %[[STATE]], %[[FINAL]]
  66   // CHECK: %[[SEXT:.*]] = llvm.sext %[[RET]] : i8 to i32
  67   // CHECK: llvm.switch %[[SEXT]] : i32, ^[[SUSPEND:[b0-9]+]]
  68   // CHECK-NEXT: 0: ^[[RESUME:[b0-9]+]]
  69   // CHECK-NEXT: 1: ^[[CLEANUP:[b0-9]+]]
  70   async.coro.suspend %2, ^suspend, ^resume, ^cleanup
  71 ^resume:
  72   // CHECK: ^[[RESUME]]
  73   // CHECK:   return {coro.resume}
  74   return { coro.resume }
  75 ^cleanup:
  76   // CHECK: ^[[CLEANUP]]
  77   // CHECK:   return {coro.cleanup}
  78   return { coro.cleanup }
  79 ^suspend:
  80   // CHECK: ^[[SUSPEND]]
  81   // CHECK:   return {coro.suspend}
  82   return { coro.suspend }
  83 }