llvm/test/CodeGen/AArch64/aarch64-gep-opt.ll

   1 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -verify-machineinstrs %s -o - | FileCheck %s
   2 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -print-after=codegenprepare < %s 2>&1 | FileCheck --check-prefix=CHECK-UseAA %s
   3 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -aarch64-use-aa=false -print-after=codegenprepare < %s 2>&1 | FileCheck --check-prefix=CHECK-NoAA %s
   4 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -print-after=codegenprepare -mcpu=cyclone < %s 2>&1 | FileCheck --check-prefix=CHECK-UseAA %s
   5 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -print-after=codegenprepare -mcpu=cortex-a53 < %s 2>&1 | FileCheck --check-prefix=CHECK-UseAA %s
   6
   7 target datalayout = "e-m:e-i64:64-i128:128-n32:64-S128"
   8 target triple = "aarch64-linux-gnueabi"
   9
  10 ; Following test cases test enabling SeparateConstOffsetFromGEP pass in AArch64
  11 ; backend. If useAA() returns true, it will lower a GEP with multiple indices
  12 ; into GEPs with a single index, otherwise it will lower it into a
  13 ; "ptrtoint+arithmetics+inttoptr" form.
  14
  15 %struct = type { i32, i32, i32, i32, [20 x i32] }
  16
  17 ; Check that when two complex GEPs are used in two basic blocks, LLVM can
  18 ; eliminate the common subexpression for the second use.
  19 define void @test_GEP_CSE(ptr %string, ptr %adj, i32 %lib, i64 %idxprom) {
  20   %liberties = getelementptr [240 x %struct], ptr %string, i64 1, i64 %idxprom, i32 3
  21   %1 = load i32, ptr %liberties, align 4
  22   %cmp = icmp eq i32 %1, %lib
  23   br i1 %cmp, label %if.then, label %if.end
  24
  25 if.then:                                          ; preds = %entry
  26   %origin = getelementptr [240 x %struct], ptr %string, i64 1, i64 %idxprom, i32 2
  27   %2 = load i32, ptr %origin, align 4
  28   store i32 %2, ptr %adj, align 4
  29   br label %if.end
  30
  31 if.end:                                           ; preds = %if.then, %entry
  32   ret void
  33 }
  34
  35 ; CHECK-LABEL: test_GEP_CSE:
  36 ; CHECK: madd
  37 ; CHECK: ldr
  38 ; CHECK-NOT: madd
  39 ; CHECK:ldr
  40
  41 ; CHECK-NoAA-LABEL: @test_GEP_CSE(
  42 ; CHECK-NoAA: [[PTR0:%[a-zA-Z0-9]+]] = ptrtoint ptr %string to i64
  43 ; CHECK-NoAA: [[PTR1:%[a-zA-Z0-9]+]] = mul i64 %idxprom, 96
  44 ; CHECK-NoAA: [[PTR2:%[a-zA-Z0-9]+]] = add i64 [[PTR0]], [[PTR1]]
  45 ; CHECK-NoAA: add i64 [[PTR2]], 23052
  46 ; CHECK-NoAA: inttoptr
  47 ; CHECK-NoAA: if.then:
  48 ; CHECK-NoAA-NOT: ptrtoint
  49 ; CHECK-NoAA-NOT: mul
  50 ; CHECK-NoAA: add i64 [[PTR2]], 23048
  51 ; CHECK-NoAA: inttoptr
  52
  53 ; CHECK-UseAA-LABEL: @test_GEP_CSE(
  54 ; CHECK-UseAA: [[IDX:%[a-zA-Z0-9]+]] = mul i64 %idxprom, 96
  55 ; CHECK-UseAA: [[PTR1:%[a-zA-Z0-9]+]] = getelementptr i8, ptr %string, i64 [[IDX]]
  56 ; CHECK-UseAA: getelementptr i8, ptr [[PTR1]], i64 23052
  57 ; CHECK-UseAA: if.then:
  58 ; CHECK-UseAA: getelementptr i8, ptr [[PTR1]], i64 23048
  59
  60 %class.my = type { i32, [128 x i32], i32, [256 x %struct.pt]}
  61 %struct.pt = type { ptr, i32, i32 }
  62 %struct.point = type { i32, i32 }
  63
  64 ; Check when a GEP is used across two basic block, LLVM can sink the address
  65 ; calculation and code gen can generate a better addressing mode for the second
  66 ; use.
  67 define void @test_GEP_across_BB(ptr %this, i64 %idx) {
  68   %1 = getelementptr %class.my, ptr %this, i64 0, i32 3, i64 %idx, i32 1
  69   %2 = load i32, ptr %1, align 4
  70   %3 = getelementptr %class.my, ptr %this, i64 0, i32 3, i64 %idx, i32 2
  71   %4 = load i32, ptr %3, align 4
  72   %5 = icmp eq i32 %2, %4
  73   br i1 %5, label %if.true, label %exit
  74
  75 if.true:
  76   %6 = shl i32 %4, 1
  77   store i32 %6, ptr %3, align 4
  78   br label %exit
  79
  80 exit:
  81   %7 = add nsw i32 %4, 1
  82   store i32 %7, ptr %1, align 4
  83   ret void
  84 }
  85 ; CHECK-LABEL: test_GEP_across_BB:
  86 ; CHECK: ldr {{w[0-9]+}}, [{{x[0-9]+}}, #528]
  87 ; CHECK: ldr {{w[0-9]+}}, [{{x[0-9]+}}, #532]
  88 ; CHECK-NOT: add
  89 ; CHECK: str {{w[0-9]+}}, [{{x[0-9]+}}, #532]
  90 ; CHECK: str {{w[0-9]+}}, [{{x[0-9]+}}, #528]
  91
  92 ; CHECK-NoAA-LABEL: test_GEP_across_BB(
  93 ; CHECK-NoAA: add i64 [[TMP:%[a-zA-Z0-9]+]], 528
  94 ; CHECK-NoAA: add i64 [[TMP]], 532
  95 ; CHECK-NoAA: if.true:
  96 ; CHECK-NoAA: inttoptr
  97 ; CHECK-NoAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, {{.*}}, i64 532
  98 ; CHECK-NoAA: exit:
  99 ; CHECK-NoAA: inttoptr
 100 ; CHECK-NoAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, {{.*}}, i64 528
 101
 102 ; CHECK-UseAA-LABEL: test_GEP_across_BB(
 103 ; CHECK-UseAA: [[PTR0:%[a-zA-Z0-9]+]] = getelementptr
 104 ; CHECK-UseAA: getelementptr i8, ptr [[PTR0]], i64 528
 105 ; CHECK-UseAA: getelementptr i8, ptr [[PTR0]], i64 532
 106 ; CHECK-UseAA: if.true:
 107 ; CHECK-UseAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, ptr [[PTR0]], i64 532
 108 ; CHECK-UseAA: exit:
 109 ; CHECK-UseAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, ptr [[PTR0]], i64 528
 110
 111 %struct.S = type { float, double }
 112 @struct_array = global [1024 x %struct.S] zeroinitializer, align 16
 113
 114 ; The following two test cases check we can extract constant from indices of
 115 ; struct type.
 116 ; The constant offsets are from indices "i64 %idxprom" and "i32 1". As the
 117 ; alloca size of %struct.S is 16, and "i32 1" is the 2rd element whose field
 118 ; offset is 8, the total constant offset is (5 * 16 + 8) = 88.
 119 define ptr @test-struct_1(i32 %i) {
 120 entry:
 121   %add = add nsw i32 %i, 5
 122   %idxprom = sext i32 %add to i64
 123   %p = getelementptr [1024 x %struct.S], ptr @struct_array, i64 0, i64 %idxprom, i32 1
 124   ret ptr %p
 125 }
 126 ; CHECK-NoAA-LABEL: @test-struct_1(
 127 ; CHECK-NoAA-NOT: getelementptr
 128 ; CHECK-NoAA: add i64 %{{[a-zA-Z0-9]+}}, 88
 129
 130 ; CHECK-UseAA-LABEL: @test-struct_1(
 131 ; CHECK-UseAA: getelementptr i8, ptr %{{[a-zA-Z0-9]+}}, i64 88
 132
 133 %struct3 = type { i64, i32 }
 134 %struct2 = type { %struct3, i32 }
 135 %struct1 = type { i64, %struct2 }
 136 %struct0 = type { i32, i32, ptr, [100 x %struct1] }
 137
 138 ; The constant offsets are from indices "i32 3", "i64 %arrayidx" and "i32 1".
 139 ; "i32 3" is the 4th element whose field offset is 16. The alloca size of
 140 ; %struct1 is 32. "i32 1" is the 2rd element whose field offset is 8. So the
 141 ; total constant offset is 16 + (-2 * 32) + 8 = -40
 142 define ptr @test-struct_2(ptr %ptr, i64 %idx) {
 143 entry:
 144   %arrayidx = add nsw i64 %idx, -2
 145   %ptr2 = getelementptr %struct0, ptr %ptr, i64 0, i32 3, i64 %arrayidx, i32 1
 146   ret ptr %ptr2
 147 }
 148 ; CHECK-NoAA-LABEL: @test-struct_2(
 149 ; CHECK-NoAA-NOT: = getelementptr
 150 ; CHECK-NoAA: add i64 %{{[a-zA-Z0-9]+}}, -40
 151
 152 ; CHECK-UseAA-LABEL: @test-struct_2(
 153 ; CHECK-UseAA: getelementptr i8, ptr %{{[a-zA-Z0-9]+}}, i64 -40
 154
 155 ; Test that when a index is added from two constant, SeparateConstOffsetFromGEP
 156 ; pass does not generate incorrect result.
 157 define void @test_const_add(ptr %in) {
 158   %inc = add nsw i32 2, 1
 159   %idxprom = sext i32 %inc to i64
 160   %arrayidx = getelementptr [3 x i32], ptr %in, i64 %idxprom, i64 2
 161   store i32 0, ptr %arrayidx, align 4
 162   ret void
 163 }
 164 ; CHECK-LABEL: test_const_add:
 165 ; CHECK: str wzr, [x0, #44]