cmake/config-ix.cmake

   1
   2 # include checks
   3 include(CheckIncludeFile)
   4 check_include_file(argz.h HAVE_ARGZ_H)
   5 check_include_file(assert.h HAVE_ASSERT_H)
   6 check_include_file(dirent.h HAVE_DIRENT_H)
   7 check_include_file(dl.h HAVE_DL_H)
   8 check_include_file(dld.h HAVE_DLD_H)
   9 check_include_file(dlfcn.h HAVE_DLFCN_H)
  10 check_include_file(errno.h HAVE_ERRNO_H)
  11 check_include_file(execinfo.h HAVE_EXECINFO_H)
  12 check_include_file(fcntl.h HAVE_FCNTL_H)
  13 check_include_file(inttypes.h HAVE_INTTYPES_H)
  14 check_include_file(limits.h HAVE_LIMITS_H)
  15 check_include_file(link.h HAVE_LINK_H)
  16 check_include_file(malloc.h HAVE_MALLOC_H)
  17 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  18 check_include_file(memory.h HAVE_MEMORY_H)
  19 check_include_file(ndir.h HAVE_NDIR_H)
  20 check_include_file(pthread.h HAVE_PTHREAD_H)
  21 check_include_file(setjmp.h HAVE_SETJMP_H)
  22 check_include_file(signal.h HAVE_SIGNAL_H)
  23 check_include_file(stdint.h HAVE_STDINT_H)
  24 check_include_file(stdio.h HAVE_STDIO_H)
  25 check_include_file(stdlib.h HAVE_STDLIB_H)
  26 check_include_file(string.h HAVE_STRING_H)
  27 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  28 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  29 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  30 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  31 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  32 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  33 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  34 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  35 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  36 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  37 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  38 check_include_file(termios.h HAVE_TERMIOS_H)
  39 check_include_file(unistd.h HAVE_UNISTD_H)
  40 check_include_file(utime.h HAVE_UTIME_H)
  41 check_include_file(windows.h HAVE_WINDOWS_H)
  42
  43 # library checks
  44 include(CheckLibraryExists)
  45 check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  46 check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  47 check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  48 check_library_exists(dl dlopen "" HAVE_LIBDL)
  49
  50 # function checks
  51 include(CheckSymbolExists)
  52 include(CheckFunctionExists)
  53 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  54 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  55 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  56 check_function_exists(isatty HAVE_ISATTY)
  57 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  58 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  59 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  60 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  61 check_symbol_exists(ceilf math.h HAVE_CEILF)
  62 check_symbol_exists(floorf math.h HAVE_FLOORF)
  63 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  64 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  65                     HAVE_MALLOC_ZONE_STATISTICS)
  66 check_symbol_exists(mkdtemp unistd.h HAVE_MKDTEMP)
  67 check_symbol_exists(mkstemp unistd.h HAVE_MKSTEMP)
  68 check_symbol_exists(mktemp unistd.h HAVE_MKTEMP)
  69 check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
  70 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
  71 check_symbol_exists(strerror string.h HAVE_STRERROR)
  72 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
  73 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
  74
  75 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
  76 if( LLVM_USING_GLIBC )
  77   add_llvm_definitions( -D_GNU_SOURCE )
  78 endif()
  79
  80 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
  81 include(CheckAtomic)
  82
  83 include(CheckCXXCompilerFlag)
  84 # On windows all code is position-independent and mingw warns if -fPIC
  85 # is in the command-line.
  86 if( NOT WIN32 )
  87   check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  88 endif()
  89
  90 include(GetTargetTriple)
  91 get_target_triple(LLVM_HOSTTRIPLE)
  92 message(STATUS "LLVM_HOSTTRIPLE: ${LLVM_HOSTTRIPLE}")
  93
  94 # Determine the native architecture.
  95 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
  96 if( LLVM_NATIVE_ARCH STREQUAL "host" )
  97   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
  98 endif ()
  99
 100 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 101   set(LLVM_NATIVE_ARCH X86)
 102 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 103   set(LLVM_NATIVE_ARCH X86)
 104 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 105   set(LLVM_NATIVE_ARCH X86)
 106 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 107   set(LLVM_NATIVE_ARCH X86)
 108 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 109   set(LLVM_NATIVE_ARCH Sparc)
 110 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 111   set(LLVM_NATIVE_ARCH PowerPC)
 112 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 113   set(LLVM_NATIVE_ARCH Alpha)
 114 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 115   set(LLVM_NATIVE_ARCH ARM)
 116 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 117   set(LLVM_NATIVE_ARCH Mips)
 118 elseif (LLVM_NATIVE_ARCH MATCHES "pic16")
 119   set(LLVM_NATIVE_ARCH "PIC16")
 120 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 121   set(LLVM_NATIVE_ARCH XCore)
 122 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 123   set(LLVM_NATIVE_ARCH MSP430)
 124 else ()
 125   message(STATUS
 126     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 127   set(LLVM_NATIVE_ARCH)
 128 endif ()
 129
 130 if (LLVM_NATIVE_ARCH)
 131   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 132   if (NATIVE_ARCH_IDX EQUAL -1)
 133     message(STATUS
 134       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 135     set(LLVM_NATIVE_ARCH)
 136   else ()
 137     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 138   endif ()
 139 endif()
 140
 141 if( MINGW )
 142   set(HAVE_LIBIMAGEHLP 1)
 143   set(HAVE_LIBPSAPI 1)
 144   # TODO: Check existence of libraries.
 145   #   include(CheckLibraryExists)
 146   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 147 endif( MINGW )
 148
 149 if( MSVC )
 150   set(error_t int)
 151   set(mode_t "unsigned short")
 152   set(LTDL_SHLIBPATH_VAR "PATH")
 153   set(LTDL_SYSSEARCHPATH "")
 154   set(LTDL_DLOPEN_DEPLIBS 1)
 155   set(SHLIBEXT ".lib")
 156   set(LTDL_OBJDIR "_libs")
 157   set(HAVE_STRTOLL 1)
 158   set(strtoll "_strtoi64")
 159   set(strtoull "_strtoui64")
 160   set(stricmp "_stricmp")
 161   set(strdup "_strdup")
 162 else( MSVC )
 163   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 164   set(LTDL_SYSSEARCHPATH "") # TODO
 165   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 166 endif( MSVC )
 167
 168 # FIXME: Signal handler return type, currently hardcoded to 'void'
 169 set(RETSIGTYPE void)
 170
 171 if( LLVM_ENABLE_THREADS )
 172   if( HAVE_PTHREAD_H OR WIN32 )
 173     set(ENABLE_THREADS 1)
 174   endif()
 175 endif()
 176
 177 if( ENABLE_THREADS )
 178   message(STATUS "Threads enabled.")
 179 else( ENABLE_THREADS )
 180   message(STATUS "Threads disabled.")
 181 endif()
 182
 183 configure_file(
 184   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 185   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 186   )
 187
 188 configure_file(
 189   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 190   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 191   )
 192