llvm/test/Transforms/LoopRotate/pr51981-scev-problem.ll

   1 ; RUN: opt < %s -passes='print<scalar-evolution>,loop(loop-rotate),invalidate<scalar-evolution>,print<scalar-evolution>' -disable-output 2>&1 | FileCheck -check-prefixes CHECK-SCEV %s
   2 ; RUN: opt < %s -passes='print<scalar-evolution>,loop(loop-rotate),print<scalar-evolution>' -disable-output 2>&1 | FileCheck -check-prefixes CHECK-SCEV %s
   3 ; RUN: opt < %s -passes='loop(canon-freeze),loop(loop-rotate),print<scalar-evolution>' -disable-output
   4
   5 ; In the first two RUN lines print<scalar-evolution> is used to populate the
   6 ; analysis cache before loop-rotate. That was enough to see the problem by
   7 ; examining print<scalar-evolution> printouts after loop-rotate. However, the
   8 ; crashes where only observed when using canon-freeze as a trigger to populate
   9 ; the analysis cache, so that is why canon-freeze is used in the third RUN
  10 ; line.
  11
  12 ; Verify that we get the same SCEV expressions after loop-rotate, regardless
  13 ; if we invalidate scalar-evolution before the final printing or not.
  14 ;
  15 ; This used to fail as described by PR51981 (some expressions still referred
  16 ; to (trunc i32 %div210 to i16) but after the rotation it should be (trunc i32
  17 ; %div2102 to i16).
  18 ;
  19 ; CHECK-SCEV: Classifying expressions for: @test_function
  20 ; CHECK-SCEV:   %wide = load i32, ptr @offset, align 1
  21 ; CHECK-SCEV:   -->  %wide U: full-set S: full-set          Exits: <<Unknown>>              LoopDispositions: { %loop.outer.header: Variant, %loop.inner: Invariant }
  22 ; CHECK-SCEV:   %narrow = trunc i32 %wide to i16
  23 ; CHECK-SCEV:   -->  (trunc i32 %wide to i16) U: full-set S: full-set               Exits: <<Unknown>>              LoopDispositions: { %loop.outer.header: Variant, %loop.inner: Invariant }
  24 ; CHECK-SCEV:   %iv = phi i16 [ %narrow, %loop.inner.ph ], [ %iv.plus, %loop.inner ]
  25 ; CHECK-SCEV:   -->  {(trunc i32 %wide to i16),+,1}<nw><%loop.inner> U: full-set S: full-set           Exits: (-1 + (700 umax (1 + (trunc i32 %wide to i16))))               LoopDispositions: { %loop.inner: Computable, %loop.outer.header: Variant }
  26 ;
  27 ; CHECK-SCEV: Classifying expressions for: @test_function
  28 ; CHECK-SCEV:   %wide1 = load i32, ptr @offset, align 1
  29 ; CHECK-SCEV:   -->  %wide1 U: full-set S: full-set
  30 ; CHECK-SCEV:   %wide2 = phi i32 [ %wide1, %loop.inner.ph.lr.ph ], [ %wide, %loop.outer.latch ]
  31 ; CHECK-SCEV:   -->  %wide2 U: full-set S: full-set         Exits: <<Unknown>>              LoopDispositions: { %loop.inner.ph: Variant, %loop.inner: Invariant }
  32 ; CHECK-SCEV:   %narrow = trunc i32 %wide2 to i16
  33 ; CHECK-SCEV:   -->  (trunc i32 %wide2 to i16) U: full-set S: full-set               Exits: <<Unknown>>              LoopDispositions: { %loop.inner.ph: Variant, %loop.inner: Invariant }
  34 ; CHECK-SCEV:   %iv = phi i16 [ %narrow, %loop.inner.ph ], [ %iv.plus, %loop.inner ]
  35 ; CHECK-SCEV:   -->  {(trunc i32 %wide2 to i16),+,1}<nw><%loop.inner> U: full-set S: full-set           Exits: (-1 + (700 umax (1 + (trunc i32 %wide2 to i16))))               LoopDispositions: { %loop.inner: Computable, %loop.inner.ph: Variant }
  36
  37
  38 @offset = external dso_local global i32, align 1
  39 @array = internal global [11263 x i32] zeroinitializer, align 1
  40
  41 define void @test_function(i1 %cond) {
  42 entry:
  43   br label %loop.outer.header
  44
  45 loop.outer.header:                                ; preds = %loop.outer.latch, %entry
  46   %wide = load i32, ptr @offset, align 1
  47   br i1 %cond, label %exit, label %loop.inner.ph
  48
  49 loop.inner.ph:                                    ; preds = %loop.outer.header
  50   %narrow = trunc i32 %wide to i16
  51   br label %loop.inner
  52
  53 loop.inner:                                       ; preds = %loop.inner, %loop.inner.ph
  54   %iv = phi i16 [ %narrow, %loop.inner.ph ], [ %iv.plus, %loop.inner ]
  55   %iv.promoted = zext i16 %iv to i32
  56   %gep = getelementptr inbounds [11263 x i32], ptr @array, i32 0, i32 %iv.promoted
  57   store i32 7, ptr %gep, align 1
  58   %iv.plus = add i16 %iv, 1
  59   %cmp = icmp ult i16 %iv.plus, 700
  60   br i1 %cmp, label %loop.inner, label %loop.outer.latch
  61
  62 loop.outer.latch:                                 ; preds = %loop.inner
  63   br label %loop.outer.header
  64
  65 exit:                                             ; preds = %loop.outer.header
  66   ret void
  67 }
  68