cmake/config-ix.cmake

   1
   2 # include checks
   3 include(CheckIncludeFile)
   4 check_include_file(argz.h HAVE_ARGZ_H)
   5 check_include_file(assert.h HAVE_ASSERT_H)
   6 check_include_file(dirent.h HAVE_DIRENT_H)
   7 check_include_file(dl.h HAVE_DL_H)
   8 check_include_file(dld.h HAVE_DLD_H)
   9 check_include_file(dlfcn.h HAVE_DLFCN_H)
  10 check_include_file(errno.h HAVE_ERRNO_H)
  11 check_include_file(execinfo.h HAVE_EXECINFO_H)
  12 check_include_file(fcntl.h HAVE_FCNTL_H)
  13 check_include_file(inttypes.h HAVE_INTTYPES_H)
  14 check_include_file(limits.h HAVE_LIMITS_H)
  15 check_include_file(link.h HAVE_LINK_H)
  16 check_include_file(malloc.h HAVE_MALLOC_H)
  17 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  18 check_include_file(memory.h HAVE_MEMORY_H)
  19 check_include_file(ndir.h HAVE_NDIR_H)
  20 check_include_file(pthread.h HAVE_PTHREAD_H)
  21 check_include_file(setjmp.h HAVE_SETJMP_H)
  22 check_include_file(signal.h HAVE_SIGNAL_H)
  23 check_include_file(stdint.h HAVE_STDINT_H)
  24 check_include_file(stdio.h HAVE_STDIO_H)
  25 check_include_file(stdlib.h HAVE_STDLIB_H)
  26 check_include_file(string.h HAVE_STRING_H)
  27 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  28 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  29 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  30 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  31 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  32 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  33 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  34 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  35 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  36 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  37 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  38 check_include_file(termios.h HAVE_TERMIOS_H)
  39 check_include_file(unistd.h HAVE_UNISTD_H)
  40 check_include_file(utime.h HAVE_UTIME_H)
  41 check_include_file(windows.h HAVE_WINDOWS_H)
  42
  43 # library checks
  44 include(CheckLibraryExists)
  45 check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  46 check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  47 check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  48 check_library_exists(dl dlopen "" HAVE_LIBDL)
  49
  50 # function checks
  51 include(CheckSymbolExists)
  52 include(CheckFunctionExists)
  53 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  54 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  55 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  56 check_function_exists(isatty HAVE_ISATTY)
  57 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  58 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  59 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  60 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  61 check_symbol_exists(ceilf math.h HAVE_CEILF)
  62 check_symbol_exists(floorf math.h HAVE_FLOORF)
  63 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  64 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  65                     HAVE_MALLOC_ZONE_STATISTICS)
  66 check_symbol_exists(mkdtemp unistd.h HAVE_MKDTEMP)
  67 check_symbol_exists(mkstemp unistd.h HAVE_MKSTEMP)
  68 check_symbol_exists(mktemp unistd.h HAVE_MKTEMP)
  69 check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
  70 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
  71 check_symbol_exists(strerror string.h HAVE_STRERROR)
  72 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
  73 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
  74
  75 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
  76 if( LLVM_USING_GLIBC )
  77   add_llvm_definitions( -D_GNU_SOURCE )
  78 endif()
  79
  80 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
  81 include(CheckAtomic)
  82
  83 include(CheckCXXCompilerFlag)
  84 # On windows all code is position-independent and mingw warns if -fPIC
  85 # is in the command-line.
  86 if( NOT WIN32 )
  87   check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  88 endif()
  89
  90 include(GetTargetTriple)
  91 get_target_triple(LLVM_HOSTTRIPLE)
  92 message(STATUS "LLVM_HOSTTRIPLE: ${LLVM_HOSTTRIPLE}")
  93
  94 # Determine the native architecture.
  95 # FIXME: this will have to change for cross-compiling.
  96 string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
  97 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
  98   set(LLVM_NATIVE_ARCH X86)
  99 elseif (LLVM_NATIVE_ARCH STREQUAL amd64)
 100   set(LLVM_NATIVE_ARCH X86)
 101 elseif (LLVM_NATIVE_ARCH STREQUAL x86_64)
 102   set(LLVM_NATIVE_ARCH X86)
 103 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 104   set(LLVM_NATIVE_ARCH Sparc)
 105 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 106   set(LLVM_NATIVE_ARCH PowerPC)
 107 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 108   set(LLVM_NATIVE_ARCH Alpha)
 109 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 110   set(LLVM_NATIVE_ARCH ARM)
 111 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 112   set(LLVM_NATIVE_ARCH Mips)
 113 elseif (LLVM_NATIVE_ARCH MATCHES "pic16")
 114   set(LLVM_NATIVE_ARCH "PIC16")
 115 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 116   set(LLVM_NATIVE_ARCH XCore)
 117 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 118   set(LLVM_NATIVE_ARCH MSP430)
 119 else ()
 120   message(STATUS
 121     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 122   set(LLVM_NATIVE_ARCH)
 123 endif ()
 124
 125 if (LLVM_NATIVE_ARCH)
 126   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 127   if (NATIVE_ARCH_IDX EQUAL -1)
 128     message(STATUS
 129       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 130     set(LLVM_NATIVE_ARCH)
 131   else ()
 132     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 133   endif ()
 134 endif()
 135
 136 if( MINGW )
 137   set(HAVE_LIBIMAGEHLP 1)
 138   set(HAVE_LIBPSAPI 1)
 139   # TODO: Check existence of libraries.
 140   #   include(CheckLibraryExists)
 141   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 142 endif( MINGW )
 143
 144 if( MSVC )
 145   set(error_t int)
 146   set(mode_t "unsigned short")
 147   set(LTDL_SHLIBPATH_VAR "PATH")
 148   set(LTDL_SYSSEARCHPATH "")
 149   set(LTDL_DLOPEN_DEPLIBS 1)
 150   set(SHLIBEXT ".lib")
 151   set(LTDL_OBJDIR "_libs")
 152   set(HAVE_STRTOLL 1)
 153   set(strtoll "_strtoi64")
 154   set(strtoull "_strtoui64")
 155   set(stricmp "_stricmp")
 156   set(strdup "_strdup")
 157 else( MSVC )
 158   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 159   set(LTDL_SYSSEARCHPATH "") # TODO
 160   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 161 endif( MSVC )
 162
 163 # FIXME: Signal handler return type, currently hardcoded to 'void'
 164 set(RETSIGTYPE void)
 165
 166 if( LLVM_ENABLE_THREADS )
 167   if( HAVE_PTHREAD_H OR WIN32 )
 168     set(ENABLE_THREADS 1)
 169   endif()
 170 endif()
 171
 172 if( ENABLE_THREADS )
 173   message(STATUS "Threads enabled.")
 174 else( ENABLE_THREADS )
 175   message(STATUS "Threads disabled.")
 176 endif()
 177
 178 configure_file(
 179   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 180   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 181   )
 182
 183 configure_file(
 184   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 185   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 186   )
 187