llvm/test/Transforms/FunctionAttrs/nocapture.ll

   1 ; RUN: opt -function-attrs -S < %s | FileCheck %s --check-prefixes=FNATTR
   2 ; RUN: opt -passes=function-attrs -S < %s | FileCheck %s --check-prefixes=FNATTR
   3
   4 @g = global i32* null           ; <i32**> [#uses=1]
   5
   6 ; FNATTR: define i32* @c1(i32* readnone returned %q)
   7 define i32* @c1(i32* %q) {
   8         ret i32* %q
   9 }
  10
  11 ; FNATTR: define void @c2(i32* %q)
  12 ; It would also be acceptable to mark %q as readnone. Update @c3 too.
  13 define void @c2(i32* %q) {
  14         store i32* %q, i32** @g
  15         ret void
  16 }
  17
  18 ; FNATTR: define void @c3(i32* %q)
  19 define void @c3(i32* %q) {
  20         call void @c2(i32* %q)
  21         ret void
  22 }
  23
  24 ; FNATTR: define i1 @c4(i32* %q, i32 %bitno)
  25 define i1 @c4(i32* %q, i32 %bitno) {
  26         %tmp = ptrtoint i32* %q to i32
  27         %tmp2 = lshr i32 %tmp, %bitno
  28         %bit = trunc i32 %tmp2 to i1
  29         br i1 %bit, label %l1, label %l0
  30 l0:
  31         ret i1 0 ; escaping value not caught by def-use chaining.
  32 l1:
  33         ret i1 1 ; escaping value not caught by def-use chaining.
  34 }
  35
  36 ; c4b is c4 but without the escaping part
  37 ; FNATTR: define i1 @c4b(i32* %q, i32 %bitno)
  38 define i1 @c4b(i32* %q, i32 %bitno) {
  39         %tmp = ptrtoint i32* %q to i32
  40         %tmp2 = lshr i32 %tmp, %bitno
  41         %bit = trunc i32 %tmp2 to i1
  42         br i1 %bit, label %l1, label %l0
  43 l0:
  44         ret i1 0 ; not escaping!
  45 l1:
  46         ret i1 0 ; not escaping!
  47 }
  48
  49 @lookup_table = global [2 x i1] [ i1 0, i1 1 ]
  50
  51 ; FNATTR: define i1 @c5(i32* %q, i32 %bitno)
  52 define i1 @c5(i32* %q, i32 %bitno) {
  53         %tmp = ptrtoint i32* %q to i32
  54         %tmp2 = lshr i32 %tmp, %bitno
  55         %bit = and i32 %tmp2, 1
  56         ; subtle escape mechanism follows
  57         %lookup = getelementptr [2 x i1], [2 x i1]* @lookup_table, i32 0, i32 %bit
  58         %val = load i1, i1* %lookup
  59         ret i1 %val
  60 }
  61
  62 declare void @throw_if_bit_set(i8*, i8) readonly
  63
  64 ; FNATTR: define i1 @c6(i8* readonly %q, i8 %bit)
  65 define i1 @c6(i8* %q, i8 %bit) personality i32 (...)* @__gxx_personality_v0 {
  66         invoke void @throw_if_bit_set(i8* %q, i8 %bit)
  67                 to label %ret0 unwind label %ret1
  68 ret0:
  69         ret i1 0
  70 ret1:
  71         %exn = landingpad {i8*, i32}
  72                  cleanup
  73         ret i1 1
  74 }
  75
  76 declare i32 @__gxx_personality_v0(...)
  77
  78 define i1* @lookup_bit(i32* %q, i32 %bitno) readnone nounwind {
  79         %tmp = ptrtoint i32* %q to i32
  80         %tmp2 = lshr i32 %tmp, %bitno
  81         %bit = and i32 %tmp2, 1
  82         %lookup = getelementptr [2 x i1], [2 x i1]* @lookup_table, i32 0, i32 %bit
  83         ret i1* %lookup
  84 }
  85
  86 ; FNATTR: define i1 @c7(i32* readonly %q, i32 %bitno)
  87 define i1 @c7(i32* %q, i32 %bitno) {
  88         %ptr = call i1* @lookup_bit(i32* %q, i32 %bitno)
  89         %val = load i1, i1* %ptr
  90         ret i1 %val
  91 }
  92
  93
  94 ; FNATTR: define i32 @nc1(i32* %q, i32* nocapture %p, i1 %b)
  95 define i32 @nc1(i32* %q, i32* %p, i1 %b) {
  96 e:
  97         br label %l
  98 l:
  99         %x = phi i32* [ %p, %e ]
 100         %y = phi i32* [ %q, %e ]
 101         %tmp = bitcast i32* %x to i32*          ; <i32*> [#uses=2]
 102         %tmp2 = select i1 %b, i32* %tmp, i32* %y
 103         %val = load i32, i32* %tmp2             ; <i32> [#uses=1]
 104         store i32 0, i32* %tmp
 105         store i32* %y, i32** @g
 106         ret i32 %val
 107 }
 108
 109 ; FNATTR: define i32 @nc1_addrspace(i32* %q, i32 addrspace(1)* nocapture %p, i1 %b)
 110 define i32 @nc1_addrspace(i32* %q, i32 addrspace(1)* %p, i1 %b) {
 111 e:
 112         br label %l
 113 l:
 114         %x = phi i32 addrspace(1)* [ %p, %e ]
 115         %y = phi i32* [ %q, %e ]
 116         %tmp = addrspacecast i32 addrspace(1)* %x to i32*               ; <i32*> [#uses=2]
 117         %tmp2 = select i1 %b, i32* %tmp, i32* %y
 118         %val = load i32, i32* %tmp2             ; <i32> [#uses=1]
 119         store i32 0, i32* %tmp
 120         store i32* %y, i32** @g
 121         ret i32 %val
 122 }
 123
 124 ; FNATTR: define void @nc2(i32* nocapture %p, i32* %q)
 125 define void @nc2(i32* %p, i32* %q) {
 126         %1 = call i32 @nc1(i32* %q, i32* %p, i1 0)              ; <i32> [#uses=0]
 127         ret void
 128 }
 129
 130
 131 ; FNATTR: define void @nc3(void ()* nocapture %p)
 132 define void @nc3(void ()* %p) {
 133         call void %p()
 134         ret void
 135 }
 136
 137 declare void @external(i8*) readonly nounwind
 138 ; FNATTR: define void @nc4(i8* nocapture readonly %p)
 139 define void @nc4(i8* %p) {
 140         call void @external(i8* %p)
 141         ret void
 142 }
 143
 144 ; FNATTR: define void @nc5(void (i8*)* nocapture %f, i8* nocapture %p)
 145 define void @nc5(void (i8*)* %f, i8* %p) {
 146         call void %f(i8* %p) readonly nounwind
 147         call void %f(i8* nocapture %p)
 148         ret void
 149 }
 150
 151 ; FNATTR:     define void @test1_1(i8* nocapture readnone %x1_1, i8* %y1_1, i1 %c)
 152 ; It would be acceptable to add readnone to %y1_1 and %y1_2.
 153 define void @test1_1(i8* %x1_1, i8* %y1_1, i1 %c) {
 154   call i8* @test1_2(i8* %x1_1, i8* %y1_1, i1 %c)
 155   store i32* null, i32** @g
 156   ret void
 157 }
 158
 159 ; FNATTR: define i8* @test1_2(i8* nocapture readnone %x1_2, i8* returned %y1_2, i1 %c)
 160 define i8* @test1_2(i8* %x1_2, i8* %y1_2, i1 %c) {
 161   br i1 %c, label %t, label %f
 162 t:
 163   call void @test1_1(i8* %x1_2, i8* %y1_2, i1 %c)
 164   store i32* null, i32** @g
 165   br label %f
 166 f:
 167   ret i8* %y1_2
 168 }
 169
 170 ; FNATTR: define void @test2(i8* nocapture readnone %x2)
 171 define void @test2(i8* %x2) {
 172   call void @test2(i8* %x2)
 173   store i32* null, i32** @g
 174   ret void
 175 }
 176
 177 ; FNATTR: define void @test3(i8* nocapture readnone %x3, i8* nocapture readnone %y3, i8* nocapture readnone %z3)
 178 define void @test3(i8* %x3, i8* %y3, i8* %z3) {
 179   call void @test3(i8* %z3, i8* %y3, i8* %x3)
 180   store i32* null, i32** @g
 181   ret void
 182 }
 183
 184 ; FNATTR: define void @test4_1(i8* %x4_1, i1 %c)
 185 define void @test4_1(i8* %x4_1, i1 %c) {
 186   call i8* @test4_2(i8* %x4_1, i8* %x4_1, i8* %x4_1, i1 %c)
 187   store i32* null, i32** @g
 188   ret void
 189 }
 190
 191 ; FNATTR: define i8* @test4_2(i8* nocapture readnone %x4_2, i8* readnone returned %y4_2, i8* nocapture readnone %z4_2, i1 %c)
 192 define i8* @test4_2(i8* %x4_2, i8* %y4_2, i8* %z4_2, i1 %c) {
 193   br i1 %c, label %t, label %f
 194 t:
 195   call void @test4_1(i8* null, i1 %c)
 196   store i32* null, i32** @g
 197   br label %f
 198 f:
 199   ret i8* %y4_2
 200 }
 201
 202 declare i8* @test5_1(i8* %x5_1)
 203
 204 ; FNATTR: define void @test5_2(i8* %x5_2)
 205 define void @test5_2(i8* %x5_2) {
 206   call i8* @test5_1(i8* %x5_2)
 207   store i32* null, i32** @g
 208   ret void
 209 }
 210
 211 declare void @test6_1(i8* %x6_1, i8* nocapture %y6_1, ...)
 212
 213 ; FNATTR: define void @test6_2(i8* %x6_2, i8* nocapture %y6_2, i8* %z6_2)
 214 define void @test6_2(i8* %x6_2, i8* %y6_2, i8* %z6_2) {
 215   call void (i8*, i8*, ...) @test6_1(i8* %x6_2, i8* %y6_2, i8* %z6_2)
 216   store i32* null, i32** @g
 217   ret void
 218 }
 219
 220 ; FNATTR: define void @test_cmpxchg(i32* nocapture %p)
 221 define void @test_cmpxchg(i32* %p) {
 222   cmpxchg i32* %p, i32 0, i32 1 acquire monotonic
 223   ret void
 224 }
 225
 226 ; FNATTR: define void @test_cmpxchg_ptr(i32** nocapture %p, i32* %q)
 227 define void @test_cmpxchg_ptr(i32** %p, i32* %q) {
 228   cmpxchg i32** %p, i32* null, i32* %q acquire monotonic
 229   ret void
 230 }
 231
 232 ; FNATTR: define void @test_atomicrmw(i32* nocapture %p)
 233 define void @test_atomicrmw(i32* %p) {
 234   atomicrmw add i32* %p, i32 1 seq_cst
 235   ret void
 236 }
 237
 238 ; FNATTR: define void @test_volatile(i32* %x)
 239 define void @test_volatile(i32* %x) {
 240 entry:
 241   %gep = getelementptr i32, i32* %x, i64 1
 242   store volatile i32 0, i32* %gep, align 4
 243   ret void
 244 }
 245
 246 ; FNATTR: nocaptureLaunder(i8* nocapture %p)
 247 define void @nocaptureLaunder(i8* %p) {
 248 entry:
 249   %b = call i8* @llvm.launder.invariant.group.p0i8(i8* %p)
 250   store i8 42, i8* %b
 251   ret void
 252 }
 253
 254 @g2 = global i8* null
 255 ; FNATTR: define void @captureLaunder(i8* %p)
 256 define void @captureLaunder(i8* %p) {
 257   %b = call i8* @llvm.launder.invariant.group.p0i8(i8* %p)
 258   store i8* %b, i8** @g2
 259   ret void
 260 }
 261
 262 ; FNATTR: @nocaptureStrip(i8* nocapture %p)
 263 define void @nocaptureStrip(i8* %p) {
 264 entry:
 265   %b = call i8* @llvm.strip.invariant.group.p0i8(i8* %p)
 266   store i8 42, i8* %b
 267   ret void
 268 }
 269
 270 @g3 = global i8* null
 271 ; FNATTR: define void @captureStrip(i8* %p)
 272 define void @captureStrip(i8* %p) {
 273   %b = call i8* @llvm.strip.invariant.group.p0i8(i8* %p)
 274   store i8* %b, i8** @g3
 275   ret void
 276 }
 277
 278 ; FNATTR: define i1 @captureICmp(i32* readnone %x)
 279 define i1 @captureICmp(i32* %x) {
 280   %1 = icmp eq i32* %x, null
 281   ret i1 %1
 282 }
 283
 284 ; FNATTR: define i1 @captureICmpRev(i32* readnone %x)
 285 define i1 @captureICmpRev(i32* %x) {
 286   %1 = icmp eq i32* null, %x
 287   ret i1 %1
 288 }
 289
 290 ; FNATTR: define i1 @nocaptureInboundsGEPICmp(i32* nocapture readnone %x)
 291 define i1 @nocaptureInboundsGEPICmp(i32* %x) {
 292   %1 = getelementptr inbounds i32, i32* %x, i32 5
 293   %2 = bitcast i32* %1 to i8*
 294   %3 = icmp eq i8* %2, null
 295   ret i1 %3
 296 }
 297
 298 ; FNATTR: define i1 @nocaptureInboundsGEPICmpRev(i32* nocapture readnone %x)
 299 define i1 @nocaptureInboundsGEPICmpRev(i32* %x) {
 300   %1 = getelementptr inbounds i32, i32* %x, i32 5
 301   %2 = bitcast i32* %1 to i8*
 302   %3 = icmp eq i8* null, %2
 303   ret i1 %3
 304 }
 305
 306 ; FNATTR: define i1 @nocaptureDereferenceableOrNullICmp(i32* nocapture readnone dereferenceable_or_null(4) %x)
 307 define i1 @nocaptureDereferenceableOrNullICmp(i32* dereferenceable_or_null(4) %x) {
 308   %1 = bitcast i32* %x to i8*
 309   %2 = icmp eq i8* %1, null
 310   ret i1 %2
 311 }
 312
 313 ; FNATTR: define i1 @captureDereferenceableOrNullICmp(i32* readnone dereferenceable_or_null(4) %x)
 314 define i1 @captureDereferenceableOrNullICmp(i32* dereferenceable_or_null(4) %x) null_pointer_is_valid {
 315   %1 = bitcast i32* %x to i8*
 316   %2 = icmp eq i8* %1, null
 317   ret i1 %2
 318 }
 319
 320 declare i8* @llvm.launder.invariant.group.p0i8(i8*)
 321 declare i8* @llvm.strip.invariant.group.p0i8(i8*)