llvm/test/Transforms/GlobalDCE/virtual-functions-relative-pointers-gep.ll

   1 ; RUN: opt < %s -passes='globaldce' -S | FileCheck %s
   2
   3 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
   4
   5 declare { i8*, i1 } @llvm.type.checked.load(i8*, i32, metadata)
   6
   7 ; A vtable with "relative pointers", slots don't contain pointers to implementations, but instead have an i32 offset from the vtable itself to the implementation.
   8 @vtable = internal unnamed_addr constant { [4 x i32] } { [4 x i32] [
   9   i32 42,
  10   i32 1337,
  11   i32 trunc (i64 sub (i64 ptrtoint (void ()* @vfunc1_live              to i64), i64 ptrtoint (i32* getelementptr inbounds ({ [4 x i32] }, { [4 x i32] }* @vtable, i32 0, i32 0, i32 2) to i64)) to i32),
  12   i32 trunc (i64 sub (i64 ptrtoint (void ()* @vfunc2_dead              to i64), i64 ptrtoint (i32* getelementptr inbounds ({ [4 x i32] }, { [4 x i32] }* @vtable, i32 0, i32 0, i32 2) to i64)) to i32)
  13 ]}, align 8, !type !0, !type !1, !vcall_visibility !{i64 2}
  14 !0 = !{i64 8, !"vfunc1.type"}
  15 !1 = !{i64 12, !"vfunc2.type"}
  16
  17 ; CHECK:      @vtable = internal unnamed_addr constant { [4 x i32] } { [4 x i32] [
  18 ; CHECK-SAME:   i32 trunc (i64 sub (i64 ptrtoint (void ()* @vfunc1_live              to i64), i64 ptrtoint (i32* getelementptr inbounds ({ [4 x i32] }, { [4 x i32] }* @vtable, i32 0, i32 0, i32 2) to i64)) to i32),
  19 ; CHECK-SAME:   i32 0
  20 ; CHECK-SAME: ] }, align 8, !type !0, !type !1, !vcall_visibility !2
  21
  22 ; (1) vfunc1_live is referenced from @main, stays alive
  23 define internal void @vfunc1_live() {
  24   ; CHECK: define internal void @vfunc1_live(
  25   ret void
  26 }
  27
  28 ; (2) vfunc2_dead is never referenced, gets removed and vtable slot is null'd
  29 define internal void @vfunc2_dead() {
  30   ; CHECK-NOT: define internal void @vfunc2_dead(
  31   ret void
  32 }
  33
  34 define void @main() {
  35   %1 = ptrtoint { [4 x i32] }* @vtable to i64 ; to keep @vtable alive
  36   %2 = tail call { i8*, i1 } @llvm.type.checked.load(i8* null, i32 0, metadata !"vfunc1.type")
  37   ret void
  38 }
  39
  40 !999 = !{i32 1, !"Virtual Function Elim", i32 1}
  41 !llvm.module.flags = !{!999}