llvm/cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckStructHasMember)
  11 include(CheckCCompilerFlag)
  12 include(CMakePushCheckState)
  13
  14 include(CheckCompilerVersion)
  15 include(HandleLLVMStdlib)
  16
  17 if( UNIX AND NOT (APPLE OR BEOS OR HAIKU) )
  18   # Used by check_symbol_exists:
  19   list(APPEND CMAKE_REQUIRED_LIBRARIES "m")
  20 endif()
  21 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  22 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  23     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  24   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  25 endif()
  26
  27 # Do checks with _XOPEN_SOURCE and large-file API on AIX, because we will build
  28 # with those too.
  29 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
  30           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_XOPEN_SOURCE=700")
  31           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_LARGE_FILE_API")
  32 endif()
  33
  34 # Do checks with _FILE_OFFSET_BITS=64 on Solaris, because we will build
  35 # with those too.
  36 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  37           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_FILE_OFFSET_BITS=64")
  38 endif()
  39
  40 # include checks
  41 check_include_file(dlfcn.h HAVE_DLFCN_H)
  42 check_include_file(errno.h HAVE_ERRNO_H)
  43 check_include_file(fcntl.h HAVE_FCNTL_H)
  44 check_include_file(link.h HAVE_LINK_H)
  45 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  46 if( NOT PURE_WINDOWS )
  47   check_include_file(pthread.h HAVE_PTHREAD_H)
  48 endif()
  49 check_include_file(signal.h HAVE_SIGNAL_H)
  50 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  51 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  52 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  53 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  54 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  55 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  56 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  57 check_include_file(sysexits.h HAVE_SYSEXITS_H)
  58 check_include_file(termios.h HAVE_TERMIOS_H)
  59 check_include_file(unistd.h HAVE_UNISTD_H)
  60 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  61 check_include_file(fenv.h HAVE_FENV_H)
  62 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  63 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  64
  65 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  66 check_include_file(histedit.h HAVE_HISTEDIT_H)
  67 check_include_file(CrashReporterClient.h HAVE_CRASHREPORTERCLIENT_H)
  68 if(APPLE)
  69   include(CheckCSourceCompiles)
  70   CHECK_C_SOURCE_COMPILES("
  71      static const char *__crashreporter_info__ = 0;
  72      asm(\".desc ___crashreporter_info__, 0x10\");
  73      int main() { return 0; }"
  74     HAVE_CRASHREPORTER_INFO)
  75 endif()
  76
  77 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  78   check_include_file(linux/magic.h HAVE_LINUX_MAGIC_H)
  79   if(NOT HAVE_LINUX_MAGIC_H)
  80     # older kernels use split files
  81     check_include_file(linux/nfs_fs.h HAVE_LINUX_NFS_FS_H)
  82     check_include_file(linux/smb.h HAVE_LINUX_SMB_H)
  83   endif()
  84 endif()
  85
  86 # library checks
  87 if( NOT PURE_WINDOWS )
  88   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  89   if (HAVE_LIBPTHREAD)
  90     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  91     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  92     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  93   else()
  94     # this could be Android
  95     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  96     if (PTHREAD_IN_LIBC)
  97       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  98       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  99       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 100     endif()
 101   endif()
 102   check_library_exists(dl dlopen "" HAVE_LIBDL)
 103   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 104 endif()
 105
 106 # Check for libpfm.
 107 include(FindLibpfm)
 108
 109 if(HAVE_LIBPTHREAD)
 110   # We want to find pthreads library and at the moment we do want to
 111   # have it reported as '-l<lib>' instead of '-pthread'.
 112   # TODO: switch to -pthread once the rest of the build system can deal with it.
 113   set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 114   set(THREADS_HAVE_PTHREAD_ARG Off)
 115   find_package(Threads REQUIRED)
 116   set(LLVM_PTHREAD_LIB ${CMAKE_THREAD_LIBS_INIT})
 117 endif()
 118
 119 if(LLVM_ENABLE_ZLIB)
 120   if(LLVM_ENABLE_ZLIB STREQUAL FORCE_ON)
 121     find_package(ZLIB REQUIRED)
 122   elseif(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 123     find_package(ZLIB)
 124   endif()
 125   if(ZLIB_FOUND)
 126     # Check if zlib we found is usable; for example, we may have found a 32-bit
 127     # library on a 64-bit system which would result in a link-time failure.
 128     cmake_push_check_state()
 129     list(APPEND CMAKE_REQUIRED_INCLUDES ${ZLIB_INCLUDE_DIRS})
 130     list(APPEND CMAKE_REQUIRED_LIBRARIES ${ZLIB_LIBRARY})
 131     check_symbol_exists(compress2 zlib.h HAVE_ZLIB)
 132     cmake_pop_check_state()
 133     if(LLVM_ENABLE_ZLIB STREQUAL FORCE_ON AND NOT HAVE_ZLIB)
 134       message(FATAL_ERROR "Failed to configure zlib")
 135     endif()
 136   endif()
 137   set(LLVM_ENABLE_ZLIB "${HAVE_ZLIB}")
 138 endif()
 139
 140 if(LLVM_ENABLE_LIBXML2)
 141   if(LLVM_ENABLE_LIBXML2 STREQUAL FORCE_ON)
 142     find_package(LibXml2 REQUIRED)
 143   elseif(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 144     find_package(LibXml2)
 145   endif()
 146   if(LibXml2_FOUND)
 147     # Check if libxml2 we found is usable; for example, we may have found a 32-bit
 148     # library on a 64-bit system which would result in a link-time failure.
 149     cmake_push_check_state()
 150     list(APPEND CMAKE_REQUIRED_INCLUDES ${LIBXML2_INCLUDE_DIRS})
 151     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBXML2_LIBRARIES})
 152     list(APPEND CMAKE_REQUIRED_DEFINITIONS ${LIBXML2_DEFINITIONS})
 153     check_symbol_exists(xmlReadMemory libxml/xmlreader.h HAVE_LIBXML2)
 154     cmake_pop_check_state()
 155     if(LLVM_ENABLE_LIBXML2 STREQUAL FORCE_ON AND NOT HAVE_LIBXML2)
 156       message(FATAL_ERROR "Failed to configure libxml2")
 157     endif()
 158   endif()
 159   set(LLVM_ENABLE_LIBXML2 "${HAVE_LIBXML2}")
 160 endif()
 161
 162 # Don't look for these libraries if we're using MSan, since uninstrumented third
 163 # party code may call MSan interceptors like strlen, leading to false positives.
 164 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 165   # Don't look for these libraries on Windows.
 166   if (NOT PURE_WINDOWS)
 167     # Skip libedit if using ASan as it contains memory leaks.
 168     if (LLVM_ENABLE_LIBEDIT AND HAVE_HISTEDIT_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*")
 169       check_library_exists(edit el_init "" HAVE_LIBEDIT)
 170     else()
 171       set(HAVE_LIBEDIT 0)
 172     endif()
 173     if(LLVM_ENABLE_TERMINFO STREQUAL FORCE_ON)
 174       set(MAYBE_REQUIRED REQUIRED)
 175     else()
 176       set(MAYBE_REQUIRED)
 177     endif()
 178     if(LLVM_ENABLE_TERMINFO)
 179       find_library(TERMINFO_LIB NAMES terminfo tinfo curses ncurses ncursesw ${MAYBE_REQUIRED})
 180     endif()
 181     if(TERMINFO_LIB)
 182       set(LLVM_ENABLE_TERMINFO 1)
 183     else()
 184       set(LLVM_ENABLE_TERMINFO 0)
 185     endif()
 186   else()
 187     set(LLVM_ENABLE_TERMINFO 0)
 188   endif()
 189 else()
 190   set(LLVM_ENABLE_TERMINFO 0)
 191 endif()
 192
 193 check_library_exists(xar xar_open "" LLVM_HAVE_LIBXAR)
 194 if(LLVM_HAVE_LIBXAR)
 195   set(XAR_LIB xar)
 196 endif()
 197
 198 # function checks
 199 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 200 find_package(Backtrace)
 201 set(HAVE_BACKTRACE ${Backtrace_FOUND})
 202 set(BACKTRACE_HEADER ${Backtrace_HEADER})
 203
 204 # Prevent check_symbol_exists from using API that is not supported for a given
 205 # deployment target.
 206 check_c_compiler_flag("-Werror=unguarded-availability-new" "C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW")
 207 if(C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW)
 208   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unguarded-availability-new")
 209 endif()
 210
 211 # Determine whether we can register EH tables.
 212 check_symbol_exists(__register_frame "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_REGISTER_FRAME)
 213 check_symbol_exists(__deregister_frame "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_DEREGISTER_FRAME)
 214 check_symbol_exists(__unw_add_dynamic_fde "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_UNW_ADD_DYNAMIC_FDE)
 215
 216 check_symbol_exists(_Unwind_Backtrace "unwind.h" HAVE__UNWIND_BACKTRACE)
 217 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 218 check_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
 219 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 220 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 221 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 222 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 223 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 224 check_symbol_exists(posix_fallocate fcntl.h HAVE_POSIX_FALLOCATE)
 225 # AddressSanitizer conflicts with lib/Support/Unix/Signals.inc
 226 # Avoid sigaltstack on Apple platforms, where backtrace() cannot handle it
 227 # (rdar://7089625) and _Unwind_Backtrace is unusable because it cannot unwind
 228 # past the signal handler after an assertion failure (rdar://29866587).
 229 if( HAVE_SIGNAL_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*" AND NOT APPLE )
 230   check_symbol_exists(sigaltstack signal.h HAVE_SIGALTSTACK)
 231 endif()
 232 set(CMAKE_REQUIRED_DEFINITIONS "-D_LARGEFILE64_SOURCE")
 233 check_symbol_exists(lseek64 "sys/types.h;unistd.h" HAVE_LSEEK64)
 234 set(CMAKE_REQUIRED_DEFINITIONS "")
 235 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 236 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 237 check_symbol_exists(mallinfo2 malloc.h HAVE_MALLINFO2)
 238 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 239                     HAVE_MALLOC_ZONE_STATISTICS)
 240 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 241 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 242 check_symbol_exists(pread unistd.h HAVE_PREAD)
 243 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 244 check_symbol_exists(strerror string.h HAVE_STRERROR)
 245 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 246 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 247 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 248 if( PURE_WINDOWS )
 249   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 250
 251   check_function_exists(_alloca HAVE__ALLOCA)
 252   check_function_exists(__alloca HAVE___ALLOCA)
 253   check_function_exists(__chkstk HAVE___CHKSTK)
 254   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 255   check_function_exists(___chkstk HAVE____CHKSTK)
 256   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 257
 258   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 259   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 260   check_function_exists(__divdi3 HAVE___DIVDI3)
 261   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 262   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 263   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 264   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 265   check_function_exists(__moddi3 HAVE___MODDI3)
 266   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 267   check_function_exists(__umoddi3 HAVE___UMODDI3)
 268
 269   check_function_exists(__main HAVE___MAIN)
 270   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 271 endif()
 272 if( HAVE_DLFCN_H )
 273   if( HAVE_LIBDL )
 274     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 275   endif()
 276   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 277   check_symbol_exists(dladdr dlfcn.h HAVE_DLADDR)
 278   if( HAVE_LIBDL )
 279     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 280   endif()
 281 endif()
 282
 283 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
 284     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
 285 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 286 # The st_mtim.tv_nsec member of a `stat` structure is not reliable on some AIX
 287 # environments.
 288   set(HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC 0)
 289 else()
 290   CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
 291       "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
 292 endif()
 293
 294 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 295 if( LLVM_USING_GLIBC )
 296   add_definitions( -D_GNU_SOURCE )
 297   list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 298 endif()
 299 # This check requires _GNU_SOURCE
 300 if (NOT PURE_WINDOWS)
 301   if (LLVM_PTHREAD_LIB)
 302     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 303   endif()
 304   check_symbol_exists(pthread_getname_np pthread.h HAVE_PTHREAD_GETNAME_NP)
 305   check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 306   if (LLVM_PTHREAD_LIB)
 307     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 308   endif()
 309 endif()
 310
 311 # available programs checks
 312 function(llvm_find_program name)
 313   string(TOUPPER ${name} NAME)
 314   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 315
 316   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 317   mark_as_advanced(LLVM_PATH_${NAME})
 318   if(LLVM_PATH_${NAME})
 319     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 320     mark_as_advanced(HAVE_${NAME})
 321   else(LLVM_PATH_${NAME})
 322     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 323   endif(LLVM_PATH_${NAME})
 324 endfunction()
 325
 326 if (LLVM_ENABLE_DOXYGEN)
 327   llvm_find_program(dot)
 328 endif ()
 329
 330 if( LLVM_ENABLE_FFI )
 331   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 332   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 333     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 334     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 335   else()
 336     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 337     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 338       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 339       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 340     endif()
 341   endif()
 342
 343   if( NOT FFI_HEADER )
 344     message(FATAL_ERROR "libffi includes are not found.")
 345   endif()
 346
 347   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 348   if( NOT FFI_LIBRARY_PATH )
 349     message(FATAL_ERROR "libffi is not found.")
 350   endif()
 351
 352   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 353   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 354   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 355   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 356   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 357 else()
 358   unset(HAVE_FFI_FFI_H CACHE)
 359   unset(HAVE_FFI_H CACHE)
 360   unset(HAVE_FFI_CALL CACHE)
 361 endif( LLVM_ENABLE_FFI )
 362
 363 check_symbol_exists(proc_pid_rusage "libproc.h" HAVE_PROC_PID_RUSAGE)
 364
 365 # Whether we can use std::is_trivially_copyable to verify llvm::is_trivially_copyable.
 366 CHECK_CXX_SOURCE_COMPILES("
 367 #include <type_traits>
 368 struct T { int val; };
 369 static_assert(std::is_trivially_copyable<T>::value, \"ok\");
 370 int main() { return 0;}
 371 " HAVE_STD_IS_TRIVIALLY_COPYABLE)
 372
 373
 374 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 375 include(CheckAtomic)
 376
 377 if( LLVM_ENABLE_PIC )
 378   set(ENABLE_PIC 1)
 379 else()
 380   set(ENABLE_PIC 0)
 381   check_cxx_compiler_flag("-fno-pie" SUPPORTS_NO_PIE_FLAG)
 382   if(SUPPORTS_NO_PIE_FLAG)
 383     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fno-pie")
 384   endif()
 385 endif()
 386
 387 check_cxx_compiler_flag("-Wvariadic-macros" SUPPORTS_VARIADIC_MACROS_FLAG)
 388 check_cxx_compiler_flag("-Wgnu-zero-variadic-macro-arguments"
 389                         SUPPORTS_GNU_ZERO_VARIADIC_MACRO_ARGUMENTS_FLAG)
 390
 391 set(USE_NO_MAYBE_UNINITIALIZED 0)
 392 set(USE_NO_UNINITIALIZED 0)
 393
 394 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 395 # false positives.
 396 if (CMAKE_COMPILER_IS_GNUCXX)
 397   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 398   if (HAS_MAYBE_UNINITIALIZED)
 399     set(USE_NO_MAYBE_UNINITIALIZED 1)
 400   else()
 401     # Only recent versions of gcc make the distinction between -Wuninitialized
 402     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 403     # turn off all uninitialized use warnings.
 404     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 405     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 406   endif()
 407 endif()
 408
 409 # By default, we target the host, but this can be overridden at CMake
 410 # invocation time.
 411 include(GetHostTriple)
 412 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 413
 414 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 415     "Host on which LLVM binaries will run")
 416
 417 # Determine the native architecture.
 418 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 419 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 420   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 421 endif ()
 422
 423 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 424   set(LLVM_NATIVE_ARCH X86)
 425 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 426   set(LLVM_NATIVE_ARCH X86)
 427 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 428   set(LLVM_NATIVE_ARCH X86)
 429 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 430   set(LLVM_NATIVE_ARCH X86)
 431 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 432   set(LLVM_NATIVE_ARCH Sparc)
 433 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 434   set(LLVM_NATIVE_ARCH PowerPC)
 435 elseif (LLVM_NATIVE_ARCH MATCHES "ppc64le")
 436   set(LLVM_NATIVE_ARCH PowerPC)
 437 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 438   set(LLVM_NATIVE_ARCH AArch64)
 439 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 440   set(LLVM_NATIVE_ARCH AArch64)
 441 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 442   set(LLVM_NATIVE_ARCH ARM)
 443 elseif (LLVM_NATIVE_ARCH MATCHES "avr")
 444   set(LLVM_NATIVE_ARCH AVR)
 445 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 446   set(LLVM_NATIVE_ARCH Mips)
 447 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 448   set(LLVM_NATIVE_ARCH XCore)
 449 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 450   set(LLVM_NATIVE_ARCH MSP430)
 451 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 452   set(LLVM_NATIVE_ARCH Hexagon)
 453 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 454   set(LLVM_NATIVE_ARCH SystemZ)
 455 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 456   set(LLVM_NATIVE_ARCH WebAssembly)
 457 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 458   set(LLVM_NATIVE_ARCH WebAssembly)
 459 elseif (LLVM_NATIVE_ARCH MATCHES "riscv32")
 460   set(LLVM_NATIVE_ARCH RISCV)
 461 elseif (LLVM_NATIVE_ARCH MATCHES "riscv64")
 462   set(LLVM_NATIVE_ARCH RISCV)
 463 elseif (LLVM_NATIVE_ARCH STREQUAL "m68k")
 464   set(LLVM_NATIVE_ARCH M68k)
 465 else ()
 466   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 467 endif ()
 468
 469 # If build targets includes "host" or "Native", then replace with native architecture.
 470 foreach (NATIVE_KEYWORD host Native)
 471   list(FIND LLVM_TARGETS_TO_BUILD ${NATIVE_KEYWORD} idx)
 472   if( NOT idx LESS 0 )
 473     list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 474     list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 475     list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 476   endif()
 477 endforeach()
 478
 479 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 480 if (NATIVE_ARCH_IDX EQUAL -1)
 481   message(STATUS
 482     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 483 else ()
 484   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 485   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 486   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 487   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 488   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 489
 490   # We don't have an ASM parser for all architectures yet.
 491   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 492     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 493   endif ()
 494
 495   # We don't have an disassembler for all architectures yet.
 496   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 497     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 498   endif ()
 499 endif ()
 500
 501 if( MSVC )
 502   set(SHLIBEXT ".lib")
 503   set(stricmp "_stricmp")
 504   set(strdup "_strdup")
 505
 506   # See if the DIA SDK is available and usable.
 507   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK" CACHE PATH
 508       "Path to the DIA SDK")
 509
 510   # Due to a bug in MSVC 2013's installation software, it is possible
 511   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 512   # install directory.  If this happens, the installation is corrupt
 513   # and there's nothing we can do.  It happens with enough frequency
 514   # though that we should handle it.  We do so by simply checking that
 515   # the DIA SDK folder exists.  Should this happen you will need to
 516   # uninstall VS 2012 and then re-install VS 2013.
 517   if (IS_DIRECTORY "${MSVC_DIA_SDK_DIR}")
 518     set(HAVE_DIA_SDK 1)
 519   else()
 520     set(HAVE_DIA_SDK 0)
 521   endif()
 522
 523   option(LLVM_ENABLE_DIA_SDK "Use MSVC DIA SDK for debugging if available."
 524                              ${HAVE_DIA_SDK})
 525
 526   if(LLVM_ENABLE_DIA_SDK AND NOT HAVE_DIA_SDK)
 527     message(FATAL_ERROR "DIA SDK not found. If you have both VS 2012 and 2013 installed, you may need to uninstall the former and re-install the latter afterwards.")
 528   endif()
 529 else()
 530   set(LLVM_ENABLE_DIA_SDK 0)
 531 endif( MSVC )
 532
 533 # FIXME: Signal handler return type, currently hardcoded to 'void'
 534 set(RETSIGTYPE void)
 535
 536 if( LLVM_ENABLE_THREADS )
 537   # Check if threading primitives aren't supported on this platform
 538   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 539     set(LLVM_ENABLE_THREADS 0)
 540   endif()
 541 endif()
 542
 543 if( LLVM_ENABLE_THREADS )
 544   message(STATUS "Threads enabled.")
 545 else( LLVM_ENABLE_THREADS )
 546   message(STATUS "Threads disabled.")
 547 endif()
 548
 549 if (LLVM_ENABLE_DOXYGEN)
 550   message(STATUS "Doxygen enabled.")
 551   find_package(Doxygen REQUIRED)
 552
 553   if (DOXYGEN_FOUND)
 554     # If we find doxygen and we want to enable doxygen by default create a
 555     # global aggregate doxygen target for generating llvm and any/all
 556     # subprojects doxygen documentation.
 557     if (LLVM_BUILD_DOCS)
 558       add_custom_target(doxygen ALL)
 559     endif()
 560
 561     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 562     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 563       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 564       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 565     endif()
 566   endif()
 567 else()
 568   message(STATUS "Doxygen disabled.")
 569 endif()
 570
 571 set(LLVM_BINDINGS "")
 572 find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 573 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 574   message(STATUS "Go bindings disabled.")
 575 else()
 576   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 577     message(STATUS "Go bindings disabled.")
 578   else()
 579     execute_process(COMMAND ${GO_EXECUTABLE} run ${PROJECT_SOURCE_DIR}/bindings/go/conftest.go
 580                     RESULT_VARIABLE GO_CONFTEST)
 581     if(GO_CONFTEST STREQUAL "0")
 582       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 583       message(STATUS "Go bindings enabled.")
 584     else()
 585       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 586     endif()
 587   endif()
 588 endif()
 589
 590 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 591 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 592         "PATH to binutils/include containing plugin-api.h for gold plugin.")
 593
 594 if(CMAKE_GENERATOR STREQUAL "Ninja")
 595   execute_process(COMMAND ${CMAKE_MAKE_PROGRAM} --version
 596     OUTPUT_VARIABLE NINJA_VERSION
 597     OUTPUT_STRIP_TRAILING_WHITESPACE)
 598   set(NINJA_VERSION ${NINJA_VERSION} CACHE STRING "Ninja version number" FORCE)
 599   message(STATUS "Ninja version: ${NINJA_VERSION}")
 600 endif()
 601
 602 if(CMAKE_GENERATOR STREQUAL "Ninja" AND
 603     NOT "${NINJA_VERSION}" VERSION_LESS "1.9.0" AND
 604     CMAKE_HOST_APPLE AND CMAKE_HOST_SYSTEM_VERSION VERSION_GREATER "15.6.0")
 605   set(LLVM_TOUCH_STATIC_LIBRARIES ON)
 606 endif()
 607
 608 if(CMAKE_HOST_APPLE AND APPLE)
 609   if(NOT CMAKE_XCRUN)
 610     find_program(CMAKE_XCRUN NAMES xcrun)
 611   endif()
 612   if(CMAKE_XCRUN)
 613     execute_process(COMMAND ${CMAKE_XCRUN} -find ld
 614       OUTPUT_VARIABLE LD64_EXECUTABLE
 615       OUTPUT_STRIP_TRAILING_WHITESPACE)
 616   else()
 617     find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 618   endif()
 619
 620   if(LD64_EXECUTABLE)
 621     set(LD64_EXECUTABLE ${LD64_EXECUTABLE} CACHE PATH "ld64 executable")
 622     message(STATUS "Found ld64 - ${LD64_EXECUTABLE}")
 623   endif()
 624 endif()
 625
 626 # Keep the version requirements in sync with bindings/ocaml/README.txt.
 627 include(FindOCaml)
 628 include(AddOCaml)
 629 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 630   message(STATUS "OCaml bindings disabled.")
 631 else()
 632   find_package(OCaml)
 633   if( NOT OCAML_FOUND )
 634     message(STATUS "OCaml bindings disabled.")
 635   else()
 636     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 637       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 638     else()
 639       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 640       if( HAVE_OCAML_CTYPES )
 641         message(STATUS "OCaml bindings enabled.")
 642         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
 643         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 644
 645         set(LLVM_OCAML_INSTALL_PATH "${OCAML_STDLIB_PATH}" CACHE STRING
 646             "Install directory for LLVM OCaml packages")
 647       else()
 648         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 649       endif()
 650     endif()
 651   endif()
 652 endif()
 653
 654 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")
 655
 656 function(find_python_module module)
 657   string(REPLACE "." "_" module_name ${module})
 658   string(TOUPPER ${module_name} module_upper)
 659   set(FOUND_VAR PY_${module_upper}_FOUND)
 660   if (DEFINED ${FOUND_VAR})
 661     return()
 662   endif()
 663
 664   execute_process(COMMAND "${Python3_EXECUTABLE}" "-c" "import ${module}"
 665     RESULT_VARIABLE status
 666     ERROR_QUIET)
 667
 668   if(status)
 669     set(${FOUND_VAR} OFF CACHE BOOL "Failed to find python module '${module}'")
 670     message(STATUS "Could NOT find Python module ${module}")
 671   else()
 672   set(${FOUND_VAR} ON CACHE BOOL "Found python module '${module}'")
 673     message(STATUS "Found Python module ${module}")
 674   endif()
 675 endfunction()
 676
 677 set (PYTHON_MODULES
 678   pygments
 679   # Some systems still don't have pygments.lexers.c_cpp which was introduced in
 680   # version 2.0 in 2014...
 681   pygments.lexers.c_cpp
 682   yaml
 683   )
 684 foreach(module ${PYTHON_MODULES})
 685   find_python_module(${module})
 686 endforeach()
 687
 688 if(PY_PYGMENTS_FOUND AND PY_PYGMENTS_LEXERS_C_CPP_FOUND AND PY_YAML_FOUND)
 689   set (LLVM_HAVE_OPT_VIEWER_MODULES 1)
 690 else()
 691   set (LLVM_HAVE_OPT_VIEWER_MODULES 0)
 692 endif()
 693
 694 function(llvm_get_host_prefixes_and_suffixes)
 695   # Not all platform files will set these variables (relying on them being
 696   # implicitly empty if they're unset), so unset the variables before including
 697   # the platform file, to prevent any values from the target system leaking.
 698   unset(CMAKE_STATIC_LIBRARY_PREFIX)
 699   unset(CMAKE_STATIC_LIBRARY_SUFFIX)
 700   unset(CMAKE_SHARED_LIBRARY_PREFIX)
 701   unset(CMAKE_SHARED_LIBRARY_SUFFIX)
 702   unset(CMAKE_IMPORT_LIBRARY_PREFIX)
 703   unset(CMAKE_IMPORT_LIBRARY_SUFFIX)
 704   unset(CMAKE_EXECUTABLE_SUFFIX)
 705   unset(CMAKE_LINK_LIBRARY_SUFFIX)
 706   include(Platform/${CMAKE_HOST_SYSTEM_NAME} OPTIONAL RESULT_VARIABLE _includedFile)
 707   if (_includedFile)
 708     set(LLVM_HOST_STATIC_LIBRARY_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX} PARENT_SCOPE)
 709     set(LLVM_HOST_STATIC_LIBRARY_SUFFIX ${CMAKE_STATIC_LIBRARY_SUFFIX} PARENT_SCOPE)
 710     set(LLVM_HOST_SHARED_LIBRARY_PREFIX ${CMAKE_SHARED_LIBRARY_PREFIX} PARENT_SCOPE)
 711     set(LLVM_HOST_SHARED_LIBRARY_SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX} PARENT_SCOPE)
 712     set(LLVM_HOST_IMPORT_LIBRARY_PREFIX ${CMAKE_IMPORT_LIBRARY_PREFIX} PARENT_SCOPE)
 713     set(LLVM_HOST_IMPORT_LIBRARY_SUFFIX ${CMAKE_IMPORT_LIBRARY_SUFFIX} PARENT_SCOPE)
 714     set(LLVM_HOST_EXECUTABLE_SUFFIX ${CMAKE_EXECUTABLE_SUFFIX} PARENT_SCOPE)
 715     set(LLVM_HOST_LINK_LIBRARY_SUFFIX ${CMAKE_LINK_LIBRARY_SUFFIX} PARENT_SCOPE)
 716   endif()
 717 endfunction()
 718
 719 llvm_get_host_prefixes_and_suffixes()