llvm/test/Transforms/LoopUnroll/full-unroll-heuristics-dce.ll

   1 ; RUN: opt < %s -S -loop-unroll -unroll-max-iteration-count-to-analyze=100 -unroll-threshold=12 -unroll-max-percent-threshold-boost=400 | FileCheck %s
   2 ; RUN: opt < %s -S -passes='require<opt-remark-emit>,loop(loop-unroll-full)' -unroll-max-iteration-count-to-analyze=100 -unroll-threshold=12 -unroll-max-percent-threshold-boost=400 | FileCheck %s
   3 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
   4
   5 @known_constant = internal unnamed_addr constant [10 x i32] [i32 0, i32 0, i32 0, i32 0, i32 1, i32 0, i32 0, i32 0, i32 0, i32 0], align 16
   6
   7 ; If a load becomes a constant after loop unrolling, we sometimes can simplify
   8 ; CFG. This test verifies that we handle such cases.
   9 ; After one operand in an instruction is constant-folded and the
  10 ; instruction is simplified, the other operand might become dead.
  11 ; In this test we have::
  12 ; for i in 1..10:
  13 ;   r += A[i] * B[i]
  14 ; A[i] is 0 almost at every iteration, so there is no need in loading B[i] at
  15 ; all.
  16
  17
  18 ; CHECK-LABEL: @unroll_dce
  19 ; CHECK-NOT:   br i1 %exitcond, label %for.end, label %for.body
  20 define i32 @unroll_dce(i32* noalias nocapture readonly %b) {
  21 entry:
  22   br label %for.body
  23
  24 for.body:                                         ; preds = %for.body, %entry
  25   %iv.0 = phi i64 [ 0, %entry ], [ %iv.1, %for.body ]
  26   %r.0 = phi i32 [ 0, %entry ], [ %r.1, %for.body ]
  27   %arrayidx1 = getelementptr inbounds [10 x i32], [10 x i32]* @known_constant, i64 0, i64 %iv.0
  28   %x1 = load i32, i32* %arrayidx1, align 4
  29   %arrayidx2 = getelementptr inbounds i32, i32* %b, i64 %iv.0
  30   %x2 = load i32, i32* %arrayidx2, align 4
  31   %mul = mul i32 %x1, %x2
  32   %r.1 = add i32 %mul, %r.0
  33   %iv.1 = add nuw nsw i64 %iv.0, 1
  34   %exitcond = icmp eq i64 %iv.1, 10
  35   br i1 %exitcond, label %for.end, label %for.body
  36
  37 for.end:                                          ; preds = %for.body
  38   ret i32 %r.1
  39 }