autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   *)                      llvm_cv_target_arch="Unknown" ;;
 231 esac])
 232
 233 if test "$llvm_cv_target_arch" = "Unknown" ; then
 234   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 235 fi
 236
 237 dnl Define a substitution, ARCH, for the target architecture
 238 AC_SUBST(ARCH,$llvm_cv_target_arch)
 239
 240 dnl Check for the endianness of the target
 241 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 242
 243 dnl Check for build platform executable suffix if we're crosscompiling
 244 if test "$cross_compiling" = yes; then
 245   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 246   AC_BUILD_EXEEXT
 247   ac_build_prefix=${build_alias}-
 248   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 249   if test -z "$BUILD_CXX"; then
 250      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 251      if test -z "$BUILD_CXX"; then
 252        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 253      fi
 254   fi
 255 else
 256   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 257 fi
 258
 259 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 260 dnl that this build is being done from a checkout. This sets up several
 261 dnl defaults for the command line switches. When we build with a CVS directory,
 262 dnl we get a debug with assertions turned on. Without, we assume a source
 263 dnl release and we get an optimized build without assertions.
 264 dnl See --enable-optimized and --enable-assertions below
 265 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 266   cvsbuild="yes"
 267   optimize="no"
 268   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 269 else
 270   cvsbuild="no"
 271   optimize="yes"
 272 fi
 273
 274 dnl===-----------------------------------------------------------------------===
 275 dnl===
 276 dnl=== SECTION 3: Command line arguments for the configure script.
 277 dnl===
 278 dnl===-----------------------------------------------------------------------===
 279
 280 dnl --enable-optimized : check whether they want to do an optimized build:
 281 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 282  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 283 if test ${enableval} = "no" ; then
 284   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 285 else
 286   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 287 fi
 288
 289 dnl --enable-profiling : check whether they want to do a profile build:
 290 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 291  [--enable-profiling,Compile with profiling enabled (default is NO)]),,enableval="no")
 292 if test ${enableval} = "no" ; then
 293   AC_SUBST(ENABLE_PROFILING,[[]])
 294 else
 295   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 296 fi
 297
 298 dnl --enable-assertions : check whether they want to turn on assertions or not:
 299 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 300   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 301 if test ${enableval} = "yes" ; then
 302   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 303 else
 304   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 305 fi
 306
 307 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 308 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 309   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 310 if test ${enableval} = "yes" ; then
 311   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 312   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 313 else
 314   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 315   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 316 fi
 317
 318 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 319 AC_ARG_ENABLE(debug-runtime,
 320    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 321 if test ${enableval} = "no" ; then
 322   AC_SUBST(DEBUG_RUNTIME,[[]])
 323 else
 324   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 325 fi
 326
 327 dnl --enable-jit: check whether they want to enable the jit
 328 AC_ARG_ENABLE(jit,
 329   AS_HELP_STRING(--enable-jit,
 330                  [Enable Just In Time Compiling (default is YES)]),,
 331   enableval=default)
 332 if test ${enableval} = "no"
 333 then
 334   AC_SUBST(JIT,[[]])
 335 else
 336   case "$llvm_cv_target_arch" in
 337     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 338     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 339     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 340     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 341     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 342     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 343     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 344     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 345     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 347     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 348     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 349   esac
 350 fi
 351
 352 dnl Allow enablement of doxygen generated documentation
 353 AC_ARG_ENABLE(doxygen,
 354               AS_HELP_STRING([--enable-doxygen],
 355                              [Build doxygen documentation (default is NO)]),,
 356                              enableval=default)
 357 case "$enableval" in
 358   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 359   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 360   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 361   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 362 esac
 363
 364 dnl Allow disablement of threads
 365 AC_ARG_ENABLE(threads,
 366               AS_HELP_STRING([--enable-threads],
 367                              [Use threads if available (default is YES)]),,
 368                              enableval=default)
 369 case "$enableval" in
 370   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 371   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 372   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 373   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 374 esac
 375 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 376
 377 dnl Allow building without position independent code
 378 AC_ARG_ENABLE(pic,
 379   AS_HELP_STRING([--enable-pic],
 380                  [Build LLVM with Position Independent Code (default is YES)]),,
 381                  enableval=default)
 382 case "$enableval" in
 383   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 384   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 385   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 386   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 387 esac
 388 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 389                    [Define if position independent code is enabled])
 390
 391 dnl Allow specific targets to be specified for building (or not)
 392 TARGETS_TO_BUILD=""
 393 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 394     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 395     enableval=all)
 396 case "$enableval" in
 397   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
 398   host-only)
 399     case "$llvm_cv_target_arch" in
 400       x86)     TARGETS_TO_BUILD="X86" ;;
 401       x86_64)  TARGETS_TO_BUILD="X86" ;;
 402       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 403       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 404       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 405       IA64)    TARGETS_TO_BUILD="IA64" ;;
 406       ARM)     TARGETS_TO_BUILD="ARM" ;;
 407       Mips)    TARGETS_TO_BUILD="Mips" ;;
 408       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 409       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 410       XCore)   TARGETS_TO_BUILD="XCore" ;;
 411       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 412       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 413     esac
 414     ;;
 415   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 416       case "$a_target" in
 417         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 418         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 419         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 420         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 421         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 422         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 423         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 424         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 425         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 426         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 427         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 428         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 429         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 430         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 431         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 432         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 433       esac
 434   done
 435   ;;
 436 esac
 437 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 438
 439 dnl Prevent the CBackend from using printf("%a") for floating point so older
 440 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 441 dnl can still compile the CBE's output
 442 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 443   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 444   enableval=default)
 445 case "$enableval" in
 446   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 447   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 448   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 449   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 450 esac
 451 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 452                    [Define if CBE is enabled for printf %a output])
 453
 454 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 455 AC_ARG_WITH(llvmgccdir,
 456   AS_HELP_STRING([--with-llvmgccdir],
 457     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 458     withval=default)
 459 case "$withval" in
 460   default) WITH_LLVMGCCDIR=default ;;
 461   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 462   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 463 esac
 464
 465 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 466 AC_ARG_WITH(llvmgcc,
 467   AS_HELP_STRING([--with-llvmgcc],
 468     [Specify location of llvm-gcc driver (default searches PATH)]),
 469     LLVMGCC=$with_llvmgcc
 470       WITH_LLVMGCCDIR="",)
 471
 472 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 473 AC_ARG_WITH(llvmgxx,
 474   AS_HELP_STRING([--with-llvmgxx],
 475     [Specify location of llvm-g++ driver (default searches PATH)]),
 476     LLVMGXX=$with_llvmgxx
 477     WITH_LLVMGCCDIR="",)
 478
 479 if test -n "$LLVMGCC"; then
 480    LLVMGCCCOMMAND="$LLVMGCC"
 481 fi
 482
 483 if test -n "$LLVMGXX"; then
 484    LLVMGXXCOMMAND="$LLVMGXX"
 485 fi
 486
 487 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 488    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 489 fi
 490
 491 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 492    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 493 fi
 494
 495 dnl Specify extra build options
 496 AC_ARG_WITH(extra-options,
 497   AS_HELP_STRING([--with-extra-options],
 498                  [Specify additional options to compile LLVM with]),,
 499                  withval=default)
 500 case "$withval" in
 501   default) EXTRA_OPTIONS= ;;
 502   *) EXTRA_OPTIONS=$withval ;;
 503 esac
 504 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 505
 506 dnl Allow specific bindings to be specified for building (or not)
 507 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 508     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 509     enableval=default)
 510 BINDINGS_TO_BUILD=""
 511 case "$enableval" in
 512   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 513   all ) BINDINGS_TO_BUILD="ocaml" ;;
 514   none | no) BINDINGS_TO_BUILD="" ;;
 515   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 516       case "$a_binding" in
 517         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 518         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 519       esac
 520   done
 521   ;;
 522 esac
 523
 524 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 525 dnl script for bindings/ocaml/configure, except that its auto value depends on
 526 dnl OCAMLC, which is found here to support tests.
 527 AC_ARG_WITH([ocaml-libdir],
 528   [AS_HELP_STRING([--with-ocaml-libdir],
 529     [Specify install location for ocaml bindings (default is stdlib)])],
 530   [],
 531   [withval=auto])
 532 case "$withval" in
 533   auto) with_ocaml_libdir="$withval" ;;
 534   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 535   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 536 esac
 537
 538 dnl Allow linking of LLVM with GPLv3 binutils code.
 539 AC_ARG_WITH(binutils-include,
 540   AS_HELP_STRING([--with-binutils-include],
 541     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 542   withval=default)
 543 case "$withval" in
 544   default) WITH_BINUTILS_INCDIR=default ;;
 545   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 546   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 547 esac
 548 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 549   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 550   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 551      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 552      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 553   fi
 554 fi
 555
 556 dnl===-----------------------------------------------------------------------===
 557 dnl===
 558 dnl=== SECTION 4: Check for programs we need and that they are the right version
 559 dnl===
 560 dnl===-----------------------------------------------------------------------===
 561
 562 dnl Check for compilation tools
 563 AC_PROG_CPP
 564 AC_PROG_CC(gcc)
 565 AC_PROG_CXX(g++)
 566
 567 AC_PROG_NM
 568 AC_SUBST(NM)
 569
 570 dnl Check for the tools that the makefiles require
 571 AC_CHECK_GNU_MAKE
 572 AC_PROG_LN_S
 573 AC_PATH_PROG(CMP, [cmp], [cmp])
 574 AC_PATH_PROG(CP, [cp], [cp])
 575 AC_PATH_PROG(DATE, [date], [date])
 576 AC_PATH_PROG(FIND, [find], [find])
 577 AC_PATH_PROG(GREP, [grep], [grep])
 578 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 579 AC_PATH_PROG(MV,   [mv],   [mv])
 580 AC_PROG_RANLIB
 581 AC_PATH_PROG(RM,   [rm],   [rm])
 582 AC_PATH_PROG(SED,  [sed],  [sed])
 583 AC_PATH_PROG(TAR,  [tar],  [gtar])
 584 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 585
 586 dnl Looking for misc. graph plotting software
 587 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 588 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 589   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 590   dnl If we're targeting for mingw we should emit windows paths, not msys
 591   if test "$llvm_cv_os_type" = "MingW" ; then
 592     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 593   fi
 594   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 595    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 596 fi
 597 AC_PATH_PROG(DOT, [dot], [echo dot])
 598 if test "$DOT" != "echo dot" ; then
 599   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 600   dnl If we're targeting for mingw we should emit windows paths, not msys
 601   if test "$llvm_cv_os_type" = "MingW" ; then
 602     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 603   fi
 604   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 605    [Define to path to dot program if found or 'echo dot' otherwise])
 606 fi
 607 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 608 if test "$GV" != "echo gv" ; then
 609   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 610   dnl If we're targeting for mingw we should emit windows paths, not msys
 611   if test "$llvm_cv_os_type" = "MingW" ; then
 612     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 613   fi
 614   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 615    [Define to path to gv program if found or 'echo gv' otherwise])
 616 fi
 617 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 618 if test "$DOTTY" != "echo dotty" ; then
 619   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 620   dnl If we're targeting for mingw we should emit windows paths, not msys
 621   if test "$llvm_cv_os_type" = "MingW" ; then
 622     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 623   fi
 624   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 625    [Define to path to dotty program if found or 'echo dotty' otherwise])
 626 fi
 627
 628 dnl Look for a sufficiently recent version of Perl.
 629 LLVM_PROG_PERL([5.006])
 630 AC_SUBST(PERL)
 631 if test x"$PERL" = xnone; then
 632    AC_SUBST(HAVE_PERL,0)
 633    AC_MSG_ERROR([perl is required but was not found, please install it])
 634 else
 635    AC_SUBST(HAVE_PERL,1)
 636 fi
 637
 638 dnl Find the install program
 639 AC_PROG_INSTALL
 640
 641 dnl Checks for documentation and testing tools that we can do without. If these
 642 dnl are not found then they are set to "true" which always succeeds but does
 643 dnl nothing. This just lets the build output show that we could have done
 644 dnl something if the tool was available.
 645 AC_PATH_PROG(BZIP2, [bzip2])
 646 AC_PATH_PROG(DOXYGEN, [doxygen])
 647 AC_PATH_PROG(GROFF, [groff])
 648 AC_PATH_PROG(GZIP, [gzip])
 649 AC_PATH_PROG(POD2HTML, [pod2html])
 650 AC_PATH_PROG(POD2MAN, [pod2man])
 651 AC_PATH_PROG(RUNTEST, [runtest])
 652 DJ_AC_PATH_TCLSH
 653 AC_PATH_PROG(ZIP, [zip])
 654 AC_PATH_PROGS(OCAMLC, [ocamlc])
 655 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 656 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 657 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 658 AC_PATH_PROGS(GAS, [gas as])
 659
 660 dnl Determine whether the linker supports the -R option.
 661 AC_LINK_USE_R
 662
 663 dnl Determine whether the linker supports the -export-dynamic option.
 664 AC_LINK_EXPORT_DYNAMIC
 665
 666 dnl Check for libtool and the library that has dlopen function (which must come
 667 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 668 dnl libtool).
 669 AC_LIBTOOL_DLOPEN
 670 AC_LIB_LTDL
 671 AC_PROG_LIBTOOL
 672
 673 if test "$lt_cv_dlopen_self" = "yes" ; then
 674   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 675               [Define if dlopen(0) will open the symbols of the program])
 676 fi
 677
 678
 679 if test "$WITH_LLVMGCCDIR" = "default" ; then
 680   LLVMGCC="llvm-gcc${EXEEXT}"
 681   LLVMGXX="llvm-g++${EXEEXT}"
 682   LLVMGCCCOMMAND="$LLVMGCC"
 683   LLVMGXXCOMMAND="$LLVMGXX"
 684   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 685   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 686   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 687   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 688 else
 689   if test -z "$LLVMGCC"; then
 690     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 691     LLVMGCCCOMMAND="$LLVMGCC"
 692   fi
 693   if test -z "$LLVMGXX"; then
 694     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 695     LLVMGXXCOMMAND="$LLVMGXX"
 696   fi
 697
 698   AC_SUBST(LLVMGCC,$LLVMGCC)
 699   AC_SUBST(LLVMGXX,$LLVMGXX)
 700   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 701   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 702 fi
 703
 704
 705 AC_MSG_CHECKING([tool compatibility])
 706
 707 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 708 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 709 dnl to support those options.
 710 dnl "icc" emits gcc signatures
 711 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 712 ICC=no
 713 IXX=no
 714 case $CC in
 715   icc*|icpc*)
 716     ICC=yes
 717     IXX=yes
 718     ;;
 719    *)
 720     ;;
 721 esac
 722
 723 if test "$GCC" != "yes" && test "$ICC" != "yes"
 724 then
 725   AC_MSG_ERROR([gcc|icc required but not found])
 726 fi
 727
 728 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 729 if test "$GXX" != "yes" && test "$IXX" != "yes"
 730 then
 731   AC_MSG_ERROR([g++|icc required but not found])
 732 fi
 733
 734 dnl Verify that GCC is version 3.0 or higher
 735 if test "$GCC" = "yes"
 736 then
 737   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 738 #error Unsupported GCC version
 739 #endif
 740 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 741 fi
 742
 743 dnl Check for GNU Make.  We use its extensions, so don't build without it
 744 if test -z "$llvm_cv_gnu_make_command"
 745 then
 746   AC_MSG_ERROR([GNU Make required but not found])
 747 fi
 748
 749 dnl Tool compatibility is okay if we make it here.
 750 AC_MSG_RESULT([ok])
 751
 752 dnl===-----------------------------------------------------------------------===
 753 dnl===
 754 dnl=== SECTION 5: Check for libraries
 755 dnl===
 756 dnl===-----------------------------------------------------------------------===
 757
 758 dnl libelf is for sparc only; we can ignore it if we don't have it
 759 AC_CHECK_LIB(elf, elf_begin)
 760 AC_CHECK_LIB(m,sin)
 761 if test "$llvm_cv_os_type" = "MingW" ; then
 762   AC_CHECK_LIB(imagehlp, main)
 763   AC_CHECK_LIB(psapi, main)
 764 fi
 765
 766 dnl dlopen() is required for plugin support.
 767 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 768                [Define if dlopen() is available on this platform.]),
 769                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 770
 771 dnl libffi is optional; used to call external functions from the interpreter
 772 AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 773                [Define if libffi is available on this platform.]),
 774                AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 775
 776 dnl mallinfo is optional; the code can compile (minus features) without it
 777 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 778                [Define if mallinfo() is available on this platform.]))
 779
 780 dnl pthread locking functions are optional - but llvm will not be thread-safe
 781 dnl without locks.
 782 if test "$ENABLE_THREADS" -eq 1 ; then
 783   AC_CHECK_LIB(pthread,pthread_mutex_init)
 784   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 785                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 786                            [Have pthread_mutex_lock]))
 787 fi
 788
 789 dnl Allow extra x86-disassembler library
 790 AC_ARG_WITH(udis86,
 791   AS_HELP_STRING([--with-udis86=<path>],
 792     [Use udis86 external x86 disassembler library]),
 793     [
 794       AC_SUBST(USE_UDIS86, [1])
 795       case "$withval" in
 796         /usr/lib|yes) ;;
 797         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 798       esac
 799       AC_CHECK_LIB(udis86, ud_init, [], [
 800         echo "Error! You need to have libudis86 around."
 801         exit -1
 802       ])
 803     ],
 804     AC_SUBST(USE_UDIS86, [0]))
 805 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 806                    [Define if use udis86 library])
 807
 808 dnl===-----------------------------------------------------------------------===
 809 dnl===
 810 dnl=== SECTION 6: Check for header files
 811 dnl===
 812 dnl===-----------------------------------------------------------------------===
 813
 814 dnl First, use autoconf provided macros for specific headers that we need
 815 dnl We don't check for ancient stuff or things that are guaranteed to be there
 816 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 817 dnl Generally we're looking for POSIX headers.
 818 AC_HEADER_DIRENT
 819 AC_HEADER_MMAP_ANONYMOUS
 820 AC_HEADER_STAT
 821 AC_HEADER_STDC
 822 AC_HEADER_SYS_WAIT
 823 AC_HEADER_TIME
 824
 825 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 826 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 827 AC_CHECK_HEADERS([utime.h windows.h])
 828 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 829 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 830 if test "$ENABLE_THREADS" -eq 1 ; then
 831   AC_CHECK_HEADERS(pthread.h,
 832                    AC_SUBST(HAVE_PTHREAD, 1),
 833                    AC_SUBST(HAVE_PTHREAD, 0))
 834 else
 835   AC_SUBST(HAVE_PTHREAD, 0)
 836 fi
 837
 838 dnl Try to find ffi.h.
 839 AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 840
 841 dnl===-----------------------------------------------------------------------===
 842 dnl===
 843 dnl=== SECTION 7: Check for types and structures
 844 dnl===
 845 dnl===-----------------------------------------------------------------------===
 846
 847 AC_HUGE_VAL_CHECK
 848 AC_TYPE_PID_T
 849 AC_TYPE_SIZE_T
 850 AC_TYPE_SIGNAL
 851 AC_STRUCT_TM
 852 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 853 AC_CHECK_TYPES([uint64_t],,
 854          AC_CHECK_TYPES([u_int64_t],,
 855          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 856
 857 dnl===-----------------------------------------------------------------------===
 858 dnl===
 859 dnl=== SECTION 8: Check for specific functions needed
 860 dnl===
 861 dnl===-----------------------------------------------------------------------===
 862
 863 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 864 AC_CHECK_FUNCS([powf fmodf strtof round ])
 865 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 866 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 867 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 868 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 869 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 870 AC_C_PRINTF_A
 871 AC_FUNC_ALLOCA
 872 AC_FUNC_RAND48
 873
 874 dnl Check for variations in the Standard C++ library and STL. These macros are
 875 dnl provided by LLVM in the autoconf/m4 directory.
 876 AC_CXX_HAVE_STD_ITERATOR
 877 AC_CXX_HAVE_BI_ITERATOR
 878 AC_CXX_HAVE_FWD_ITERATOR
 879 AC_FUNC_ISNAN
 880 AC_FUNC_ISINF
 881
 882 dnl Check for mmap support.We also need to know if /dev/zero is required to
 883 dnl be opened for allocating RWX memory.
 884 dnl Make sure we aren't attempting to configure for an unknown system
 885 if test "$llvm_cv_platform_type" = "Unix" ; then
 886   AC_FUNC_MMAP
 887   AC_FUNC_MMAP_FILE
 888   AC_NEED_DEV_ZERO_FOR_MMAP
 889
 890   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 891   then
 892     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 893   fi
 894   if test "$ac_cv_func_mmap_file" = "no"
 895   then
 896     AC_MSG_WARN([mmap() of files required but not found])
 897   fi
 898 fi
 899
 900 dnl atomic builtins are required for threading support.
 901 AC_MSG_CHECKING(for GCC atomic builtins)
 902 AC_LINK_IFELSE(
 903   AC_LANG_SOURCE(
 904     [[int main() {
 905         volatile unsigned long val = 1;
 906         __sync_synchronize();
 907         __sync_val_compare_and_swap(&val, 1, 0);
 908         return 0;
 909       }
 910     ]]),
 911   AC_MSG_RESULT(yes)
 912   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
 913   AC_MSG_RESULT(no)
 914   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
 915   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
 916
 917
 918 dnl===-----------------------------------------------------------------------===
 919 dnl===
 920 dnl=== SECTION 9: Additional checks, variables, etc.
 921 dnl===
 922 dnl===-----------------------------------------------------------------------===
 923
 924 dnl Check, whether __dso_handle is present
 925 AC_CHECK_FUNCS([__dso_handle])
 926
 927 dnl See if the llvm-gcc executable can compile to LLVM assembly
 928 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 929 [llvm_cv_llvmgcc_sanity="no"
 930 if test -x "$LLVMGCC" ; then
 931   cp /dev/null conftest.c
 932   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 933       grep 'target datalayout =' > /dev/null 2>&1
 934   if test $? -eq 0 ; then
 935     llvm_cv_llvmgcc_sanity="yes"
 936   fi
 937   rm conftest.c
 938 fi])
 939
 940 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 941 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 942   AC_MSG_CHECKING([llvm-gcc component support])
 943   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 944   AC_SUBST(LLVMCC1,$llvmcc1path)
 945   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 946   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 947   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 948   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 949   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 950   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 951   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 952   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 953   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 954   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 955   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
 956   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 957   AC_MSG_RESULT([ok])
 958 fi
 959
 960 dnl Propagate the shared library extension that the libltdl checks did to
 961 dnl the Makefiles so we can use it there too
 962 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 963
 964 # Translate the various configuration directories and other basic
 965 # information into substitutions that will end up in Makefile.config.in
 966 # that these configured values can be used by the makefiles
 967 if test "${prefix}" = "NONE" ; then
 968   prefix="/usr/local"
 969 fi
 970 eval LLVM_PREFIX="${prefix}";
 971 eval LLVM_BINDIR="${prefix}/bin";
 972 eval LLVM_LIBDIR="${prefix}/lib";
 973 eval LLVM_DATADIR="${prefix}/share/llvm";
 974 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 975 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 976 eval LLVM_INCLUDEDIR="${prefix}/include";
 977 eval LLVM_INFODIR="${prefix}/info";
 978 eval LLVM_MANDIR="${prefix}/man";
 979 LLVM_CONFIGTIME=`date`
 980 AC_SUBST(LLVM_PREFIX)
 981 AC_SUBST(LLVM_BINDIR)
 982 AC_SUBST(LLVM_LIBDIR)
 983 AC_SUBST(LLVM_DATADIR)
 984 AC_SUBST(LLVM_DOCSDIR)
 985 AC_SUBST(LLVM_ETCDIR)
 986 AC_SUBST(LLVM_INCLUDEDIR)
 987 AC_SUBST(LLVM_INFODIR)
 988 AC_SUBST(LLVM_MANDIR)
 989 AC_SUBST(LLVM_CONFIGTIME)
 990
 991 # Place the various directores into the config.h file as #defines so that we
 992 # can know about the installation paths within LLVM.
 993 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 994                    [Installation prefix directory])
 995 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 996                    [Installation directory for binary executables])
 997 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 998                    [Installation directory for libraries])
 999 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1000                    [Installation directory for data files])
