mlir/test/mlir-vulkan-runner/addf.mlir

   1 // RUN: mlir-vulkan-runner %s --shared-libs=%vulkan_wrapper_library_dir/libvulkan-runtime-wrappers%shlibext,%linalg_test_lib_dir/libmlir_runner_utils%shlibext --entry-point-result=void | FileCheck %s
   2
   3 // CHECK: [3.3,  3.3,  3.3,  3.3,  3.3,  3.3,  3.3,  3.3]
   4 module attributes {
   5   gpu.container_module,
   6   spv.target_env = #spv.target_env<
   7     #spv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>, {}>
   8 } {
   9   gpu.module @kernels {
  10     gpu.func @kernel_add(%arg0 : memref<8xf32>, %arg1 : memref<8xf32>, %arg2 : memref<8xf32>)
  11       kernel attributes { spv.entry_point_abi = {local_size = dense<[1, 1, 1]>: vector<3xi32> }} {
  12       %0 = "gpu.block_id"() {dimension = "x"} : () -> index
  13       %1 = memref.load %arg0[%0] : memref<8xf32>
  14       %2 = memref.load %arg1[%0] : memref<8xf32>
  15       %3 = arith.addf %1, %2 : f32
  16       memref.store %3, %arg2[%0] : memref<8xf32>
  17       gpu.return
  18     }
  19   }
  20
  21   func @main() {
  22     %arg0 = memref.alloc() : memref<8xf32>
  23     %arg1 = memref.alloc() : memref<8xf32>
  24     %arg2 = memref.alloc() : memref<8xf32>
  25     %0 = arith.constant 0 : i32
  26     %1 = arith.constant 1 : i32
  27     %2 = arith.constant 2 : i32
  28     %value0 = arith.constant 0.0 : f32
  29     %value1 = arith.constant 1.1 : f32
  30     %value2 = arith.constant 2.2 : f32
  31     %arg3 = memref.cast %arg0 : memref<8xf32> to memref<?xf32>
  32     %arg4 = memref.cast %arg1 : memref<8xf32> to memref<?xf32>
  33     %arg5 = memref.cast %arg2 : memref<8xf32> to memref<?xf32>
  34     call @fillResource1DFloat(%arg3, %value1) : (memref<?xf32>, f32) -> ()
  35     call @fillResource1DFloat(%arg4, %value2) : (memref<?xf32>, f32) -> ()
  36     call @fillResource1DFloat(%arg5, %value0) : (memref<?xf32>, f32) -> ()
  37
  38     %cst1 = arith.constant 1 : index
  39     %cst8 = arith.constant 8 : index
  40     gpu.launch_func @kernels::@kernel_add
  41         blocks in (%cst8, %cst1, %cst1) threads in (%cst1, %cst1, %cst1)
  42         args(%arg0 : memref<8xf32>, %arg1 : memref<8xf32>, %arg2 : memref<8xf32>)
  43     %arg6 = memref.cast %arg5 : memref<?xf32> to memref<*xf32>
  44     call @print_memref_f32(%arg6) : (memref<*xf32>) -> ()
  45     return
  46   }
  47   func private @fillResource1DFloat(%0 : memref<?xf32>, %1 : f32)
  48   func private @print_memref_f32(%ptr : memref<*xf32>)
  49 }
  50