llvm/CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.20.0)
   4
   5 set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   6 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   7   NO_POLICY_SCOPE)
   8
   9 set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  10
  11 if(NOT DEFINED LLVM_VERSION_MAJOR)
  12   set(LLVM_VERSION_MAJOR 18)
  13 endif()
  14 if(NOT DEFINED LLVM_VERSION_MINOR)
  15   set(LLVM_VERSION_MINOR 0)
  16 endif()
  17 if(NOT DEFINED LLVM_VERSION_PATCH)
  18   set(LLVM_VERSION_PATCH 0)
  19 endif()
  20 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  21   set(LLVM_VERSION_SUFFIX git)
  22 endif()
  23
  24 if (NOT PACKAGE_VERSION)
  25   set(PACKAGE_VERSION
  26     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  27 endif()
  28
  29 if(NOT DEFINED LLVM_SHLIB_SYMBOL_VERSION)
  30   # "Symbol version prefix for libLLVM.so"
  31   set(LLVM_SHLIB_SYMBOL_VERSION "LLVM_${LLVM_VERSION_MAJOR}")
  32 endif()
  33
  34 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (MSVC_TOOLSET_VERSION LESS 142) AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  35   message(WARNING "Visual Studio generators use the x86 host compiler by "
  36                   "default, even for 64-bit targets. This can result in linker "
  37                   "instability and out of memory errors. To use the 64-bit "
  38                   "host compiler, pass -Thost=x64 on the CMake command line.")
  39 endif()
  40
  41 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  42   # Some CMake features like object libraries get confused if you don't
  43   # explicitly specify an architecture setting with the Xcode generator.
  44   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  45 endif()
  46
  47 project(LLVM
  48   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  49   LANGUAGES C CXX ASM)
  50
  51 if (NOT DEFINED CMAKE_INSTALL_LIBDIR AND DEFINED LLVM_LIBDIR_SUFFIX)
  52   # Must go before `include(GNUInstallDirs)`.
  53   set(CMAKE_INSTALL_LIBDIR "lib${LLVM_LIBDIR_SUFFIX}")
  54 endif()
  55
  56 # Must go after `DEFINED LLVM_LIBDIR_SUFFIX` check.
  57 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  58
  59 # Must go after `project(..)`.
  60 include(GNUInstallDirs)
  61
  62 # This C++ standard is required to build LLVM.
  63 set(LLVM_REQUIRED_CXX_STANDARD 17)
  64
  65 # If we find that the cache contains CMAKE_CXX_STANDARD it means that it's a old CMakeCache.txt
  66 # and we can just inform the user and then reset it.
  67 if($CACHE{CMAKE_CXX_STANDARD} AND $CACHE{CMAKE_CXX_STANDARD} LESS ${LLVM_REQUIRED_CXX_STANDARD})
  68   message(WARNING "Resetting cache value for CMAKE_CXX_STANDARD to ${LLVM_REQUIRED_CXX_STANDARD}")
  69   unset(CMAKE_CXX_STANDARD CACHE)
  70 endif()
  71
  72 # if CMAKE_CXX_STANDARD is still set after the cache unset above it means that the user requested it
  73 # and we allow it to be set to something newer than the required standard but otherwise we fail.
  74 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD LESS ${LLVM_REQUIRED_CXX_STANDARD})
  75   message(FATAL_ERROR "Requested CMAKE_CXX_STANDARD=${CMAKE_CXX_STANDARD} which is less than the required ${LLVM_REQUIRED_CXX_STANDARD}.")
  76 endif()
  77
  78 set(CMAKE_CXX_STANDARD ${LLVM_REQUIRED_CXX_STANDARD} CACHE STRING "C++ standard to conform to")
  79 set(CMAKE_CXX_STANDARD_REQUIRED YES)
  80
  81 if (CYGWIN)
  82   # Cygwin is a bit stricter and lack things like 'strdup', 'stricmp', etc in
  83   # c++xx mode.
  84   set(CMAKE_CXX_EXTENSIONS YES)
  85 else()
  86   set(CMAKE_CXX_EXTENSIONS NO)
  87 endif()
  88
  89 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  90   message(FATAL_ERROR "
  91 No build type selected. You need to pass -DCMAKE_BUILD_TYPE=<type> in order to configure LLVM.
  92 Available options are:
  93   * -DCMAKE_BUILD_TYPE=Release - For an optimized build with no assertions or debug info.
  94   * -DCMAKE_BUILD_TYPE=Debug - For an unoptimized build with assertions and debug info.
  95   * -DCMAKE_BUILD_TYPE=RelWithDebInfo - For an optimized build with no assertions but with debug info.
  96   * -DCMAKE_BUILD_TYPE=MinSizeRel - For a build optimized for size instead of speed.
  97 Learn more about these options in our documentation at https://llvm.org/docs/CMake.html#cmake-build-type
  98 ")
  99 endif()
 100
 101 # Set default build type for cmake's try_compile module.
 102 # CMake 3.17 or newer sets CMAKE_DEFAULT_BUILD_TYPE to one of the
 103 # items from CMAKE_CONFIGURATION_TYPES. Logic below can be further
 104 # simplified once LLVM's minimum CMake version is updated to 3.17.
 105 if(CMAKE_DEFAULT_BUILD_TYPE)
 106   set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_DEFAULT_BUILD_TYPE})
 107 else()
 108   if(CMAKE_CONFIGURATION_TYPES)
 109     list(GET CMAKE_CONFIGURATION_TYPES 0 CMAKE_TRY_COMPILE_CONFIGURATION)
 110   elseif(CMAKE_BUILD_TYPE)
 111     set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_BUILD_TYPE})
 112   endif()
 113 endif()
 114
 115 # Side-by-side subprojects layout: automatically set the
 116 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 117 # This allows an easy way of setting up a build directory for llvm and another
 118 # one for llvm+clang+... using the same sources.
 119 set(LLVM_ALL_PROJECTS "bolt;clang;clang-tools-extra;compiler-rt;cross-project-tests;libc;libclc;lld;lldb;mlir;openmp;polly;pstl")
 120 # The flang project is not yet part of "all" projects (see C++ requirements)
 121 set(LLVM_EXTRA_PROJECTS "flang")
 122 # List of all known projects in the mono repo
 123 set(LLVM_KNOWN_PROJECTS "${LLVM_ALL_PROJECTS};${LLVM_EXTRA_PROJECTS}")
 124 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 125     "Semicolon-separated list of projects to build (${LLVM_KNOWN_PROJECTS}), or \"all\".")
 126 # Make sure expansion happens first to not handle "all" in rest of the checks.
 127 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 128   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 129 endif()
 130 foreach(proj ${LLVM_ENABLE_PROJECTS})
 131   if (NOT proj STREQUAL "llvm" AND NOT "${proj}" IN_LIST LLVM_KNOWN_PROJECTS)
 132      MESSAGE(FATAL_ERROR "${proj} isn't a known project: ${LLVM_KNOWN_PROJECTS}. Did you mean to enable it as a runtime in LLVM_ENABLE_RUNTIMES?")
 133   endif()
 134 endforeach()
 135
 136 if ("flang" IN_LIST LLVM_ENABLE_PROJECTS)
 137   if (NOT "mlir" IN_LIST LLVM_ENABLE_PROJECTS)
 138     message(STATUS "Enabling MLIR as a dependency to flang")
 139     list(APPEND LLVM_ENABLE_PROJECTS "mlir")
 140   endif()
 141
 142   if (NOT "clang" IN_LIST LLVM_ENABLE_PROJECTS)
 143     message(FATAL_ERROR "Clang is not enabled, but is required for the Flang driver")
 144   endif()
 145 endif()
 146
 147 # Select the runtimes to build
 148 #
 149 # As we migrate runtimes to using the bootstrapping build, the set of default runtimes
 150 # should grow as we remove those runtimes from LLVM_ENABLE_PROJECTS above.
 151 set(LLVM_DEFAULT_RUNTIMES "libcxx;libcxxabi;libunwind")
 152 set(LLVM_SUPPORTED_RUNTIMES "libc;libunwind;libcxxabi;pstl;libcxx;compiler-rt;openmp;llvm-libgcc")
 153 set(LLVM_ENABLE_RUNTIMES "" CACHE STRING
 154   "Semicolon-separated list of runtimes to build, or \"all\" (${LLVM_DEFAULT_RUNTIMES}). Supported runtimes are ${LLVM_SUPPORTED_RUNTIMES}.")
 155 if(LLVM_ENABLE_RUNTIMES STREQUAL "all")
 156   set(LLVM_ENABLE_RUNTIMES ${LLVM_DEFAULT_RUNTIMES})
 157 endif()
 158 foreach(proj IN LISTS LLVM_ENABLE_RUNTIMES)
 159   if (NOT "${proj}" IN_LIST LLVM_SUPPORTED_RUNTIMES)
 160     message(FATAL_ERROR "Runtime \"${proj}\" is not a supported runtime. Supported runtimes are: ${LLVM_SUPPORTED_RUNTIMES}")
 161   endif()
 162 endforeach()
 163
 164 if ("libc" IN_LIST LLVM_ENABLE_RUNTIMES)
 165   # To build the libc runtime, we need to be able to build few libc build
 166   # tools from the "libc" project. So, we add it to the list of enabled
 167   # projects.
 168   if (NOT "libc" IN_LIST LLVM_ENABLE_PROJECTS)
 169     message(STATUS "Enabling libc project to build libc build tools")
 170     list(APPEND LLVM_ENABLE_PROJECTS "libc")
 171   endif()
 172 endif()
 173
 174 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
 175 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
 176 # several reasons:
 177 #
 178 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
 179 # source of truth for which projects to build. This means we will ignore user
 180 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
 181 # them.
 182 #
 183 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
 184 # non-empty list but now the user wishes to disable building all other projects
 185 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
 186 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
 187 # building all the projects that were previously enabled.
 188 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
 189 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
 190
 191 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
 192   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
 193   foreach(proj ${LLVM_KNOWN_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
 194     string(TOUPPER "${proj}" upper_proj)
 195     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 196     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
 197       message(STATUS "${proj} project is enabled")
 198       set(SHOULD_ENABLE_PROJECT TRUE)
 199       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 200       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 201         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 202       endif()
 203       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
 204         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
 205       else()
 206         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
 207       endif()
 208     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 209       message(STATUS "${proj} project is enabled")
 210       set(SHOULD_ENABLE_PROJECT TRUE)
 211     else()
 212       message(STATUS "${proj} project is disabled")
 213       set(SHOULD_ENABLE_PROJECT FALSE)
 214     endif()
 215     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 216     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 217     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 218     # we should deprecate allowing users to set these variables by turning them
 219     # into normal CMake variables rather than cache variables.
 220     set(LLVM_TOOL_${upper_proj}_BUILD
 221       ${SHOULD_ENABLE_PROJECT}
 222       CACHE
 223       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 224     )
 225   endforeach()
 226 endif()
 227 unset(SHOULD_ENABLE_PROJECT)
 228
 229 # Build llvm with ccache if the package is present
 230 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 231 if(LLVM_CCACHE_BUILD)
 232   find_program(CCACHE_PROGRAM ccache)
 233   if(CCACHE_PROGRAM)
 234     set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 235     set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 236     set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 237         CACHE STRING "Parameters to pass through to ccache")
 238
 239     if(NOT CMAKE_SYSTEM_NAME MATCHES "Windows")
 240       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 241       if (LLVM_CCACHE_MAXSIZE)
 242         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 243       endif()
 244       if (LLVM_CCACHE_DIR)
 245         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 246       endif()
 247       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 248     else()
 249       if(LLVM_CCACHE_MAXSIZE OR LLVM_CCACHE_DIR OR
 250          NOT LLVM_CCACHE_PARAMS MATCHES "CCACHE_CPP2=yes CCACHE_HASHDIR=yes")
 251         message(FATAL_ERROR "Ccache configuration through CMake is not supported on Windows. Please use environment variables.")
 252       endif()
 253       # RULE_LAUNCH_COMPILE should work with Ninja but currently has issues
 254       # with cmd.exe and some MSVC tools other than cl.exe
 255       set(CMAKE_C_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
 256       set(CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
 257     endif()
 258   else()
 259     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 260   endif()
 261 endif()
 262
 263 set(LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS "" CACHE STRING
 264   "Optional arguments for the native tool used in CMake --build invocations for external projects.")
 265 mark_as_advanced(LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS)
 266
 267 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 268
 269 # Some features of the LLVM build may be disallowed when dependency debugging is
 270 # enabled. In particular you cannot use ccache because we want to force compile
 271 # operations to always happen.
 272 if(LLVM_DEPENDENCY_DEBUGGING)
 273   if(NOT CMAKE_HOST_APPLE)
 274     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 275   endif()
 276   if(LLVM_CCACHE_BUILD)
 277     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 278   endif()
 279 endif()
 280
 281 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 282 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 283 if(LLVM_ENABLE_GISEL_COV)
 284   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 285 endif()
 286
 287 # Add path for custom modules
 288 list(INSERT CMAKE_MODULE_PATH 0
 289   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 290   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 291   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
 292   )
 293
 294 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 295 # for use by clang_complete, YouCompleteMe, etc.
 296 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 297
 298 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 299   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 300
 301 option(LLVM_INSTALL_CCTOOLS_SYMLINKS
 302   "Install symlinks from the cctools tool names to the corresponding LLVM tools." OFF)
 303
 304 # By default we use symlinks on Unix platforms and copy binaries on Windows
 305 # If you have the correct setup on Windows you can use this option to enable
 306 # symlinks and save a lot of diskspace.
 307 option(LLVM_USE_SYMLINKS "Use symlinks instead of copying binaries" ${CMAKE_HOST_UNIX})
 308
 309 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 310
 311 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 312
 313 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 314 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 315 # the installation by default. See llvm.org/PR31905.
 316 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 317
 318 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 319 if ( LLVM_USE_FOLDERS )
 320   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 321 endif()
 322
 323 include(VersionFromVCS)
 324
 325 option(LLVM_APPEND_VC_REV
 326   "Embed the version control system revision in LLVM" ON)
 327
 328 option(LLVM_TOOL_LLVM_DRIVER_BUILD "Enables building the llvm multicall tool" OFF)
 329
 330 set(PACKAGE_NAME LLVM)
 331 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 332 set(PACKAGE_BUGREPORT "https://github.com/llvm/llvm-project/issues/")
 333
 334 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 335   "Default URL where bug reports are to be submitted.")
 336
 337 # Configure CPack.
 338 if(NOT DEFINED CPACK_PACKAGE_INSTALL_DIRECTORY)
 339   set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 340 endif()
 341 if(NOT DEFINED CPACK_PACKAGE_VENDOR)
 342   set(CPACK_PACKAGE_VENDOR "LLVM")
 343 endif()
 344 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 345 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 346 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 347 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 348 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 349 if(WIN32 AND NOT UNIX)
 350   set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 351   if(NOT DEFINED CPACK_PACKAGE_INSTALL_REGISTRY_KEY)
 352     set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 353   endif()
 354   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 355   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 356   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 357   set(CPACK_NSIS_MODIFY_PATH "ON")
 358   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 359   if( CMAKE_CL_64 )
 360     if(NOT DEFINED CPACK_NSIS_INSTALL_ROOT)
 361       set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 362     endif()
 363   endif()
 364 endif()
 365 include(CPack)
 366
 367 # Sanity check our source directory to make sure that we are not trying to
 368 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 369 # sure that we don't have any stray generated files lying around in the tree
 370 # (which would end up getting picked up by header search, instead of the correct
 371 # versions).
 372 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 373   message(FATAL_ERROR "In-source builds are not allowed.
 374 Please create a directory and run cmake from there, passing the path
 375 to this source directory as the last argument.
 376 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 377 Please delete them.")
 378 endif()
 379
 380 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 381
 382 if (CMAKE_BUILD_TYPE AND
 383     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 384   message(WARNING "Unknown value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 385 endif()
 386
 387 # LLVM_INSTALL_PACKAGE_DIR needs to be declared prior to adding the tools
 388 # subdirectory in order to have the value available for llvm-config.
 389 include(GNUInstallPackageDir)
 390 set(LLVM_INSTALL_PACKAGE_DIR "${CMAKE_INSTALL_PACKAGEDIR}/llvm" CACHE STRING
 391   "Path for CMake subdirectory for LLVM (defaults to '${CMAKE_INSTALL_PACKAGEDIR}/llvm')")
 392
 393 set(LLVM_TOOLS_INSTALL_DIR "${CMAKE_INSTALL_BINDIR}" CACHE STRING
 394     "Path for binary subdirectory (defaults to '${CMAKE_INSTALL_BINDIR}')")
 395 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 396
 397 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 398     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 399 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 400
 401 set(LLVM_EXAMPLES_INSTALL_DIR "examples" CACHE STRING
 402     "Path for examples subdirectory (enabled by LLVM_BUILD_EXAMPLES=ON) (defaults to 'examples')")
 403 mark_as_advanced(LLVM_EXAMPLES_INSTALL_DIR)
 404
 405 # They are used as destination of target generators.
 406 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 407 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 408 if(WIN32 OR CYGWIN)
 409   # DLL platform -- put DLLs into bin.
 410   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 411 else()
 412   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 413 endif()
 414
 415 # Each of them corresponds to llvm-config's.
 416 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 417 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 418 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 419 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 420 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 421
 422
 423 # Note: LLVM_CMAKE_DIR does not include generated files
 424 set(LLVM_CMAKE_DIR ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 425 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 426 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 427
 428 # List of all targets to be built by default:
 429 set(LLVM_ALL_TARGETS
 430   AArch64
 431   AMDGPU
 432   ARM
 433   AVR
 434   BPF
 435   Hexagon
 436   Lanai
 437   LoongArch
 438   Mips
 439   MSP430
 440   NVPTX
 441   PowerPC
 442   RISCV
 443   Sparc
 444   SystemZ
 445   VE
 446   WebAssembly
 447   X86
 448   XCore
 449   )
 450
 451 set(LLVM_ALL_EXPERIMENTAL_TARGETS
 452   ARC
 453   CSKY
 454   DirectX
 455   M68k
 456   SPIRV
 457   Xtensa
 458 )
 459
 460 # List of targets with JIT support:
 461 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 462
 463 set(LLVM_TARGETS_TO_BUILD "all"
 464     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 465
 466 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 467     CACHE STRING "Semicolon-separated list of experimental targets to build, or \"all\".")
 468
 469 option(BUILD_SHARED_LIBS
 470   "Build all libraries as shared libraries instead of static" OFF)
 471
 472 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 473 if(LLVM_ENABLE_BACKTRACES)
 474   set(ENABLE_BACKTRACES 1)
 475 endif()
 476
 477 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 478
 479 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 480 if(LLVM_ENABLE_CRASH_OVERRIDES)
 481   set(ENABLE_CRASH_OVERRIDES 1)
 482 endif()
 483
 484 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 485
 486 set(WINDOWS_PREFER_FORWARD_SLASH_DEFAULT OFF)
 487 if (MINGW)
 488   # Cygwin doesn't identify itself as Windows, and thus gets path::Style::posix
 489   # as native path style, regardless of what this is set to.
 490   set(WINDOWS_PREFER_FORWARD_SLASH_DEFAULT ON)
 491 endif()
 492 option(LLVM_WINDOWS_PREFER_FORWARD_SLASH "Prefer path names with forward slashes on Windows." ${WINDOWS_PREFER_FORWARD_SLASH_DEFAULT})
 493
 494 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 495 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 496 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 497
 498 set(LLVM_TARGET_ARCH "host"
 499   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 500
 501 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 502
 503 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 504
 505 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 506
 507 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 508
 509 # On z/OS, threads cannot be used because TLS is not supported.
 510 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
 511   option(LLVM_ENABLE_THREADS "Use threads if available." OFF)
 512 else()
 513   option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 514 endif()
 515
 516 set(LLVM_ENABLE_ZLIB "ON" CACHE STRING "Use zlib for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
 517
 518 set(LLVM_ENABLE_ZSTD "ON" CACHE STRING "Use zstd for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
 519
 520 set(LLVM_USE_STATIC_ZSTD FALSE CACHE BOOL "Use static version of zstd. Can be TRUE, FALSE")
 521
 522 set(LLVM_ENABLE_CURL "OFF" CACHE STRING "Use libcurl for the HTTP client if available. Can be ON, OFF, or FORCE_ON")
 523
 524 set(LLVM_ENABLE_HTTPLIB "OFF" CACHE STRING "Use cpp-httplib HTTP server library if available. Can be ON, OFF, or FORCE_ON")
 525
 526 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 527
 528 option(LLVM_ENABLE_Z3_SOLVER
 529   "Enable Support for the Z3 constraint solver in LLVM."
 530   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 531 )
 532
 533 if (LLVM_ENABLE_Z3_SOLVER)
 534   find_package(Z3 4.7.1)
 535
 536   if (LLVM_Z3_INSTALL_DIR)
 537     if (NOT Z3_FOUND)
 538       message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 539     endif()
 540   endif()
 541
 542   if (NOT Z3_FOUND)
 543     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 544   endif()
 545
 546   set(LLVM_WITH_Z3 1)
 547 endif()
 548
 549 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 550
 551
 552 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 553   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 554 endif()
 555
 556 if(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD STREQUAL "all")
 557   set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${LLVM_ALL_EXPERIMENTAL_TARGETS})
 558 endif()
 559
 560 set(LLVM_TARGETS_TO_BUILD
 561    ${LLVM_TARGETS_TO_BUILD}
 562    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 563 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 564
 565 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 566 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 567 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 568   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 569 else()
 570   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 571 endif()
 572 option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 573 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 574 option(LLVM_ENABLE_LLVM_LIBC "Set to on to link all LLVM executables against LLVM libc, assuming it is accessible by the host compiler." OFF)
 575 option(LLVM_STATIC_LINK_CXX_STDLIB "Statically link the standard library." OFF)
 576 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 577 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 578 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 579
 580 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 581 option(LLVM_UNREACHABLE_OPTIMIZE "Optimize llvm_unreachable() as undefined behavior (default), guaranteed trap when OFF" ON)
 582
 583 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 584   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 585 else()
 586   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 587 endif()
 588
 589 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 590
 591 # While adding scalable vector support to LLVM, we temporarily want to
 592 # allow an implicit conversion of TypeSize to uint64_t, and to allow
 593 # code to get the fixed number of elements from a possibly scalable vector.
 594 # This CMake flag enables a more strict mode where it asserts that the type
 595 # is not a scalable vector type.
 596 #
 597 # Enabling this flag makes it easier to find cases where the compiler makes
 598 # assumptions on the size being 'fixed size', when building tests for
 599 # SVE/SVE2 or other scalable vector architectures.
 600 option(LLVM_ENABLE_STRICT_FIXED_SIZE_VECTORS
 601        "Enable assertions that type is not scalable in implicit conversion from TypeSize to uint64_t and calls to getNumElements" OFF)
 602
 603 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 604   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 605
 606 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 607        "Set to ON to force using an old, unsupported host toolchain." OFF)
 608
 609 set(LLVM_LOCAL_RPATH "" CACHE FILEPATH
 610   "If set, an absolute path added as rpath on binaries that do not already contain an executable-relative rpath.")
 611
 612 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 613        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 614
 615 option(LLVM_USE_INTEL_JITEVENTS
 616   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 617   OFF)
 618
 619 if( LLVM_USE_INTEL_JITEVENTS )
 620   # Verify we are on a supported platform
 621   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 622     message(FATAL_ERROR
 623       "Intel JIT API support is available on Linux and Windows only.")
 624   endif()
 625 endif( LLVM_USE_INTEL_JITEVENTS )
 626
 627 option(LLVM_USE_OPROFILE
 628   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 629
 630 option(LLVM_EXTERNALIZE_DEBUGINFO
 631   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 632
 633 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 634   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 635
 636 # If enabled, verify we are on a platform that supports oprofile.
 637 if( LLVM_USE_OPROFILE )
 638   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 639     message(FATAL_ERROR "OProfile support is available on Linux only.")
 640   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 641 endif( LLVM_USE_OPROFILE )
 642
 643 option(LLVM_USE_PERF
 644   "Use perf JIT interface to inform perf about JIT code" OFF)
 645
 646 # If enabled, verify we are on a platform that supports perf.
 647 if( LLVM_USE_PERF )
 648   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 649     message(FATAL_ERROR "perf support is available on Linux only.")
 650   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 651 endif( LLVM_USE_PERF )
 652
 653 set(LLVM_USE_SANITIZER "" CACHE STRING
 654   "Define the sanitizer used to build binaries and tests.")
 655 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 656 set(LLVM_UBSAN_FLAGS
 657     "-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 658     CACHE STRING
 659     "Compile flags set to enable UBSan. Only used if LLVM_USE_SANITIZER contains 'Undefined'.")
 660 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 661   "Path to fuzzing library for linking with fuzz targets")
 662
 663 option(LLVM_USE_SPLIT_DWARF
 664   "Use -gsplit-dwarf when compiling llvm and --gdb-index when linking." OFF)
 665
 666 # Define an option controlling whether we should build for 32-bit on 64-bit
 667 # platforms, where supported.
 668 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT (WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX"))
 669   # TODO: support other platforms and toolchains.
 670   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 671 endif()
 672
 673 # Define the default arguments to use with 'lit', and an option for the user to
 674 # override.
 675 set(LIT_ARGS_DEFAULT "-sv")
 676 if (MSVC_IDE OR XCODE)
 677   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 678 endif()
 679 if(LLVM_INDIVIDUAL_TEST_COVERAGE)
 680    set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --per-test-coverage")
 681 endif()
 682 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 683
 684 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 685 if( WIN32 AND NOT CYGWIN )
 686   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 687 endif()
 688 set(LLVM_NATIVE_TOOL_DIR "" CACHE PATH "Path to a directory containing prebuilt matching native tools (such as llvm-tblgen)")
 689
 690 set(LLVM_INTEGRATED_CRT_ALLOC "" CACHE PATH "Replace the Windows CRT allocator with any of {rpmalloc|mimalloc|snmalloc}. Only works with CMAKE_MSVC_RUNTIME_LIBRARY=MultiThreaded.")
 691 if(LLVM_INTEGRATED_CRT_ALLOC)
 692   if(NOT WIN32)
 693     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC is only supported on Windows.")
 694   endif()
 695   if(LLVM_USE_SANITIZER)
 696     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC cannot be used along with LLVM_USE_SANITIZER!")
 697   endif()
 698   if(CMAKE_BUILD_TYPE AND uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 699     message(FATAL_ERROR "The Debug target isn't supported along with LLVM_INTEGRATED_CRT_ALLOC!")
 700   endif()
 701 endif()
 702
 703 # Define options to control the inclusion and default build behavior for
 704 # components which may not strictly be necessary (tools, examples, and tests).
 705 #
 706 # This is primarily to support building smaller or faster project files.
 707 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 708 option(LLVM_BUILD_TOOLS
 709   "Build the LLVM tools. If OFF, just generate build targets." ON)
 710
 711 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 712 option(LLVM_BUILD_UTILS
 713   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 714
 715 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 716 option(LLVM_BUILD_RUNTIMES
 717   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 718
 719 option(LLVM_BUILD_RUNTIME
 720   "Build the LLVM runtime libraries." ON)
 721 option(LLVM_BUILD_EXAMPLES
 722   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 723 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 724
 725 if(LLVM_BUILD_EXAMPLES)
 726   add_compile_definitions(BUILD_EXAMPLES)
 727 endif(LLVM_BUILD_EXAMPLES)
 728
 729 option(LLVM_BUILD_TESTS
 730   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 731 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 732
 733 option(LLVM_INSTALL_GTEST
 734   "Install the llvm gtest library.  This should be on if you want to do
 735    stand-alone builds of the other projects and run their unit tests." OFF)
 736
 737 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 738 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 739 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 740
 741 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 742 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 743 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 744 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 745 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 746 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 747
 748 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "${CMAKE_INSTALL_DOCDIR}/llvm/doxygen-html"
 749     CACHE STRING "Doxygen-generated HTML documentation install directory")
 750 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "${CMAKE_INSTALL_DOCDIR}/llvm/ocaml-html"
 751     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 752
 753 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 754   "Build compiler-rt as an external project." OFF)
 755
 756 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 757   "Show target and host info when tools are invoked with --version." ON)
 758
 759 # You can configure which libraries from LLVM you want to include in the
 760 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 761 # list of LLVM components. All component names handled by llvm-config are valid.
 762 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 763   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 764     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 765 endif()
 766
 767 if(MSVC)
 768   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 769   # Set this variable to OFF here so it can't be set with a command-line
 770   # argument.
 771   set (LLVM_LINK_LLVM_DYLIB OFF)
 772   if (BUILD_SHARED_LIBS)
 773     message(FATAL_ERROR "BUILD_SHARED_LIBS options is not supported on Windows.")
 774   endif()
 775 else()
 776   option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 777   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 778   set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 779   if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 780     set(LLVM_BUILD_LLVM_DYLIB_default ON)
 781   endif()
 782   option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 783 endif()
 784
 785 if (LLVM_LINK_LLVM_DYLIB AND BUILD_SHARED_LIBS)
 786   message(FATAL_ERROR "Cannot enable BUILD_SHARED_LIBS with LLVM_LINK_LLVM_DYLIB.  We recommend disabling BUILD_SHARED_LIBS.")
 787 endif()
 788
 789 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 790 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 791   set(LLVM_USE_HOST_TOOLS ON)
 792 endif()
 793
 794 option(LLVM_OMIT_DAGISEL_COMMENTS "Do not add comments to DAG ISel" ON)
 795 if (CMAKE_BUILD_TYPE AND uppercase_CMAKE_BUILD_TYPE MATCHES "^(RELWITHDEBINFO|DEBUG)$")
 796   set(LLVM_OMIT_DAGISEL_COMMENTS OFF)
 797 endif()
 798
 799 if (MSVC_IDE)
 800   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 801 endif()
 802
 803 if(NOT LLVM_INDIVIDUAL_TEST_COVERAGE)
 804   if(LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR LLVM_ENABLE_IR_PGO)
 805     if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 806       # A pool size of 1-2 is probably sufficient on an SSD. 3-4 should be fine
 807       # for spinning disks. Anything higher may only help on slower mediums.
 808       set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 809     endif()
 810     if(NOT LLVM_PROFILE_FILE_PATTERN)
 811       if(NOT LLVM_PROFILE_DATA_DIR)
 812         file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 813       endif()
 814       file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 815     endif()
 816     if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 817       if(NOT LLVM_CSPROFILE_DATA_DIR)
 818         file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 819       endif()
 820       file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 821     endif()
 822   endif()
 823 endif()
 824
 825 if (LLVM_BUILD_STATIC)
 826   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 827   # Remove shared library suffixes from use in find_library
 828   foreach (shared_lib_suffix ${CMAKE_SHARED_LIBRARY_SUFFIX} ${CMAKE_IMPORT_LIBRARY_SUFFIX})
 829     list(FIND CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix} shared_lib_suffix_idx)
 830     if(NOT ${shared_lib_suffix_idx} EQUAL -1)
 831       list(REMOVE_AT CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix_idx})
 832     endif()
 833   endforeach()
 834 endif()
 835
 836 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 837 if(CMAKE_HOST_APPLE AND APPLE)
 838   include(UseLibtool)
 839 endif()
 840
 841 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 842 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 843 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 844
 845 if(CMAKE_SYSTEM_NAME MATCHES "BSD|Linux|OS390")
 846   set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default ON)
 847 else()
 848   set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default OFF)
 849 endif()
 850 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR ${LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default} CACHE BOOL
 851   "Enable per-target runtimes directory")
 852
 853 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 854   "Profiling data file to use when compiling in order to improve runtime performance.")
 855
 856 if(LLVM_INCLUDE_TESTS)
 857   # Lit test suite requires at least python 3.6
 858   set(LLVM_MINIMUM_PYTHON_VERSION 3.6)
 859 else()
 860   # FIXME: it is unknown if this is the actual minimum bound
 861   set(LLVM_MINIMUM_PYTHON_VERSION 3.0)
 862 endif()
 863
 864 # Find python before including config-ix, since it needs to be able to search
 865 # for python modules.
 866 find_package(Python3 ${LLVM_MINIMUM_PYTHON_VERSION} REQUIRED
 867     COMPONENTS Interpreter)
 868
 869 # All options referred to from HandleLLVMOptions have to be specified
 870 # BEFORE this include, otherwise options will not be correctly set on
 871 # first cmake run
 872 include(config-ix)
 873
 874 # By default, we target the host, but this can be overridden at CMake
 875 # invocation time. Except on 64-bit AIX, where the system toolchain
 876 # expect 32-bit objects by default.
 877 if("${LLVM_HOST_TRIPLE}" MATCHES "^powerpc64-ibm-aix")
 878   string(REGEX REPLACE "^powerpc64" "powerpc" LLVM_DEFAULT_TARGET_TRIPLE_default "${LLVM_HOST_TRIPLE}")
 879 else()
 880   # Only set default triple when native target is enabled.
 881   if (LLVM_NATIVE_TARGET)
 882     set(LLVM_DEFAULT_TARGET_TRIPLE_default "${LLVM_HOST_TRIPLE}")
 883   endif()
 884 endif()
 885
 886 include(SetTargetTriple)
 887 set_llvm_target_triple()
 888
 889 if(WIN32 OR CYGWIN)
 890   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 891     set(LLVM_ENABLE_PLUGINS_default ON)
 892   else()
 893     set(LLVM_ENABLE_PLUGINS_default OFF)
 894   endif()
 895 else()
 896   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 897 endif()
 898 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 899
 900 set(LLVM_ENABLE_NEW_PASS_MANAGER TRUE CACHE BOOL
 901   "Enable the new pass manager by default.")
 902 if(NOT LLVM_ENABLE_NEW_PASS_MANAGER)
 903   message(FATAL_ERROR "Enabling the legacy pass manager on the cmake level is"
 904                       " no longer supported.")
 905 endif()
 906
 907 include(HandleLLVMOptions)
 908
 909 ######
 910
 911 # Configure all of the various header file fragments LLVM uses which depend on
 912 # configuration variables.
 913 set(LLVM_ENUM_TARGETS "")
 914 set(LLVM_ENUM_ASM_PRINTERS "")
 915 set(LLVM_ENUM_ASM_PARSERS "")
 916 set(LLVM_ENUM_DISASSEMBLERS "")
 917 set(LLVM_ENUM_TARGETMCAS "")
 918 set(LLVM_ENUM_EXEGESIS "")
 919 foreach(t ${LLVM_TARGETS_TO_BUILD})
 920   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 921
 922   # Make sure that any experimental targets were passed via
 923   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 924   # We allow experimental targets that are not in LLVM_ALL_EXPERIMENTAL_TARGETS,
 925   # as long as they are passed via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.
 926   if ( NOT ${t} IN_LIST LLVM_ALL_TARGETS AND NOT ${t} IN_LIST LLVM_EXPERIMENTAL_TARGETS_TO_BUILD )
 927     if( ${t} IN_LIST LLVM_ALL_EXPERIMENTAL_TARGETS )
 928       message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 929         "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 930     else()
 931       message(FATAL_ERROR "The target `${t}' is not a core tier target. It may be "
 932         "experimental, if so it must be passed via "
 933         "LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.\n"
 934         "Core tier targets: ${LLVM_ALL_TARGETS}\n"
 935         "Known experimental targets: ${LLVM_ALL_EXPERIMENTAL_TARGETS}")
 936     endif()
 937   else()
 938     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 939   endif()
 940
 941   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 942   if( asmp_file )
 943     set(LLVM_ENUM_ASM_PRINTERS
 944       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 945   endif()
 946   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 947     set(LLVM_ENUM_ASM_PARSERS
 948       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 949   endif()
 950   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 951     set(LLVM_ENUM_DISASSEMBLERS
 952       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 953   endif()
 954   if( EXISTS ${td}/MCA/CMakeLists.txt )
 955     set(LLVM_ENUM_TARGETMCAS
 956       "${LLVM_ENUM_TARGETMCAS}LLVM_TARGETMCA(${t})\n")
 957   endif()
 958   if( EXISTS ${LLVM_MAIN_SRC_DIR}/tools/llvm-exegesis/lib/${t}/CMakeLists.txt )
 959     set(LLVM_ENUM_EXEGESIS
 960       "${LLVM_ENUM_EXEGESIS}LLVM_EXEGESIS(${t})\n")
 961   endif()
 962 endforeach(t)
 963
 964 # Provide an LLVM_ namespaced alias for use in #cmakedefine.
 965 set(LLVM_BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS})
 966
 967 # Produce the target definition files, which provide a way for clients to easily
 968 # include various classes of targets.
 969 configure_file(
 970   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 971   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 972   )
 973 configure_file(
 974   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 975   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 976   )
 977 configure_file(
 978   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 979   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 980   )
 981 configure_file(
 982   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 983   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 984   )
 985 configure_file(
 986   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/TargetMCAs.def.in
 987   ${LLVM_INCLUDE_DIR}/llvm/Config/TargetMCAs.def
 988   )
 989 configure_file(
 990   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/TargetExegesis.def.in
 991   ${LLVM_INCLUDE_DIR}/llvm/Config/TargetExegesis.def
 992   )
 993
 994 # They are not referenced. See set_output_directory().
 995 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 996 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_LIBRARY_DIR} )
 997 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_LIBRARY_DIR} )
 998
 999 # For up-to-date instructions for installing the TFLite dependency, refer to
1000 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/main/buildbot/buildbot_init.sh
1001 set(LLVM_HAVE_TFLITE "" CACHE BOOL "Use tflite")
1002 if (LLVM_HAVE_TFLITE)
1003   find_package(tensorflow-lite REQUIRED)
1004 endif()
1005
1006 # For up-to-date instructions for installing the Tensorflow dependency, refer to
1007 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/main/buildbot/buildbot_init.sh
1008 # Specifically, assuming python3 is installed:
1009 # python3 -m pip install --upgrade pip && python3 -m pip install --user tf_nightly==2.3.0.dev20200528
1010 # Then set TENSORFLOW_AOT_PATH to the package install - usually it's ~/.local/lib/python3.7/site-packages/tensorflow
1011 #
1012 set(TENSORFLOW_AOT_PATH "" CACHE PATH "Path to TensorFlow pip install dir")
1013
1014 if (NOT TENSORFLOW_AOT_PATH STREQUAL "")
1015   set(LLVM_HAVE_TF_AOT "ON" CACHE BOOL "Tensorflow AOT available")
1016   set(TENSORFLOW_AOT_COMPILER
1017     "${TENSORFLOW_AOT_PATH}/../../../../bin/saved_model_cli"
1018     CACHE PATH "Path to the Tensorflow AOT compiler")
1019   include_directories(${TENSORFLOW_AOT_PATH}/include)
1020   add_subdirectory(${TENSORFLOW_AOT_PATH}/xla_aot_runtime_src
1021     ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/tf_runtime)
1022   install(TARGETS tf_xla_runtime EXPORT LLVMExports
1023     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX} COMPONENT tf_xla_runtime)
1024   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS tf_xla_runtime)
1025   # Once we add more modules, we should handle this more automatically.
1026   if (DEFINED LLVM_OVERRIDE_MODEL_HEADER_INLINERSIZEMODEL)
1027     set(LLVM_INLINER_MODEL_PATH "none")
1028   elseif(NOT DEFINED LLVM_INLINER_MODEL_PATH
1029       OR "${LLVM_INLINER_MODEL_PATH}" STREQUAL ""
1030       OR "${LLVM_INLINER_MODEL_PATH}" STREQUAL "autogenerate")
1031     set(LLVM_INLINER_MODEL_PATH "autogenerate")
1032     set(LLVM_INLINER_MODEL_AUTOGENERATED 1)
1033   endif()
1034   if (DEFINED LLVM_OVERRIDE_MODEL_HEADER_REGALLOCEVICTMODEL)
1035     set(LLVM_RAEVICT_MODEL_PATH "none")
1036   elseif(NOT DEFINED LLVM_RAEVICT_MODEL_PATH
1037       OR "${LLVM_RAEVICT_MODEL_PATH}" STREQUAL ""
1038       OR "${LLVM_RAEVICT_MODEL_PATH}" STREQUAL "autogenerate")
1039     set(LLVM_RAEVICT_MODEL_PATH "autogenerate")
1040     set(LLVM_RAEVICT_MODEL_AUTOGENERATED 1)
1041   endif()
1042
1043 endif()
1044
1045 # Configure the three LLVM configuration header files.
1046 configure_file(
1047   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
1048   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
1049 configure_file(
1050   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
1051   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
1052 configure_file(
1053   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
1054   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
1055
1056 # Add target for generating source rpm package.
1057 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
1058     CACHE FILEPATH ".spec file to use for srpm generation")
1059 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
1060 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
1061
1062 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
1063 string(LENGTH "${revision}" revision_length)
1064 set(LLVM_RPM_SPEC_REVISION "${revision}")
1065
1066 configure_file(
1067   ${LLVM_SRPM_USER_BINARY_SPECFILE}
1068   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
1069
1070 add_custom_target(srpm
1071   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
1072   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
1073 set_target_properties(srpm PROPERTIES FOLDER "Misc")
1074
1075 if(APPLE AND DARWIN_LTO_LIBRARY)
1076   set(CMAKE_EXE_LINKER_FLAGS
1077     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1078   set(CMAKE_SHARED_LINKER_FLAGS
1079     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1080   set(CMAKE_MODULE_LINKER_FLAGS
1081     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1082 endif()
1083
1084 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
1085 # break things. In this case we need to enable the large-file API as well.
1086 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
1087           add_compile_definitions(_XOPEN_SOURCE=700)
1088           add_compile_definitions(_LARGE_FILE_API)
1089
1090   # Modules should be built with -shared -Wl,-G, so we can use runtime linking
1091   # with plugins.
1092   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -shared -Wl,-G")
1093
1094   # Also set the correct flags for building shared libraries.
1095   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -shared")
1096 endif()
1097
1098 # Build with _XOPEN_SOURCE on z/OS.
1099 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
1100   add_compile_definitions(_XOPEN_SOURCE=600)
1101   add_compile_definitions(_OPEN_SYS) # Needed for process information.
1102   add_compile_definitions(_OPEN_SYS_FILE_EXT) # Needed for EBCDIC I/O.
1103 endif()
1104
1105 # Build with _FILE_OFFSET_BITS=64 on Solaris to match g++ >= 9.
1106 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
1107           add_compile_definitions(_FILE_OFFSET_BITS=64)
1108 endif()
1109
1110 set(CMAKE_INCLUDE_CURRENT_DIR ON)
1111
1112 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
1113
1114 # when crosscompiling import the executable targets from a file
1115 if(LLVM_USE_HOST_TOOLS)
1116   include(CrossCompile)
1117   llvm_create_cross_target(LLVM NATIVE "" Release)
1118 endif(LLVM_USE_HOST_TOOLS)
1119 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
1120 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
1121 # (this is a variable that CrossCompile sets on recursive invocations)
1122 endif()
1123
1124 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
1125    # special hack for Solaris to handle crazy system sys/regset.h
1126    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
1127 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
1128
1129 # Make sure we don't get -rdynamic in every binary. For those that need it,
1130 # use export_executable_symbols(target).
1131 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
1132
1133 include(AddLLVM)
1134 include(TableGen)
1135
1136 include(LLVMDistributionSupport)
1137
1138 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
1139   # People report that -O3 is unreliable on MinGW. The traditional
1140   # build also uses -O2 for that reason:
1141   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
1142 endif()
1143
1144 if(LLVM_INCLUDE_TESTS)
1145   umbrella_lit_testsuite_begin(check-all)
1146 endif()
1147
1148 # Put this before tblgen. Else we have a circular dependence.
1149 add_subdirectory(lib/Demangle)
1150 add_subdirectory(lib/Support)
1151 add_subdirectory(lib/TableGen)
1152
1153 add_subdirectory(utils/TableGen)
1154
1155 add_subdirectory(include)
1156
1157 add_subdirectory(lib)
1158
1159 if( LLVM_INCLUDE_UTILS )
1160   add_subdirectory(utils/FileCheck)
1161   add_subdirectory(utils/PerfectShuffle)
1162   add_subdirectory(utils/count)
1163   add_subdirectory(utils/not)
1164   add_subdirectory(utils/UnicodeData)
1165   add_subdirectory(utils/yaml-bench)
1166   add_subdirectory(utils/split-file)
1167   if( LLVM_INCLUDE_TESTS )
1168     add_subdirectory(${LLVM_THIRD_PARTY_DIR}/unittest ${CMAKE_CURRENT_BINARY_DIR}/third-party/unittest)
1169   endif()
1170 else()
1171   if ( LLVM_INCLUDE_TESTS )
1172     message(FATAL_ERROR "Including tests when not building utils will not work.
1173     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
1174   endif()
1175 endif()
1176
1177 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
1178 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
1179   add_subdirectory(utils/LLVMVisualizers)
1180 endif()
1181
1182 foreach( binding ${LLVM_BINDINGS_LIST} )
1183   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
1184     add_subdirectory(bindings/${binding})
1185   endif()
1186 endforeach()
1187
1188 add_subdirectory(projects)
1189
1190 if( LLVM_INCLUDE_TOOLS )
1191   add_subdirectory(tools)
1192 endif()
1193
1194 if( LLVM_INCLUDE_RUNTIMES )
1195   add_subdirectory(runtimes)
1196 endif()
1197
1198 if( LLVM_INCLUDE_EXAMPLES )
1199   add_subdirectory(examples)
1200 endif()
1201
1202 if( LLVM_INCLUDE_TESTS )
1203   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
1204     include(LLVMExternalProjectUtils)
1205     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
1206       USE_TOOLCHAIN
1207       EXCLUDE_FROM_ALL
1208       NO_INSTALL
1209       ALWAYS_CLEAN)
1210   endif()
1211   add_subdirectory(utils/lit)
1212   add_subdirectory(test)
1213   add_subdirectory(unittests)
1214
1215   if (WIN32)
1216     # This utility is used to prevent crashing tests from calling Dr. Watson on
1217     # Windows.
1218     add_subdirectory(utils/KillTheDoctor)
1219   endif()
1220
1221   umbrella_lit_testsuite_end(check-all)
1222   get_property(LLVM_ALL_LIT_DEPENDS GLOBAL PROPERTY LLVM_ALL_LIT_DEPENDS)
1223   get_property(LLVM_ALL_ADDITIONAL_TEST_DEPENDS
1224       GLOBAL PROPERTY LLVM_ALL_ADDITIONAL_TEST_DEPENDS)
1225   add_custom_target(test-depends
1226       DEPENDS ${LLVM_ALL_LIT_DEPENDS} ${LLVM_ALL_ADDITIONAL_TEST_DEPENDS})
1227   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
1228 endif()
1229
1230 if (LLVM_INCLUDE_DOCS)
1231   add_subdirectory(docs)
1232 endif()
1233
1234 add_subdirectory(cmake/modules)
1235
1236 # Do this last so that all lit targets have already been created.
1237 if (LLVM_INCLUDE_UTILS)
1238   add_subdirectory(utils/llvm-lit)
1239 endif()
1240
1241 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1242   install(DIRECTORY include/llvm include/llvm-c
1243     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1244     COMPONENT llvm-headers
1245     FILES_MATCHING
1246     PATTERN "*.def"
1247     PATTERN "*.h"
1248     PATTERN "*.td"
1249     PATTERN "*.inc"
1250     PATTERN "LICENSE.TXT"
1251     )
1252
1253   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1254     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1255     COMPONENT llvm-headers
1256     FILES_MATCHING
1257     PATTERN "*.def"
1258     PATTERN "*.h"
1259     PATTERN "*.gen"
1260     PATTERN "*.inc"
1261     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1262     PATTERN "CMakeFiles" EXCLUDE
1263     PATTERN "config.h" EXCLUDE
1264     )
1265
1266   if (LLVM_INSTALL_MODULEMAPS)
1267     install(DIRECTORY include
1268             DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1269             COMPONENT llvm-headers
1270             FILES_MATCHING
1271             PATTERN "module.modulemap"
1272             )
1273     install(FILES include/module.install.modulemap
1274             DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1275             COMPONENT llvm-headers
1276             RENAME "module.extern.modulemap"
1277             )
1278   endif(LLVM_INSTALL_MODULEMAPS)
1279
1280   # Installing the headers needs to depend on generating any public
1281   # tablegen'd headers.
1282   add_custom_target(llvm-headers DEPENDS intrinsics_gen omp_gen)
1283   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1284
1285   if (NOT LLVM_ENABLE_IDE)
1286     add_llvm_install_targets(install-llvm-headers
1287                              DEPENDS llvm-headers
1288                              COMPONENT llvm-headers)
1289   endif()
1290
1291   # Custom target to install all libraries.
1292   add_custom_target(llvm-libraries)
1293   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1294
1295   if (NOT LLVM_ENABLE_IDE)
1296     add_llvm_install_targets(install-llvm-libraries
1297                              DEPENDS llvm-libraries
1298                              COMPONENT llvm-libraries)
1299   endif()
1300
1301   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1302   if(LLVM_LIBS)
1303     list(REMOVE_DUPLICATES LLVM_LIBS)
1304     foreach(lib ${LLVM_LIBS})
1305       add_dependencies(llvm-libraries ${lib})
1306       if (NOT LLVM_ENABLE_IDE)
1307         add_dependencies(install-llvm-libraries install-${lib})
1308         add_dependencies(install-llvm-libraries-stripped install-${lib}-stripped)
1309       endif()
1310     endforeach()
1311   endif()
1312 endif()
1313
1314 # This must be at the end of the LLVM root CMakeLists file because it must run
1315 # after all targets are created.
1316 llvm_distribution_add_targets()
1317 process_llvm_pass_plugins(GEN_CONFIG)
1318 include(CoverageReport)
1319
1320 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1321 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1322   include(InstallRequiredSystemLibraries)
1323 endif()
1324
1325 if (LLVM_INCLUDE_BENCHMARKS)
1326   # Override benchmark defaults so that when the library itself is updated these
1327   # modifications are not lost.
1328   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1329   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1330   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1331   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1332   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1333   set(BENCHMARK_ENABLE_WERROR ${LLVM_ENABLE_WERROR} CACHE BOOL
1334     "Handle -Werror for Google Benchmark based on LLVM_ENABLE_WERROR" FORCE)
1335   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1336   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1337   add_subdirectory(${LLVM_THIRD_PARTY_DIR}/benchmark
1338     ${CMAKE_CURRENT_BINARY_DIR}/third-party/benchmark)
1339   add_subdirectory(benchmarks)
1340 endif()
1341
1342 if (LLVM_INCLUDE_UTILS AND LLVM_INCLUDE_TOOLS)
1343   add_subdirectory(utils/llvm-locstats)
1344 endif()