1001 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1002                    [Installation directory for documentation])
1003 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1004                    [Installation directory for config files])
1005 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1006                    [Installation directory for include files])
1007 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1008                    [Installation directory for .info files])
1009 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1010                    [Installation directory for man pages])
1011 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1012                    [Time at which LLVM was configured])
1013 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1014                    [Host triple we were built on])
1015
1016 # Determine which bindings to build.
1017 if test "$BINDINGS_TO_BUILD" = auto ; then
1018   BINDINGS_TO_BUILD=""
1019   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1020     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1021   fi
1022 fi
1023 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1024
1025 # This isn't really configurey, but it avoids having to repeat the list in
1026 # other files.
1027 AC_SUBST(ALL_BINDINGS,ocaml)
1028
1029 # Do any work necessary to ensure that bindings have what they need.
1030 binding_prereqs_failed=0
1031 for a_binding in $BINDINGS_TO_BUILD ; do
1032   case "$a_binding" in
1033   ocaml)
1034     if test "x$OCAMLC" = x ; then
1035       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1036       binding_prereqs_failed=1
1037     fi
1038     if test "x$OCAMLDEP" = x ; then
1039       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1040       binding_prereqs_failed=1
1041     fi
1042     if test "x$OCAMLOPT" = x ; then
1043       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1044       dnl ocamlopt is optional!
1045     fi
1046     if test "x$with_ocaml_libdir" != xauto ; then
1047       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1048     else
1049       ocaml_stdlib="`"$OCAMLC" -where`"
1050       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1051       then
1052         # ocaml stdlib is beneath our prefix; use stdlib
1053         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1054       else
1055         # ocaml stdlib is outside our prefix; use libdir/ocaml
1056         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1057       fi
1058     fi
1059     ;;
1060   esac
1061 done
1062 if test "$binding_prereqs_failed" = 1 ; then
1063   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1064 fi
1065
1066 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1067 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1068
1069 dnl Determine linker rpath flag
1070 if test "$llvm_cv_link_use_r" = "yes" ; then
1071   RPATH="-Wl,-R"
1072 else
1073   RPATH="-Wl,-rpath"
1074 fi
1075 AC_SUBST(RPATH)
1076
1077 dnl Determine linker rdynamic flag
1078 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1079   RDYNAMIC="-Wl,-export-dynamic"
1080 else
1081   RDYNAMIC=""
1082 fi
1083 AC_SUBST(RDYNAMIC)
1084
1085 dnl===-----------------------------------------------------------------------===
1086 dnl===
1087 dnl=== SECTION 10: Specify the output files and generate it
1088 dnl===
1089 dnl===-----------------------------------------------------------------------===
1090
1091 dnl Configure header files
1092 dnl WARNING: dnl If you add or remove any of the following config headers, then
1093 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1094 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1095 dnl files can be updated automatically when their *.in sources change.
1096 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1097 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1098 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1099
1100 dnl Configure the makefile's configuration data
1101 AC_CONFIG_FILES([Makefile.config])
1102
1103 dnl Configure the RPM spec file for LLVM
1104 AC_CONFIG_FILES([llvm.spec])
1105
1106 dnl Configure doxygen's configuration file
1107 AC_CONFIG_FILES([docs/doxygen.cfg])
1108
1109 dnl Configure llvmc's Base plugin
1110 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1111
1112 dnl Do the first stage of configuration for llvm-config.in.
1113 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1114
1115 dnl Do special configuration of Makefiles
1116 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1117 AC_CONFIG_MAKEFILE(Makefile)
1118 AC_CONFIG_MAKEFILE(Makefile.common)
1119 AC_CONFIG_MAKEFILE(examples/Makefile)
1120 AC_CONFIG_MAKEFILE(lib/Makefile)
1121 AC_CONFIG_MAKEFILE(runtime/Makefile)
1122 AC_CONFIG_MAKEFILE(test/Makefile)
1123 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1124 AC_CONFIG_MAKEFILE(unittests/Makefile)
1125 AC_CONFIG_MAKEFILE(tools/Makefile)
1126 AC_CONFIG_MAKEFILE(utils/Makefile)
1127 AC_CONFIG_MAKEFILE(projects/Makefile)
1128 AC_CONFIG_MAKEFILE(bindings/Makefile)
1129 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1130
1131 dnl Finally, crank out the output
1132 AC_OUTPUT