llvm/test/Transforms/Coroutines/coro-split-01.ll

   1 ; Tests that a coroutine is split, inlined into the caller and devirtualized.
   2 ; RUN: opt < %s -S -passes='default<O2>' | FileCheck %s
   3
   4 define ptr @f() presplitcoroutine {
   5 entry:
   6   %id = call token @llvm.coro.id(i32 0, ptr null, ptr null, ptr null)
   7   %need.dyn.alloc = call i1 @llvm.coro.alloc(token %id)
   8   br i1 %need.dyn.alloc, label %dyn.alloc, label %coro.begin
   9 dyn.alloc:
  10   %size = call i32 @llvm.coro.size.i32()
  11   %alloc = call ptr @malloc(i32 %size)
  12   br label %coro.begin
  13 coro.begin:
  14   %phi = phi ptr [ null, %entry ], [ %alloc, %dyn.alloc ]
  15   %hdl = call ptr @llvm.coro.begin(token %id, ptr %phi)
  16   call void @print(i32 0)
  17   %0 = call i8 @llvm.coro.suspend(token none, i1 false)
  18   switch i8 %0, label %suspend [i8 0, label %resume
  19                                 i8 1, label %cleanup]
  20 resume:
  21   call void @print(i32 1)
  22   br label %cleanup
  23
  24 cleanup:
  25   %mem = call ptr @llvm.coro.free(token %id, ptr %hdl)
  26   call void @free(ptr %mem)
  27   br label %suspend
  28 suspend:
  29   call i1 @llvm.coro.end(ptr %hdl, i1 0, token none)
  30   ret ptr %hdl
  31 }
  32 define i32 @main() {
  33 entry:
  34   %hdl = call ptr @f()
  35   call void @llvm.coro.resume(ptr %hdl)
  36   ret i32 0
  37 ; CHECK-LABEL: @main(
  38 ; CHECK: call void @print(i32 0)
  39 ; CHECK: call void @print(i32 1)
  40 ; CHECK:      ret i32 0
  41 }
  42
  43 declare ptr @llvm.coro.free(token, ptr)
  44 declare i32 @llvm.coro.size.i32()
  45 declare i8  @llvm.coro.suspend(token, i1)
  46 declare void @llvm.coro.resume(ptr)
  47 declare void @llvm.coro.destroy(ptr)
  48
  49 declare token @llvm.coro.id(i32, ptr, ptr, ptr)
  50 declare i1 @llvm.coro.alloc(token)
  51 declare ptr @llvm.coro.begin(token, ptr)
  52 declare i1 @llvm.coro.end(ptr, i1, token)
  53
  54 declare noalias ptr @malloc(i32)
  55 declare void @print(i32)
  56 declare void @free(ptr)